vl-string->list et vl-list-string

[zebulon_]

Bonjour,

 

je me suis demandé à quoi pouvaient servir ces 2 fonctions. L'une qui transforme un texte en une liste de code ascii et l'autre qui fait l'inverse.

Je me suis appliqué a trouver une utilisation en faisant une fonction où on donne en entrée un texte et qui renvoie le suivant (en majuscules), comme dans les exemples ci dessous

 

(a+ "AAA") donne "AAB"

(a+ "ZZZ") donne "AAAA"

(a+ "AAZ") donne "ABA"

 

 (defun a+ (ALPHA / LALPHA FLAG ASC NLALPHA)
 (setq ALPHA (strcase ALPHA))
 (setq LALPHA (vl-string->list ALPHA))
 (setq LALPHA (reverse LALPHA))
 (setq NLALPHA nil)
 (setq FLAG T)
 (while LALPHA
   (setq ASC (car LALPHA))
   (setq LALPHA (cdr LALPHA))
   (if FLAG
     (if (setq FLAG (= ASC 90)) ;; je suis arrivé au Z
       (setq ASC 65)            ;; alors je passe au A
       (setq ASC (1+ ASC))      ;; sinon je passe au suivant
     )
   )
   (setq NLALPHA (cons ASC NLALPHA))
 )
 (if FLAG
   (setq NLALPHA (cons 65 NLALPHA))
 )
 (vl-list->string NLALPHA)
)

 

ça a déjà dû être fait quelque part en mieux, mais là c'est plus pour tester les fonctions vl-list->string et consorts.

 

Amicalement

Zebulon_

[Patrick_35]

Salut

Elle peut aussi servir pour écrire le caractère 0 dans un fichier texte, chose que ne sait pas faire le write-char.

 

@+