Etirer circulaire

[serge77]

Bonjour,

 

Est t-il possible avec Autocad de faire un étirer circulaire ?

Merci pour vos réponse

[jalna]

Salut

:o

Pas tout compris

[serge77]

Explications:

 

Je veux pouvoir sur un tracé de circuit type convoyeur changer des courbes qui font 90°

par des courbes qui font 120° par exemple.

Aujourd'hui je fait une rotation d'un des parties droites du circuit et un prolonger de mon cercle. Je voudrais faire ca en une seule opération.

Du genre étirer ou je spécifie le centre de rotation et l'angle.

J'espère m'etre fait comprendre, les vacances ont été longues et c'est un peu dur.

Merci d'avance

 

[Edité le 11/9/2006 par serge77]

[Tramber]

Aujourd'hui je fait une rotation d'un des parties droites du circuit et un prolonger de mon cercle

 

C'est bien là le problème. Il y a l'accrochage Extension avec l'édition par poignées mais que faire des bout de lignes droites tangeant aux début et fins d'arcs ?

 

Je pense que tu aurais du prolonger tes vacances encore un peu pour bien te reposer :cool:

[(gile)]

Salut,

 

Ça ne fait peut-être pas tout, mais ça pourrait aider : tu touveras ici un LISP qui permet de transformer les cercles et ellipses en arc (ou vice-versa) et de modifier les arcs (de cercle ou d'ellipse). On peut, pour les arcs spécifier les angles de départ et de fin à l'aide du pointeur ou au clavier.

[(gile)]

Re,

 

Un petit LISP vite fait (pas testé en profondeur) qui, il me sempbe répond à ta demande :

Tu sélectionne un arc puis la ligne tangente à l'arc du côté où tu veux modifier l'arc et tu spécifies le nouvel angle.

 

(defun c:arcline_edit (/ arc line sens ang dif)
 (while
   (not
     (and
(setq arc (car (entsel "\nSélectionnez un arc: ")))
(= "AcDbArc"
   (vla-get-objectName (setq arc (vlax-ename->vla-object arc)))
)
     )
   )
 )
 (while
   (not
     (and
(setq line
       (car
	 (entsel "\nSélectionnez une ligne tangente à l'arc: ")
       )
)
(= "AcDbLine"
   (vla-get-objectName
     (setq line (vlax-ename->vla-object line))
   )
)
     )
   )
 )
 (cond
   ((or
      (equal (vlax-get arc 'StartPoint)
      (vlax-get line 'StartPoint)
      1e-9
      )
      (equal (vlax-get arc 'StartPoint)
      (vlax-get line 'EndPoint)
      1e-9
      )
    )
    (setq sens -1)
   )
   ((or
      (equal (vlax-get arc 'EndPoint)
      (vlax-get line 'StartPoint)
      1e-9
      )
      (equal (vlax-get arc 'EndPoint)
      (vlax-get line 'StartPoint)
      1e-9
      )
    )
    (setq sens 1)
   )
   (T (prompt "\nL'arc et la ligne ne sont pas jointifs."))
 )
 (if sens
   (progn
     (prompt
(strcat
  "\nAngle actuel de l'arc : "
  (angtos
    (setq ang
	   (- (vla-get-EndAngle arc) (vla-get-StartAngle arc))
    )
  )
)
     )
     (initget 1)
     (setq dif (- (getangle "\nSpécifiez le nouvel angle: ") ang))
     (vla-StartUndoMark
(vla-get-ActiveDocument (vlax-get-acad-object))
     )
     (if (minusp sens)
(vla-put-StartAngle arc (- (vla-get-StartAngle arc) dif))
(vla-put-EndAngle arc (+ (vla-get-EndAngle arc) dif))
     )
     (vla-rotate
line
(vla-get-Center arc)
(* sens dif)
     )
     (vla-EndUndoMark
(vla-get-ActiveDocument (vlax-get-acad-object))
     )
   )
 )
 (princ)
)

 

[Edité le 12/9/2006 par (gile)]

[serge77]

Merci (gile) ton script marche nickel.

Maintenant Je voudrais avoir le même résultat avec un bloc dynamique.

Je rentre un angle et il me fais ma courbe avec à ses extrémités deux segment tangents.

Pas simple a priori.