suprimer bloc en doublons superposé

[lofresh]

Bonjour

sur un dwg je me retrouve avec des blocs identique superposer existe t il une solution pour purger le dessins et donc suprimer les blocs inutiles pour ensuite faire une extraction d'attribut valable.

Merci

[lecrabe]

 

Hello

 

Une petite recherche dans les forums et tu devrais trouver qq chose ! :casstet:

 

Le Decapode

 

PS: je suis gentil, le bon mot cle est DEL_BLK

 

 

[lofresh]

merci mais ca marche pas j ai cherché sur le forum j ai pas trouvé merci de m'aider

 

[lofresh]

j ai tapper del_blk et j ai commande inconnu

et quand je tape del il marque fichier a suprimer :

 

[lofresh]

j ai vraiment cherché et je trouve pas en plus je dois rendre mon plan dans l aprés midi svp aider moi :cool:

[grosseel]

je crois que tu as mal regardé. Fait une rechercher sur DEL_BLK dans 'Rechercher dans les forums.

Allez je suis gentil, voici le lien vers le post qui sera utile :

 

http://www.cadxp.com/modules.php?op=modload&name=XForum&file=viewthread&tid=20855#pid88122

[nicoping28]

Bonjour,

même avec une ou plusieurs décompositions tu ne peux pas purger ?

[lesourd2]

Salut

 

Essaies ceci (trouvé sur ce site)

 

 ;************************************************************************** *************************************************************************** *****
;;; DEL_BLK.LSP
;************************************************************************* *************************************************************************** ******
;Supprime les superpositions de blocs (même nom, même calque, même point d'insertion, même rotation, mêmes échelles)

(defun c:deldup_blk (/ ss ssdup ct len e eb
pt lay bname ang sclx scly sclz
obj obj_list
)

(princ "\nSelect block objects.")
;Select objects and filter all but block insert objects.
(setq ss (ssget (list (cons 0 "INSERT"))))
(if ss ;If any valid objects were selected.
(progn
(princ "\nBuilding list of objects.")
(setq ssdup (ssadd))
;Initialize new selection set to hold objects to delete
(setq len (sslength ss))
;Find out how many objects were selected. 
(setq ct 0)
(while (< ct len) ;Loop through selected objects
(setq e (ssname ss ct)) ;Get an object name
(setq eb (entget e)) ;Get the entity list from the object name
(setq ct (+ ct 1)) ;Increment index into selection set
(setq pt (cdr (assoc 10 eb))) ;Access object's coordinate
(setq lay (cdr (assoc 8 eb))) ;Access object's layer
(setq bname (cdr (assoc 2 eb))) ;Access object's block name
(setq ang (cdr (assoc 50 eb))) ;Access object's rotation angle
(setq sclx (cdr (assoc 41 eb))) ;Access object's x scale
(setq scly (cdr (assoc 42 eb))) ;Access object's y scale
(setq sclz (cdr (assoc 43 eb))) ;Access object's z scale 
;Make list of object properties
(setq obj (list pt lay bname ang sclx scly sclz))

(if (not (member obj obj_list))
;If these properties are not already in list
(setq obj_list (cons obj obj_list)) ;Add them to the list
(ssadd e ssdup) ;Else add object to selection set to delete
) ;End if
) ;End of while loop

(if (> (sslength ssdup) 0)
;If there are any objects in the selection set to delete
(progn
(princ "\nDeleting duplicate objects.")
(setq len (sslength ssdup))
;Find out how many many objects to delete. 
(setq ct 0)
(while (< ct len) ;Loop through objects and delete.
(setq e (ssname ssdup ct)) ;Get object name
(setq ct (+ ct 1)) ;Increment index into selection set
(entdel e) ;Delete duplicate object
) ;End of while loop

(princ ;Print the number of objects deleted to command line 
(strcat "\nDeleted "
(itoa len)
" duplicate objects."
) ;_ Fin de strcat
) ;_ Fin de princ
) ;End progn
(princ "\nNo duplicates found.")
;Else no there were no duplicates to delete.
) ;End if

) ;End progn
(princ "\nNo block objects selected.")
;Else there were no valid objects selected
) ;End if
(princ)
) ;_ Fin de defun
(prompt
"\ndeldup_blk : Supprimer les superpositions de blocs"
) ;_ Fin de prompt

.

 

 

@+

 

[Edité le 26/9/2008 par lesourd2]

[Circus]

Sinon ya OVERKILL ...

 

A+ et bonne vacance pour moi :)

[(gile)]

Salut,

 

Attention la commande pour lancer ce LISP n'est pas DEL_BLK mais DELDUP_BLK

[lofresh]

je comprend pas desoler mais j ai tappé les commande que vous m avez indiqué et rien ne marche alors merci de m'éclairer dans la précision

 

[(gile)]

Salut,

 

Il faut que le LISP soit chargé dans le dessin, voir ce sujet

[lofresh]

je comprend toujours rien on peut maider svp merci

[lofresh]

voici mon adresse msn laurent06000@live.fr

[(gile)]

Re,

 

Tu copies tout le code et uniquement le code (ce qui est sur fond de papier perforé).

 

Si tu veux seulement tester dans un dessin, tu le colles sur la ligne de commande d'AutoCAD et tu valides, le code est chargé dans le dessin tu peusx lancer la commande en entrant deldup_blk à la ligne de commande.

 

Si tu veux le conserver, tu le colles dans le bloc-notes Windows et tu l'enregistres avec le nom que tu veux et l'extension .lsp. Depuis AutoCAD, tu peux charger le fichier que tu viens d'enregistrer avec la commande APPLOAD, un fois chargé dans le dessin tu le lance ent entrant deldup_blk à la ligne de commande.