Changement de SCU

[tilte]

Salut à tous,

 

Je souhaiterais savoir comment faire en lisp un changement de scu pré-défini (nom connu car scu enregistré) soit via un menu contextuel à faire apparaitre d'un clic droit, soit par un raccourci type F1, F2, F3 préalablement défini, le tout à l'intérieur d'une routine LISP qui permet de dessiner des traits. Ouhais je sais, y'a la commande LIGNE qui existe :) mais j'suis maso.

 

merci d'avance pour vos propositions.

[(gile)]

Salut,

 

Un petit LISP vite fait, il n'y a pas de contrôle pour savoir si les SCU sont enregistrés.

 

Dans l'exemple, après avoir lancé scu_def taper 1 2 ou 3 puis Entrée ou clic droit -> choix du scu.

 

(defun c:scu_def (/ scu)
 (initget "scu1 scu2 scu3")
 (setq scu (getkword "\nChoix du SCU à activer [scu1/scu2/scu3]: "))
 (command "_.ucs" "_restore" scu)
 (princ)
) 

 

Si c'est pour mettre dans une routine, pas besoin de faire de defun et on peut aussi éviter le setq :

 

(initget "scu1 scu2 scu3")
 (command "_.ucs"
   "_restore"
   (getkword "\nChoix du SCU à activer [scu1/scu2/scu3]: ")
 ) 

 

[Edité le 11/4/2006 par (gile)]

[(gile)]

Salut un petit exemple d'utilisation avec _LINE :

 

(defun c:ma_ligne (/ scu)
 (initget "General scu1 scu2 scu3")
 (setq	scu (getkword
      "\nChoix du SCU à activer [General/scu1/scu2/scu3]: "
    )
 )
 (if (= scu "General")
   (command "_.ucs" "_world")
   (command "_.ucs" "_restore" scu)
 )
 (command "_.line"
   (while (not (zerop (getvar "cmdactive")))
     (command pause)
   )
 )
) 

[(gile)]

En récupérant les SCU enregistrés.

 

NOTA : Les noms de SCU ne doivent pas contenir d'espaces et avoir chacun une (ou plusieurs) majucule différente (et pas G de General) ou un numéro à taper au clavier (exemple : Face, DRoite, Gauche, DEssus ou scu1 scu2 ...)

 

Vois la fonction initget dans l'aide.

 

Version commentée

 

;;; Demande à l'utilisateur des spécifier un des SCU enregistrés et lance la commande ligne

(defun c:ucs_line (/ concat scu lst)

 ;;Concaténtion de "General" et de la liste de noms de scu avec un séparateur
 ;; exemple (concat "/" '("scu2" "scu1")) retourne "General/scu1/scu2"
 (defun concat	(s l)
   (strcat "General"
    (apply 'strcat
	   (mapcar '(lambda (x) (strcat s x)) (reverse l))
    )
   )
 )

 ;; Création de la liste des SCU enregistrés
 (setq scu (tblnext "UCS" T))
 (while scu
   (setq lst (cons (cdr (assoc 2 scu)) lst)
  scu (tblnext "UCS")
   )
 )

 ;; Invite pour le choix du SCU à activer
 (initget (concat " " lst))
 (setq	scu (getkword (strcat
		"\nChoix du SCU à activer ["
		(concat "/" lst)
		"]: "
	      )
    )
 )

 ;; Activation du SCU sélectionné
 (if (= scu "General")
   (command "_.ucs" "_world")
   (command "_.ucs" "_restore" scu)
 )

 ;; Donne la main à l'utilisateur pour la commande "_line"
 (command "_.line"
   (while (not (zerop (getvar "cmdactive")))
     (command pause)
   )
 )
) 

 

[Edité le 15/4/2006 par (gile)]