Generals notes

[WWA]

Bonjour,

 

J'aurais aimer savoir si une ame charitable, peut m'aider a faire un lisp ou autres pour créer automatiquement les notes generals d'un plan...

Je m'explique:

En lancant une commande, une boite de dialogue s'ouvre en affichant une sélection de notes (une vingtaine pour mon cas), donc cocher les notes que l'ont souhaite avoir notre propre plan, avec en plus une option pour chaque qui permets de mettre un rectangle autour du numero de note pour enfin créer soit un bloc soit des lignes de textes isolé.

 

En résumé, je lance la commande, je choisitdans ma liste de notes les notes que je veux avec en option un rectangle sur le numeros de notes (les notes sont numerote de 1 a ...), je valide et ca me crée mon general note. Le top serait de pouvoir édité le résultat pour pourvoir rajouter des notes preenregistre ou meme rajoute des notes a la fin que l'on remplit manuellement...

 

Voila je sais pas du tout si c'est super simple ou pas, mais je serais tres heureux d'avoir de l'aide :)

 

Merci et au plsisir de vous lire

 

[Patrick_35]

Salut

J'ai un peu de mal à comprendre ce que tu souhaites exactement

 

@+

[bonuscad]

Moins non plus je n'ai pas tout bien compris! :P

 

Cependant j'ai trouvé un lisp ici -> MyxNotes qui est fort symphatique et pourrait de donner des idées et qui va dans le sens de ta recherche.

[WWA]

Merci Bonuscad je vais aller voir le lisp.

Sinon en gros, j'aimerais crée les notes d'un plan en choisant dans une "biblio" de notes predefinie.

Exemple: 20 notes predefinies, je lance l'appli et une boite de dialogue me les montre toutes, je coche sur les notes que j'ai envie d'inserer alors j'en veux que 5, je coche donc les 5 qui m'interresse et le résultat serait:

 

Notes:

1. fdhjkgbvbz

2. blablagfjhkl

3. bliblbi

4. dfhjgkh

5. dfhjkgshjggze

 

et editer les notes pour rajouter une note "6. bvbvvcvcbvcv" qui serait specifique (pas dans la biblio des 20 proposés).

 

Pour ce qui est du triangle autour du numero de note ce serait une autre colonne, par exemple je veux le note predefinie "jjjjjjjjj" je coche pour la choisir mais je coche aussi pour lui dire qu'il a un triangle autour...

 

J'espere que c'est plus clair

 

Merci

[zebulon_]

Bonjour,

 

J'ai toujours plus ou moins les mêmes notas à mettre sur mes plans. Un moment donné, ça m'a fatigué, j'ai donc fait ceci :

 

le fichier "nota.dcl"

 
dcl_settings : default_dcl_settings { audit_level = 0 ;}

Nota : dialog {
      label = "NOTA";
        : list_box {
          label = "Liste de notas";
          width = 50;
          key = lnota;
          multiple_select = true;
        }
        spacer_1;
        ok_cancel;
}

 

le fichier "nota.lsp"

 
(defun do_accept_nota (/ RESULTAT)
 (setq RESULTAT (get_tile "lnota"))
 (setq LRES nil)
 (while (/= RESULTAT "")
   (setq LRES (cons (read RESULTAT) LRES))
   (setq RESULTAT (vl-string-left-trim  (strcat " " (itoa (read RESULTAT))) RESULTAT))
 )
 (setq LRES (reverse LRES))
 (if LRES
   (done_dialog 2)
   (alert "rien sélectionné")
 )
)


(defun c:nota (/ OLD_CMD OLDCLAY dcl_id LNOTA what_next LayTxName StyTxName COL TXTH PDEP I LIG LRES)
 (setq OLD_CMD (getvar "cmdecho"))
 (setvar "cmdecho" 0)
 (setq OLDCLAY (getvar "clayer"))

 (setq dcl_id (load_dialog "nota.dcl"))
 (if (not (new_dialog "Nota" dcl_id)) (exit))
 
 (setq LNOTA 
  '(
     "Zébulon_ est beau"
     "Zébulon_ est grand"
     "Zébulon_ est fort"
     "Zébulon_ est un magicien"
     "Zébulon_ est magnifique"
     "Zébulon_ est admirable"
     "Zébulon_ est intelligent"
     "Zébulon_ est riche"
     "Zébulon_ est ..."
     "Zébulon_ est encore ... (les mots me manquent)"
     "et surtout, Zébulon_ est modeste"
     ;;; rajouter ici les lignes supplémentaires
     ;;; sans, si possible, changer ou supprimer les lignes ci-dessus
     ;;; mais bon, s'il le faut ...
   )
 )

 (start_list "lnota")
    (mapcar 'add_list LNOTA)
 (end_list)

 (action_tile "accept" "(do_accept_nota)")
 (action_tile "cancel" "(done_dialog)")

 (setq what_next (start_dialog))
 (unload_dialog dcl_id)
 (if (= what_next 2)
   (progn
     (setq LayTxName "NOMDUCALQUE")	; nom du calque à modifier si nécessaire
     (setq StyTxName "NOMDUSTYLE")	; nom du style de texte à modifier si nécessaire
     (setq COL 1)			; couleur du calque à modifier si nécessaire
     (setq TXTH "5.00")		; hauteur du texte à modifier si nécessaire
     ; créer le calque
     (if (not (tblsearch "LAYER" LayTxName))
       (command "_layer" "_M" LayTxName "_CO" COL LayTxName "")
       (command "_layer" "_T" LayTxName "_ON" LayTxName "_S" LayTxName "")
     )
     ; créer le style de texte
     (if (not (tblsearch "STYLE" StyTxName))
       (command "_style" StyTxName "arial.ttf" TXTH "1.00" "0.00" "N" "N")
       (command "_textstyle" StyTxName)
     )     
     ; placer le texte
     (setq PDEP (getpoint "\nSpécifier le point de départ : "))

     (command "_-mtext" "_non" PDEP "_h" TXTH "_r" "0.00" "_w" "0.00")
     (setq I 1)
     (foreach LIG LRES
       (command (strcat (itoa I) "." (chr 9) (nth LIG LNOTA)))
       (setq I (+ I 1))
     )
     (command "")
   )
 )
 (setvar "cmdecho" OLD_CMD)
 (setvar "clayer" OLDCLAY)
 (princ)
)

 

 

Il s'agit d'une liste déroulante avec la possibilité de faire des choix multiples (avec shift et ctrl, comme dans l'explorateur Windows)

Donc, un seul choix possible par élément de la liste.

Les triangles autour des numéros, va falloir que tu y bosses un peu, puisqu'il faut 2 choix possibles par élément de liste, par exemple en utilisant deux colonnes de cases à cocher.

 

Amicalement

 

Zebulon_

 

[WWA]

Oh et bien,ca a l'air de correspondre a ce que je recherche, j'y jete un oeil de suite!

[zebulon_]

Bonjour,

 

j'ai oublié de dire que le lisp produit un mtext, qu'on peut bien sûr facilement modifier en l'éditant. (pour rajouter une ligne par exemple)

 

Amicalement

 

Zebulon_

 

 

 

[WWA]

Merci bcps! c'est quasiment ce que je cherchais! mais bon je reste un nul en lips :/

 

Juste 2-3 ptites questions:

- définir une largeur max pour insérer le mtext

- cocher une case a coté du nota choisis sur une fenetre sans deroulement plutot que une multi-select windows

-Rajouter un titre NOTAS: (souligné)

 

Merci!

 

[zebulon_]

Bonjour,

 

- cocher une case a coté du nota choisis sur une fenetre sans deroulement plutot que une multi-select windows

 

ce n'est plus la même logique que ce que j'ai fait.

 

mais bon je reste un nul en lips

 

il n'est pas trop tard pour s'y mettre ;)

 

 

- définir une largeur max pour insérer le mtext

 

La réponse se trouve dans :

 
(command "_-mtext" "_non" PDEP "_h" TXTH "_r" "0.00" "_w" "0.00")

 

le "0.00" qui suit le "_w" indique la largeur max (dans mon cas 0.00, et 0.00 = pas de largeur max). Tu peux remplacer "0.00" par la valeur que tu souhaites.

 

-Rajouter un titre NOTAS: (souligné)

 

ça c'est facile, il suffit de rajouter

 

(command "{\\LNOTA}")

juste après le (command _-mtext ...)

 

Le but de cadxp, enfin je crois, n'est pas de t'apporter du poisson mais de t'apprendre à pêcher.

 

Alors bonne pêche

 

Amicalement

 

Zebulon_

[WWA]

Merci bcps en tout cas pour m'avoir aider, ca marche nickel!

j'essaie juste de faire un ptit truc que j'arrive pas, qd on choisit un nota long, le fait de retrecir la largeur on obtiens on note comme ca:

 

1. mmmmmmmm

2. dddddddddddddddddddddddddddddddd

ddddddddddddddddddddddddd

3. ppppppppppppppppp

 

c'est possible d'avoir un resultat comme ca?:

 

1. mmmmmmmm

2. dddddddddddddddddddddddddddddddd

ddddddddddddddddddddddddd

3. ppppppppppppppppp

 

avec en fait les chiffres sur une colonne et les notas qui commence aligner meme en cas de nota sur 2 lignes?

[zebulon_]

Bonjour,

 

Il y a un caractère TAB (chr 9)

(command (strcat (itoa I) "." (chr 9) (nth LIG LNOTA)))

qui se met entre le numéro et le début du texte. En rajoutant un caractère TAB au bon endroit dans le texte du nota long, on peut obtenir quelque chose de ressemblant.

 

 

  (setq LNOTA 
  '(
     "Ceci est un nota long (insérer ici un caratère TAB) deuxième ligne"
     "Ceci est un nota super long (insérer ici un caractère TAB ) deuxième lligne"
   )
 )

 

Amicalement Zebulon_