Rajouter une valeur à un ensemble d\'attribut

[thierry.garré]

Bonjour,

 

Je cherche mais sans trouver.

 

j'ai un bloc insérer X fois dans mon dessin

Ce bloc contient un attribut (qui est toujours renseigné d'une valeur numérique)

je veut rajouter par exemple 5 a toutes les valeurs numériques......

 

 

A l'aide...........

[(gile)]

Salut,

 

Un petit truc vite fait

 

(defun c:addatts (/ att elst tag ss add n tot blk val)
 (and
   (setq att (car (nentsel "\nSélectionnez un attribut: ")))
   (setq elst (entget att))
   (= (cdr (assoc 0 elst)) "ATTRIB")
   (setq tag (cdr (assoc 2 elst)))
   (princ "\nSélectionnez les blocs ou :")
   (or
     (setq ss
     (ssget
       (list
	 '(0 . "INSERT")
	 (assoc 2 (entget (cdr (assoc 330 elst))))
       )
     )
     )
     (setq ss
     (ssget "_X"
	    (list
	      '(0 . "INSERT")
	      (assoc 2 (entget (cdr (assoc 330 elst))))
	    )
     )
     )
   )
   (setq add (getreal "\nValeur à ajouter: ")) ; remplacer par getint pour un entier
   (setq n 0)
   (while (setq blk (ssname ss (setq n (1+ n))))
     (setq att (entnext blk))
     (while (and att
	  (setq elst (entget att))
	  (/= (cdr (assoc 2 elst)) tag)
     )
(setq att (entnext att))
     )
     (if (setq val (distof (cdr (assoc 1 elst))))
(progn
  (entmod (subst (cons 1 (rtos (+ val add))) ; remplacer rtos par itoa
		 (assoc 1 elst)
		 elst
	  )
  )
  (entupd blk)
)
     )
   )
 )
 (princ)
) 

 

[Edité le 10/9/2008 par (gile)]

[thierry.garré]

Merci beaucoup Gilles j'essaye cela tout de suite

[Patrick_35]

Salut

 

Tu as aussi MAT

 

@+