Aller au contenu

masque encart présentaton


harnoo

Messages recommandés

Salut....

 

Le mieux est de délimiter ta fenetre de dessous.

Tu dessines une poly qui correspond à ta "nouvelle fenetre", donc avec "l'encart" exclu, tu fermes bien la poly. Puis tu sélectionnes ta fenetre du dessous, clic droit, délimiter la fenetre, et là, tu sélectionnes la poly que tu viens de dessiner.

 

Xav

AutoCad Map 3D 2011 - Covadis v16.0d

Windows 7 - 64b

Lien vers le commentaire
Partager sur d’autres sites

Merci pour ta réponse,

Mais si je comprends bien, cette méthode est parfaite quand la fenêtre (l'encart) se trouve dans un coin de la présentation, mais lorsque l'encart se trouve dans la présentation, ça me parait plus compliqué, à moins de laisser apparaitre un trait qui va rejoindre l'encart pour en faire le tour.

Lien vers le commentaire
Partager sur d’autres sites

Salut.

 

Suffit de masquer le contour de la fenêtre, au pire refaire une polyligne sur l'extérieur si tu veut que le contour reste visible.

 

Ou alors tu passe par NETTOYER, et là il faut juste faire attention à l'ordre du tracé.

 

Cordialy.

Je suis dysorthographique alors lâchez-moi les basques avec ça, je fait déjà de mon mieux.
Membre d'Extinction Rebellion, car pour sauver le monde il n'est jamais trop tard, amour et rage !
Pour écrire un vraie point médian (e·x·e·m·p·l·e) [Alt + 0183] ou ajout d'un raccourci clavier personnalisé (ex. [AltGr + ;])

Utilisateur d'AutoCAD 2021 sous Windows 10

Lien vers le commentaire
Partager sur d’autres sites

+1 avec Aleck !!!

 

c'est un sujet qui a déjà abordé plusieurs fois, et il me semble que c'est la solution la plus utilisée, et qu'il n'y a pas de solution "miracle" pour ça!

Perso, j'aime pas la commande NETTOYER!

 

Xav

AutoCad Map 3D 2011 - Covadis v16.0d

Windows 7 - 64b

Lien vers le commentaire
Partager sur d’autres sites

Moi je proscris les NETTOYER, car j'ai eu pas mal de problèmes lors d'impression PDF, avec de gros aplats à la place des NETTOYER... Mais ce n'engage que moi..

 

Perso, je passe par une fenêtre de contour se retournant "presque" sur elle-même dans un des coins de la petite fenêtre. Et je met cette fenêtre dans un calque soit, non imprimable, soit geler, soit inactif. Bref qui ne sera pas imprimé. Et la pas de problèmes.

Donc tu as donné la bonne solution, reste à mettre ta fenêtre dans un calque tel que je le décris.

www.cad-is.fr
Autocad Map 2021 - Covadis/Autopiste V18.0c
Pisser sous la douche ne suffira pas
Lien vers le commentaire
Partager sur d’autres sites

Hello

 

Voir ci-dessous la routine MAGIQUE de Patrick_35 pour ce souci !

 

MERCI Patrick, Bye, lecrabe (puise dans mon stock de 2000 routines)

 


;; 
;; http://cadxp.com/topic/38953-wipeout/page__p__230975
;; 
;; Routine: RWH_254  (Ex RWH)  par P35 pour Patrice
;; 
;; Remplacer un wipeout par une hachure "SOLID" de couleur 254,254,254
;; 
;; Modifier avec 254,254,254 a cause d un BUG Aleatoire avec les PDFs !!
;;

(vl-load-com) 

(defun c:RWH_254 (/ blo col dat dic doc ent hac ele lst obj pol rgb)
 (setq doc (vla-get-activedocument(vlax-get-acad-object))
col (vlax-create-object (strcat "AutoCAD.AcCmColor." (substr (getvar "acadver") 1 2)))
 )
 (vla-startundomark doc) 

; (vla-setrgb col 255 255 255) 
 (vla-setrgb col 254 254 254) 

 (vlax-for blo (vla-get-blocks doc)
   (or (wcmatch (vla-get-name blo) "*|*")
(eq (vla-get-isxref blo) :vlax-true)
     (progn
(vlax-for ent blo
  (and (eq (vla-get-objectname ent) "AcDbWipeout")
    (progn
      (setq hac (vla-addhatch blo acHatchPatternTypePredefined "SOLID" :vlax-true)
	    lst (gc:RasterVertices (vlax-vla-object->ename ent))
	    pol (vla-addlightweightpolyline blo
					    (vlax-safearray-fill
					      (vlax-make-safearray vlax-vbdouble (cons 0 (1- (* (length lst) 2))))
					      (apply 'append (mapcar '(lambda (x) (list (car x) (cadr x))) lst))
					    )
		)
      )
      (vlax-put pol 'closed :vlax-true)
      (vlax-invoke hac 'appendouterloop (list pol))
      (vla-evaluate hac)
      (foreach ele (list hac pol)
	(mapcar '(lambda(x) (vlax-put ele x (vlax-get ent x))) (list 'layer 'linetype 'linetypescale))
	(vlax-put ele 'truecolor col)
      )
      (setq dat (cons hac (cons pol dat)))
      (vla-delete ent)
    )
  )
)
(and dat
  (progn
    (and (vl-catch-all-error-p (setq dic (vl-catch-all-apply 'vla-item (list (vla-getextensiondictionary blo) "ACAD_SORTENTS"))))
      (setq dic (vla-addobject (vla-getextensiondictionary blo) "ACAD_SORTENTS" "AcDbSortentsTable"))
    )
    (vlax-invoke dic 'movetobottom dat)
    (setq dat nil)
  )
)
     )
   )
 )
 (vlax-release-object col)
 (vla-regen doc acallviewports)
 (vla-endundomark doc)
 (princ)
)


;; Différentes routines de GC trouves sur theswamp.org
;; http://www.theswamp.org/index.php?topic=36270.msg418035#msg418035
;; Convertion des pixels d'une image en coordonnées Autocad
;; gc:RasterVertices
;; Returns the image raster (or wipeout) boundary vertices list (WCS) 

(defun gc:RasterVertices (img / elst ins u v size norm mat disp pts)
 (setq	elst (entget img)
ins  (cdr (assoc 10 elst))
u    (cdr (assoc 11 elst))
v    (cdr (assoc 12 elst))
size (cdr (assoc 13 elst))
norm (gc:CrossProduct u v)
u    (trans u 0 norm)
v    (trans v 0 norm)
mat  (trp (list u (mapcar '- v) '(0. 0. 1.)))
disp (mapcar '+
	     (trans ins 0 norm)
	     (gc:ScaleVector v (cadr size))
	     (gc:ScaleVector u 0.5)
	     (gc:ScaleVector v -0.5)
     )
pts  (if (= 1 (logand 1 (cdr (assoc 71 elst))))
       ((lambda	(l)
	  (list	(car l)
		(list (caadr l) (cadar l) (caddar l))
		(cadr l)
		(list (caar l) (cadadr l) (caddar l))
	  )
	)
	 (gc:massoc 14 elst)
       )
       (cdr (gc:massoc 14 elst))
     )
 )
 (mapcar
   '(lambda (p)
      (trans (mapcar '+ (mxv mat p) disp) norm 0)
    )
   pts
 )
)


;; gc:ScaleVector
;; Multiply a vector by a scalar 

(defun gc:ScaleVector (v s) (mapcar (function (lambda (x) (* x s))) v))

;; gc:CrossProduct
;; Returns the cross product of two vectors
(defun gc:CrossProduct (v1 v2)
 (list	(- (* (cadr v1) (caddr v2)) (* (caddr v1) (cadr v2)))
(- (* (caddr v1) (car v2)) (* (car v1) (caddr v2)))
(- (* (car v1) (cadr v2)) (* (cadr v1) (car v2)))
 )
)


;; MXV
;; Apply a transformation matrix to a vector -Vladimir Nesterovsky- 

(defun mxv (m v)
 (mapcar (function (lambda (r) (apply '+ (mapcar '* r v)))) m)
)


;; TRP
;; Transpose a matrix -Doug Wilson- 

(defun trp (m) (apply 'mapcar (cons 'list m)))

;; gc:massoc
;; Returns the list of all values for the code in an association list
(defun gc:massoc (code alst)
 (if (setq alst (member (assoc code alst) alst))
   (cons (cdar alst) (gc:massoc code (cdr alst)))
 )
) 

Autodesk Expert Elite Team

Lien vers le commentaire
Partager sur d’autres sites

Créer un compte ou se connecter pour commenter

Vous devez être membre afin de pouvoir déposer un commentaire

Créer un compte

Créez un compte sur notre communauté. C’est facile !

Créer un nouveau compte

Se connecter

Vous avez déjà un compte ? Connectez-vous ici.

Connectez-vous maintenant
×
×
  • Créer...

Information importante

Nous avons placé des cookies sur votre appareil pour aider à améliorer ce site. Vous pouvez choisir d’ajuster vos paramètres de cookie, sinon nous supposerons que vous êtes d’accord pour continuer. Politique de confidentialité