CADxp: cotation en pourcentage - CADxp

Aller au contenu

  • 2 Pages +
  • 1
  • 2
  • Vous ne pouvez pas commencer un sujet
  • Vous ne pouvez pas répondre à ce sujet

cotation en pourcentage

#1 L'utilisateur est hors-ligne   bekibo 

  • ceinture verte
  • Groupe : Membres
  • Messages : 51
  • Inscrit(e) : 12-juin 06
  • LocationCALUIRE

Posté 08 juin 2009 - 08:37

Bonjour, je voudrai juste indiquer la cote de mes angles en pourcentage et non en degré.....
0

#2 L'utilisateur est hors-ligne   Tramber 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 7616
  • Inscrit(e) : 29-mars 03
  • LocationStrasbourg

Posté 08 juin 2009 - 08:52

Alors là c'est facile :
dans ton style de cote ou dans les proriétés d'une, choisis une cotation en gradians comme format de l'angle.
Mais il te sera plus difficile d'appliquer un coef car cela n'est possible que sur les cotations de longueur.


[Edité le 8/6/2009 par Tramber]
Image IPB

Bureau d'études par le dessin.
Spécialiste Escaliers
Développement - Formation

Et toujours...
./__\.
(.°=°.)
0

#3 L'utilisateur est hors-ligne   bekibo 

  • ceinture verte
  • Groupe : Membres
  • Messages : 51
  • Inscrit(e) : 12-juin 06
  • LocationCALUIRE

Posté 08 juin 2009 - 09:03

BonjouTrambler,

j'ai effectivement appliqué un coeff pour transposer mes angles, mais je n'arrive toujours pas à indiquer sur le plan la pente en pourcentage; sinon, il faut que je l'écrive en format texte.
0

#4 L'utilisateur est hors-ligne   (gile) 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 9619
  • Inscrit(e) : 02-septembre 05

Posté 08 juin 2009 - 09:10

Citation

Alors là c'est facile :
dans ton style de cote ou dans les proriétés d'une, choisis une cotation en gradians comme format de l'angle.
Mais il te sera plus difficile d'appliquer un coef car cela n'est possible que sur les cotations de longueur.


:casstet: Là, j'ai un doute...

Le "gradian" (il me semble qu'on parle plutôt de grade en français, encore une traduction "autodeskienne"....) est une unité angulaire comme le degré ou le radian.
L'expression d'une pente (angle) en pourcentage correspond à la tangente de l'angle multipliée par 100 (autrment dit : le rapport entre le dénivelé et la distance horizontale).

Une pente de 100% correspond donc à un angle de 45°, pi/4 radians ou 50 grades.

Je ne connais pas d'autre moyen que de forcer la cote pour faire ce que bekibo demande.
Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
Image IPB
0

#5 L'utilisateur est hors-ligne   lili2006 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 10225
  • Inscrit(e) : 21-décembre 05

Posté 08 juin 2009 - 09:16

Bonjour à toutes et tous,

Entièrement d'accord avec (gile),

Citation

50 grades


Encore écris => 50 gon ou 50 gons dans le domaine de la topographie (symbole gon gônia : angle, en grec) )

Mais, on peut aussi appeler cette mesure angulaire "Gradian", bof ! :o
0

#6 L'utilisateur est hors-ligne   Tramber 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 7616
  • Inscrit(e) : 29-mars 03
  • LocationStrasbourg

Posté 08 juin 2009 - 09:18

Citation

Une pente de 100% correspond donc à un angle de 45°, pi/4 radians ou 50 grades.


Ok, mais il est clair que le gradian et la valeur de pente n'ont rien à voir sauf peut-être dans ce cas précis. Mais tout le monde sait que TAN 45 =1 ! Cas exceptionnel.

[Edité le 8/6/2009 par Tramber]
0

#7 L'utilisateur est hors-ligne   bekibo 

  • ceinture verte
  • Groupe : Membres
  • Messages : 51
  • Inscrit(e) : 12-juin 06
  • LocationCALUIRE

Posté 08 juin 2009 - 09:27

Merci pour ce débat;
donc si je comprends bien, j'en reste à ma méthode?!! "cotation forcée"
0

#8 L'utilisateur est hors-ligne   Tramber 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 7616
  • Inscrit(e) : 29-mars 03
  • LocationStrasbourg

Posté 08 juin 2009 - 09:43

Oui, à moins d'un programme qui pourrait la forcer à ta place et faire la convertion en valeur de pente. Ceci dit, il me parait génant de coter une pente en % sur la base d'une cotation d'angle. D'ordinaire, c'est un texte écrit le long de la pente.

Veux-tu faire un programme Autolisp ?
0

#9 L'utilisateur est hors-ligne   bekibo 

  • ceinture verte
  • Groupe : Membres
  • Messages : 51
  • Inscrit(e) : 12-juin 06
  • LocationCALUIRE

Posté 08 juin 2009 - 09:49

je n'en ai malheureusement pas la capacité :exclam:
0

#10 L'utilisateur est hors-ligne   Tramber 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 7616
  • Inscrit(e) : 29-mars 03
  • LocationStrasbourg

Posté 08 juin 2009 - 10:02

(defun c:cot%()

  (vl-load-com)

  (setq vlcot(vlax-ename->vla-object(car(entsel))))

  (vla-put-TextOverride vlcot

    (strcat"Pente à"(rtos(* 100(/(sin(vla-get-Measurement vlcot))(cos(vla-get-Measurement vlcot))))2 2)"%"))

  )


Enregistre ce texte dans un fichier *.lsp puis charge le (glisser-déposer suffit)

Lance la commande COT% et dis-nous déjà si tu veux une amélio. Le principe est simple, au choix des objets, tu cliques une cotation d'angle.

A toi de vérifier la formule math par les résultats.
0

#11 L'utilisateur est hors-ligne   bekibo 

  • ceinture verte
  • Groupe : Membres
  • Messages : 51
  • Inscrit(e) : 12-juin 06
  • LocationCALUIRE

Posté 08 juin 2009 - 10:12

Merci beaucoup, je vais essayer
0

#12 L'utilisateur est hors-ligne   (gile) 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 9619
  • Inscrit(e) : 02-septembre 05

Posté 08 juin 2009 - 10:28

Un autre qui crée un objet texte le long de la pente.
Il suffit de cliquer 2 points.

(defun c:pente% (/ p1 p2 a)

  (if

    (and

      (setq p1 (getpoint "\nPremier point: "))

      (setq p2 (getpoint "\nDeuxième point: "))

      (setq a (angle p1 p2))

    )

     (entmake

       (list

	 '(0 . "TEXT")

	 '(100 . "AcDbEntity")

	 '(100 . "AcDbText")

	 '(10 0. 0. 0.)

	 (cons 40 (getvar 'textsize))

	 (cons 1

	       (strcat (rtos (abs (* 100 (/ (sin a) (cos a)))) 2 2) " %")

	 )

	 (cons 50

	       (if (minusp (cos a))

		 (+ pi a)

		 a

	       )

	 )

	 '(72 . 1)

	 (cons 11 (mapcar '(lambda (x1 x2) (/ (+ x1 x2) 2.)) p1 p2))

	 '(73 . 1)

       )

     )

  )

  (princ)

)

Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
Image IPB
0

#13 L'utilisateur est hors-ligne   Tramber 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 7616
  • Inscrit(e) : 29-mars 03
  • LocationStrasbourg

Posté 08 juin 2009 - 10:31

(gile) s'ennuie tellement qu'il fait du ENTMAKE !
0

#14 L'utilisateur est hors-ligne   bekibo 

  • ceinture verte
  • Groupe : Membres
  • Messages : 51
  • Inscrit(e) : 12-juin 06
  • LocationCALUIRE

Posté 08 juin 2009 - 10:32

Commande inconnue "COT%". :casstet:

Je l'ai pourtant charger comme un fichier lps :calim:
0

#15 L'utilisateur est hors-ligne   Tramber 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 7616
  • Inscrit(e) : 29-mars 03
  • LocationStrasbourg

Posté 08 juin 2009 - 10:45

test.LSP, par exemple !

Au glisser-déposer, tu devrais avoir une confirmation de chargement.

NB : tu peux ajouter le code de (gile) à ce fichier et aussi lancer PENTE%.

Mais d'abord, essaie de nous charger ce fichier, ca va marcher. (gile va te donner un lien pour son cours sur les chargments de programmes, n'est-ce pas (gile) ?)
Image IPB

Bureau d'études par le dessin.
Spécialiste Escaliers
Développement - Formation

Et toujours...
./__\.
(.°=°.)
0

#16 L'utilisateur est hors-ligne   bekibo 

  • ceinture verte
  • Groupe : Membres
  • Messages : 51
  • Inscrit(e) : 12-juin 06
  • LocationCALUIRE

Posté 08 juin 2009 - 10:52

Merci à tous les deux
0

#17 L'utilisateur est hors-ligne   (gile) 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 9619
  • Inscrit(e) : 02-septembre 05

Posté 08 juin 2009 - 10:52

Citation

(gile) s'ennuie tellement qu'il fait du ENTMAKE !


J'aime bien entmake, si on veux ensuite changer/ajouter certaines propriétés, il suffit de modifier/ajouter une entrée dans la liste ;)

bekibo,
tu trouveras sur cette page les explications concernant le chargement et l'exécution des LISP.
Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
Image IPB
0

#18 L'utilisateur est hors-ligne   brunomu 

  • Advanced Member
  • PipPipPip
  • Groupe : Membres
  • Messages : 45
  • Inscrit(e) : 13-mai 06

Posté 04 août 2010 - 13:49

Sauf erreur de ma part, la routine de gile ne marche que dans le SCG ?
0

#19 L'utilisateur est hors-ligne   (gile) 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 9619
  • Inscrit(e) : 02-septembre 05

Posté 04 août 2010 - 17:59

Salut

Effectivement.
Voilà deux autres versions qui ne fonctionnent qu'en 2d (plan XY du SCU courant parallèle au plan du SCG).

La première mesure la pente par rapport à l'axe X du SCU courant :
(defun c:pente% (/ p1 p2 a)

  (if

    (and

      (setq p1 (getpoint  "\nPremier point: "))

      (setq p2 (getpoint p1 "\nDeuxième point: "))

      (setq a (angle p1 p2))

    )

     (entmake

       (list

	 '(0 . "TEXT")

	 '(100 . "AcDbEntity")

	 '(100 . "AcDbText")

	 '(10 0. 0. 0.)

	 (cons 40 (getvar 'textsize))

	 (cons 1

	       (strcat (rtos (abs (* 100 (/ (sin a) (cos a)))) 2 2) " %")

	 )

	 (cons 50

	       (+ (angle '(0. 0. 0.) (getvar 'ucsxdir))

		  (if (minusp (cos a))

		    (+ pi a)

		    a

		  )

	       )

	 )

	 '(72 . 1)

	 (cons 11 (mapcar '(lambda (x1 x2) (/ (+ x1 x2) 2.)) (trans p1 1 0) (trans p2 1 0)))

	 '(73 . 1)

       )

     )

  )

  (princ)

)


La seconde mesure la pente par rapport au SCG mais fonctionne quelque soit le SCU courant :
(defun c:pente%	(/ p1 p2 a)

  (if

    (and

      (setq p1 (getpoint "\nPremier point: "))

      (setq p2 (getpoint p1 "\nDeuxième point: "))

      (setq a (angle (setq p1 (trans p1 1 0)) (setq p2 (trans p2 1 0))))

    )

     (entmake

       (list

	 '(0 . "TEXT")

	 '(100 . "AcDbEntity")

	 '(100 . "AcDbText")

	 '(10 0. 0. 0.)

	 (cons 40 (getvar 'textsize))

	 (cons 1

	       (strcat (rtos (abs (* 100 (/ (sin a) (cos a)))) 2 2) " %")

	 )

	 (cons 50

	       (if (minusp (cos a))

		 (+ pi a)

		 a

	       )

	 )

	 '(72 . 1)

	 (cons 11 (mapcar '(lambda (x1 x2) (/ (+ x1 x2) 2.)) p1 p2))

	 '(73 . 1)

       )

     )

  )

  (princ)

)

Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
Image IPB
0

#20 L'utilisateur est hors-ligne   brunomu 

  • Advanced Member
  • PipPipPip
  • Groupe : Membres
  • Messages : 45
  • Inscrit(e) : 13-mai 06

Posté 05 août 2010 - 10:17

Ça marche, c'est cool ! Merci.

Juste un truc : comment faire pour que le texte soit créé dans le style de texte courant ?
0

Partager ce sujet :


  • 2 Pages +
  • 1
  • 2
  • Vous ne pouvez pas commencer un sujet
  • Vous ne pouvez pas répondre à ce sujet

1 utilisateur(s) en train de lire ce sujet
0 membre(s), 1 invité(s), 0 utilisateur(s) anonyme(s)