commande dans chaque onglets

[Fraid]

bonjour,

 

je souhaite appliquer une comande dans chaque onglet

mais je n'arrive pas a faire une boucle

faut t'il que je determine le nombre d'onglet?

ou est stocké le nombre d'onglets?

Comment passer d'un onglet a l'autre?

J'ai chercher la commande correspondant a Ctrl+Pg-Suiv

je ne l'ai pas trouver dans les raccourci autocad :P

 

merci

 

[Patrick_35]

Salut

 

(length (layoutlist))

 

@+

[Tramber]

Vois aussi la variable CTAB, facile à enclencher en lisp foreach p de ta (layoutlist)

:cool:

[zebulon_]

Bonjour,

 

Dernièrement, j'avais une série de feuilles A4 dessinées sur mon espace objet, dessinées l'une à côté de l'autre dans le sens des X avec une décalage de 24500.00. Je devais les mettre en page, chacune séparément, dans l'espace objet. Chaque feuille son onglet.

 

J'ai mis en page la première feuille A4 sur un onglet et à partir de là j'ai lancé le lisp suivant

 

 
(defun llayouts (/ acadobject ActDoc LAYOUTS LLAY n)
 (setq acadObject (vlax-get-acad-object))
 (setq ActDoc (vla-get-ActiveDocument (vlax-get-Acad-Object)))
 (setq LAYOUTS (vla-get-Layouts ActDoc))
 (setq LLAY nil)
 (vlax-for n LAYOUTS
   (setq LLAY (cons (vla-get-name n) LLAY))
 )
 LLAY
)

(defun NewNameLayout (OLDLAY NEWLAY)
 (setq RES nil)
 (while NEWLAY
   (setq ELEM (car NEWLAY))
   (setq NEWLAY (cdr NEWLAY))
   (if (not (member ELEM OLDLAY))
      (setq RES ELEM)
   )
 )
 RES
)


(defun c:clayout ()
 (vl-load-com)
 (setq NBPAGE (getint "\nNombre de copies : "))
 (repeat NBPAGE
   (setq OLDLLAY (llayouts))
   (command "_layout" "_c" "" "")
   (setq NEWLLAY (llayouts))
   (setq NNAME (NewNameLayout OLDLLAY NEWLLAY))
   (command "_layout" "_s" NNAME)
   (command "_MSPACE")
   (command "_-pan" "_non" '(0 0) "_non" '(-24500.0 0))
   (command "_PSPACE")
 )
 (princ)
)

 

Bien entendu, la fonction (llayouts) peut être remplacée par (layoutlist) comme le suggère Patrick. C'est juste pour vous montrer que je fais des progrès en vlisp.

 

Amicalement

 

Zebulon_

 

[Edité le 12/9/2006 par zebulon_]

[Patrick_35]

C'est super zebulon_ ;)

Il reste juste encore quelques command dans to lisp ;)

 

@+

[yalta]

Bonjour,

 

.........si j'osai je demanderai la même chose dans le sens des " y "...!!

 

ce serait sympas, merci,

 

Sylvain

[Fraid]

merci pour vos reponse

 

donc

je recupere le nombre de presentation avec

 

(setq nbpres (length (layoutlist)))

 

je passe a la presentation suivante avec

 

(command "_layout" "_e" nompres)

 

mais pour nompres j'y arrive pas avec le nth

 

(set nompres (nth (+? 1) (layoutlist))

 

je ne trouve pas la bonne syntaxe :P

 

 

en fait je veux seulement avant d'envoyer un dessin a un client etre sur que dans chaque on presentation on soit dans l'espace papier et en zoom etendu

 

sa ne doit pas etre dur

[Tramber]

C'est pas le Tramber qui te mettait sur la piste ?

 

(foreach p (layoutlist)
 (setvar "CTAB" p)
 (command "zoom" "_ex")
 )

[Patrick_35]

Ou encore comme ceci

 

(mapcar '(lambda (x) (setvar "CTAB" x)(command "zoom" "_ex")) (layoutlist))

 

@+

[Fraid]

je pense que je n'ai pas compris les manipulations de listes

 

vivement que j'ai plus de temps.....

 

encore merci

[Tramber]

Les gars, je vous trouve un peu dur. Chaque chose en son temps pour le débutant !