appliquer des modifs sur l\'ensemble des fenetres

[rimbo]

Serait-il possible qu'en appliquant des modifs sur une fenetres de présentation ont l'applique a toutes les autres ?, plutôt que les refaires les unes après les autres.

[Bred]

Salut,

copier les propriétés ou passer par la fenêtre des propriétés ne suffit pas ?

[rimbo]

si j'ai dix onglets présentation pour dix présentation différentes, et que je doivent par exemples les passer toutes en pdf ou changer de traceur ou de présentation je dois le faire une par une. Pourquoi ne pas avoir la possibilité d'appliquer une modifs sur les présentations choisis ?

[(gile)]

Salut,

 

Je ne suis pas sûr que ça réponde à ta damande, mais voici un petit LISP qui permet d'appliquer la mise en page de la présentation courante à toutes les présentations choisies dans la boite de dialogue.

 

;; PROP_LAYOUT (gile) 02/12/2007
;; Applique la configuration de traçage de la présentation courante
;; aux présentations choisies dans la boite de dialogue

(defun c:prop_layout (/ acLay layouts lst)
 (vl-load-com)
 (or *acdoc*
     (setq *acdoc* (vla-get-ActiveDocument (vlax-get-acad-object)))
 )
 (if (= (getvar "TILEMODE") 0)
   (if	(setq lst (GetLayouts nil T))
     (progn
(setq aclay   (vla-get-ActiveLayout *acdoc*)
      layouts (vla-get-Layouts *acdoc*)
      lst     (mapcar
		(function
		  (lambda (l)
		    (vla-item layouts l)
		  )
		)
		(vl-remove (vla-get-Name aclay) lst)
	      )
)
(foreach lay lst
  (vla-Copyfrom lay aclay)
)
     )
   )
   (princ
     "\nCette commande n'est accessible que dans une présentation."
   )
 )
 (princ)
)

;; GETLAYOUTS (gile) 03/12/07
;; Retourne la liste des présentations choisies dans la boite de dialogue
;;
;; arguments
;; titre : titre de la boite de dialogue ou nil, défauts = Choisir la (ou les) présentation(s)
;; mult : T ou nil (pour choix multiple ou unique)

(defun GetLayouts (titre mult / lay tmp file ret)
 (vl-load-com)
 (setq	lay  (vla-get-Layouts
       (vla-get-ActiveDocument (vlax-get-acad-object))
     )
lay  (vl-sort (layoutlist)
	      (function
		(lambda	(x1 x2)
		  (			     (vla-get-TabOrder (vla-item lay x2))
		  )
		)
	      )
     )
tmp  (vl-filename-mktemp "tmp.dcl")
file (open tmp "w")
 )
 (write-line
   (strcat
     "GetLayouts:dialog{label="
     (if titre
(vl-prin1-to-string titre)
(if mult
  "\"Choisir les présentations\""
  "\"Choisir une présentation\""
)
     )
     ";:list_box{key=\"lst\";multiple_select="
     (if mult
"true;}:row{:retirement_button{label=\"Toutes\";key=\"all\";}
ok_button;cancel_button;}}"
"false;}ok_cancel;}"
     )
   )
   file
 )
 (close file)
 (setq dcl_id (load_dialog tmp))
 (if (not (new_dialog "GetLayouts" dcl_id))
   (exit)
 )
 (start_list "lst")
 (mapcar 'add_list lay)
 (end_list)
 (action_tile "all" "(setq ret (reverse lay)) (done_dialog)")
 (action_tile
   "accept"
   "(or (= (get_tile \"lst\") \"\")
   (foreach n (str2lst (get_tile \"lst\") \" \")
   (setq ret (cons (nth (atoi n) lay) ret))))
   (done_dialog)"
 )
 (start_dialog)
 (unload_dialog dcl_id)
 (vl-file-delete tmp)
 (reverse ret)
)

;; str2lst
;; Transforme un chaine avec séparateur en liste de chaines
;;
;; Arguments
;; str : la chaine à transformer en liste
;; sep : le séparateur
;;
;; Exemples
;; (str2lst "a b c" " ") -> ("a" "b" "c")
;; (str2lst "1,2,3" ",") -> ("1" "2" "3")

(defun str2lst (str sep / pos)
 (if (setq pos (vl-string-search sep str))
   (cons (substr str 1 pos)
  (str2lst (substr str (+ (strlen sep) pos 1)) sep)
   )
   (list str)
 )
) 

[Edité le 2/12/2007 par (gile)]

 

[Edité le 3/12/2007 par (gile)]

[rimbo]

Je tiens a te remercier, j'ai pas encore essayé mais si autodesk avait ta réactivité se serait le bonheur.

 

;)

[Patrick_35]

Salut

 

Sur cette page, tu as des outils qui font ce que tu recherches

 

@+

[(gile)]

Salut Patrick,

 

Il me semblait bien que tu avais fait quelque chose à ce sujet, mais j'ai du lire trop vite, je ne l'avais pas retrouvé alors j'ai fait prop_layout (à partir de copy_layout), qui ressemble beaucoup à MPL.

[rimbo]

Merci patrick 35 pour MPL. excellent.

 

Gile merci beaucoup mais quand on tape prop_layout, une boite de dialogue s'affiche demande une sélection puis se ferme...

 

mais bon MPL répond au problème. :o

[(gile)]

Gile merci beaucoup mais quand on tape prop_layout, une boite de dialogue s'affiche demande une sélection puis se ferme...

 

:casstet:

Oui, quand tu as fait ta sélection, la configuration de traçage de la présentation dans laquelle tu es est appliquée à toutes celles que tu as choisi dans la boite.

Prop_Layout fait la même chose que MPL (un peu plus vite grace à l'utilisation de vla-copyform).

[yusukens82]

Merci poue ce super lips, j'avais le même probleme.

je suis blefé par ce lips.

 

la différence avec MPL c'est qu'avec celui la :

1) ça va plus vite

2) il est possible d'appliquer des mise en page nommé.

 

encore merci