Récupérations des propriétés des fichiers DWG

guibout · le 22 février 2006

Bonjour à tous,

J'ai un dossier avec environ 1000 fichiers DWG.

Je souhaite en obtenir un listing comprenant :

- le nom du fichier

- la taille du fichier

- la date de création

- la date de dernière ouverture

- le temps passé (temps d'ouverture du fichier)

- éventuellement d'autres éléments s'ils y en a (comme les fichiers en XREFS)

Merci de m'indiquer la démarche à suivre ou une application permettant de faire se travail.

Cordialement

guibout · le 22 février 2006

Pour faire au message précédent, je souhaiterai aussi récupérer le nom des présentations si possible

Merci

Cordialement

Tramber · le 22 février 2006

J'ai toujours conseillé ce listeur en anglais.

Le masque te permet de filtrer les DWG.

Les anciens te parleront du DOS.

Pour les Xrefs, les temsp de traitement et les présentations, c'est plus dur avec ce gratuiciel qu'avec d'autres outils dont on te parlera surement.

PCL · le 22 février 2006

J'ai le meme soucis, et pour le moment le seul moyen que j'ai trouver est de creer un "jeu de feuille", ce qui a pour but de lister l'ensemble des fichiers contenu dans un repertoire et sous repertoire.

pour chacun des fichiers je renseigne les cases du tableau proprietes du fichiers (fichiers, proprietes du dessin, onglet resumé)

une fois le "jeu de feuille" créer, cela permet d'inserer "un tableau de feuille" depuis le "jeu de feuille" dans un nouveau dessin. on obtient un alors un tableau renseigné automatiquement, et que l'on peu mettre à jour aussi automatiquement. cela evite les erreurs de saisie.

à voir, dans les proprietes du dessin, il y a un onglet personnaliser, je n'ai pas encore tester mais je pense que l'on doit pouvoir y mettre des données et les inclures dans notre tableau de feuille...

salutations acadienne,

Paul

ps: ca ne vaut pas de la SGDT, mais à defaut...

LUDWIG · le 22 février 2006

Tramber, ça m'étonne que tu ne lui proposes pas un script !

C'est sûr que sur 1000 dwg, il va falloir le scinder en moult scripts pour pas faire péter la mémoire.

Moi j'utilise pcatalog (voir telecharger.com) comme listeur de dwg. Il exporte la liste dans excel. Je construits mon script dans une cellule

d'excel du type :

="open "& CAR(34)&F2&B2&CAR(34)&" LISP " &" _close O"

les car(34) sont les guillemets

les F2 et G2 les références aux cellules ou il y a le nom du chemin et le nom du fichier

LISP est le nom du lisp (qui doit être chargé au contenu de démarrage) qui écrit une ligne dans un fichier texte dans laquelle il y a les

informations recherchées.

_close o permet de fermer le fichier sans enregistrer

Dans le lisp qui écrit les données, on peut faire appelle aux variables suivantes :

- le nom du fichier : dwgname (et dwgprefix le chemin)

- la taille : commande vl-file-size

- la date de création TDCREATE ou TDUCREATE (en local / universel)

- la date du dernier enregistrement : TDUPDATE ou TDUUPDATE (en local / universel)

- le temps passé (temps d'ouverture du fichier) : TDINDWG (en jour)

- les fichiers en XREFS : le lisp peu lire les blocks de la table et écrire le nom et le chemin que si c'est un xref

- présentation : (layoutlist)

Tramber · le 22 février 2006

Bon, j'ai bien regardé pcatalog, je le dis tout de suite, mieux vaut utiliser celui que je conseille, bien plus puissant.

Après, pour le script d'espionnage, je suis 1000 fois d'accord.

J'utilise ce scripteur à cet escient.

guibout · le 9 mars 2006

Bonjour

J'ai étudié vos réponses.

Je maitrise suffisamment Excel pour faire de la gestion dedans. Par contre, je débute en LISP

Voici le code que j'ai fait à l'aide d'exemples

[surligneur]

(defun c:dateagu ()

(setvar "cmdecho" 0)

(princ "\nTraitement en cours...")

(setq f (open (strcat (getvar "dwgname") ".ctl") "w"))

(princ "Fichier dessin: " f)

(princ (getvar "dwgname") f)

(princ "\n" f)

(princ "Taille : " f)

(princ (getvar "vl-file-size") f)

(princ "\n" f)

(princ "Date de création : " f)

(princ (getvar "TDCREATE") f)

(princ "\n" f)

(princ "Date du dernier enregistrement : " f)

(princ (getvar "TDUPDATE") f)

(princ "\n" f)

(princ "Temps passé :" f)

(princ (getvar "tdindwg") f)

(princ "\n" f)

(princ "Présentations :" f)

(princ (getvar "layoutlist") f)

(princ "\n" f)

(close f)

(princ "\nFin du traitement.")

(princ (strcat "\nLe fichier d'information se nomme: " (getvar "dwgname") ".CTL"))

(princ)

(princ "\n==> DATEAGU")

(princ)

) [/surligneur]

et voici le résultat

[surligneur]Fichier dessin: Relevé du 9-03-06.dwg

Taille : nil

Date de création : 2.45367e+006

Date du dernier enregistrement : 2.4538e+006

Temps passé :0.173179

Présentations :nil

[/surligneur]

Pourriez-vous m'aider sur les formats de dates ? et sur les extraits des présentations ? et éventuellement sur les tailles de fichiers avec la commandes vf-file-size ?

Merci

Cordialement

guibout · le 13 mars 2006

Bonjour,

Apreès de multiples essais, je suis enfin arrivé à faire un lisp correct.

Par contre, ce que je croyais facile sous excel, l'ai finalement pas si simple.

Je reviens vers vous LUDWING, pour savoir comment faire un script sous excel qui à chaque ligne du tableau excel contenant le CHEMIN et le NOM d'un fichier DWG, lance l'ouverture du fichier DWG, puis la commande du LISP, et enfin la fermeture du fichier DWG.

Merci

Tramber · le 13 mars 2006

Tout est dans la formule CONCATENER

Voir ici pour son usage.

Pour les chemins, remplacer le "\" par "\\" ou "/", c'est propre au langage AutoCAD

Patrick_35 · le 14 mars 2006

Salut

C'est juste pour te montrer ce qui est possible de faire. Maintenant, pour ce qui est indiqué dans la fenêtre de texte, il faudrait que tu m'indiques comment tu veux que je reporte les infos dans excel. Depuis un fichier avec le choix de la feuille ou depuis un classeur vierge ? Le nom du dwg en colonne A, la taille en colonne B, etc...

@+

(defun c:spy(/ disk_unit folder_name folder_list lst_str olderr rep sd)

 (defun err (msg / i n)
   (if (/= msg "Fonction annulée")
     (princ (strcat "\nErreur : " msg))
     (princ msg)
   )
   (setq *error* olderr)
   (princ)
 ) 

 (defun extract_folder (lst_fold / l_dir l)
   (setq l_dir '()) 
   (foreach n lst_fold
     (setq l (vl-directory-files n nil -1))
     (if (eq (car l) ".")
       (setq l (cddr l))
     )
     (cond
       (l
         (setq l_dir
           (append
             (mapcar
               '(lambda (x)
                  (strcat n x "/")
                )
                l
             )
             l_dir
           )
         )
       )
     )
   )
   l_dir
 )
 
 (defun donne_date(td / d j hh m mm ss time y)
   (setq time (* 86400.0 (- td (setq j (fix td)))))
   (setq j (- j 1721119.0))
   (setq y (fix (/ (1- (* 4 j)) 146097.0)))
   (setq j (- (* j 4.0) 1.0 (* 146097.0 y)))
   (setq d (fix (/ j 4.0)))
   (setq j (fix (/ (+ (* 4.0 d) 3.0) 1461.0)))
   (setq d (- (+ (* 4.0 d) 3.0) (* 1461.0 j)))
   (setq d (fix (/ (+ d 4.0) 4.0)))
   (setq m (fix (/ (- (* 5.0 d) 3) 153.0)))
   (setq d (- (* 5.0 d) 3.0 (* 153.0 m)))
   (setq d (fix (/ (+ d 5.0) 5.0)))
   (setq y (+ (* 100.0 y) j))
   (if (< m 10.0)
     (setq m (+ m 3))
     (progn  
       (setq m (- m 9))
       (setq y (1+ y))
     )
   )
   (setq hh (fix (/ time 3600.0)))
   (setq time (- time (* hh 3600.00)))
   (setq mm (fix (/ time 60.0)))
   (setq ss (- time (* mm 60.0)))
   (setq d (itoa (fix d)))
   (setq m (itoa (fix m)))
   (setq y (itoa (fix y)))
   (setq hh (itoa hh))
   (setq mm (itoa mm))
   (setq ss (itoa (fix ss)))
   (if (= (strlen d) 1)
     (setq d (strcat "0" d)))
   (if (= (strlen m) 1)
     (setq m (strcat "0" m)))
   (if (= (strlen hh) 1)
     (setq hh (strcat "0" hh)))
   (if (= (strlen mm) 1)
     (setq mm (strcat "0" mm)))
   (if (= (strlen ss) 1)
     (setq ss (strcat "0" ss)))
   (list (strcat d "." m "." y "   " hh ":" mm ":" ss) (strcat hh ":" mm ":" ss))
 )

 (defun rechercher(rep fichier / bl blc dess doc fic lsp lst rech)
   (if (setq lst (vl-directory-files rep fichier 1))
     (progn
(setq lsp (getvar "acadlspasdoc"))
(setvar "acadlspasdoc" 0)
(setq doc (vla-get-documents (vlax-get-acad-object)))
       (foreach fic lst
  (setq dess (vla-open doc (strcat rep fic)))
         (princ (strcat "\nTaille du fichier " (vl-string-translate "/" "\\" rep) fic " " (itoa (vl-file-size (strcat rep fic)))))
  (princ (strcat "\nDate de création "               (car  (donne_date (vlax-variant-value (vla-getvariable dess "tdcreate"))))))
  (princ (strcat "\nDate du dernier enregistrement " (car  (donne_date (vlax-variant-value (vla-getvariable dess "tdupdate"))))))
  (princ (strcat "\nTemps passé "                    (cadr (donne_date (vlax-variant-value (vla-getvariable dess "tdindwg" ))))))
         (princ "\nXref(s) associé(s)")
         (setq blc (vla-get-blocks dess))
         (vlax-for bl blc
           (if (eq (vla-get-isxref bl) :vlax-true)
             (princ (strcat "\n\t" (vla-get-name bl)))
           )
         )
         (princ "\nPrésentation(s) dans le dessin")
         (setq blc (vla-get-layouts dess))
         (vlax-for bl blc
           (if (not (eq (vla-get-name bl) "Model"))
             (princ (strcat "\n\t" (vla-get-name bl)))
           )
         )
  (vla-close dess)
)
(setvar "acadlspasdoc" lsp)
     )
   )
 )

 (vl-load-com)
 (setq olderr *error* *error* err)
 (setq sd (getvar "sdi"))
 (setvar "sdi" 0)
 (if (member "acetutil.arx" (arx))
   (setq folder_name (acet-ui-pickdir))
   (setq folder_name (getstring T "Répertoire de recherche : "))
 )
 (if folder_name
   (progn
     (if (not (eq (vl-string-elt folder_name (1- (strlen folder_name))) 92))
       (setq folder_name (strcat folder_name "\\"))
     )
     (setq folder_name (vl-string-translate "\\" "/" folder_name)
    folder_list (list folder_name)
           lst_str folder_list)
     (rechercher folder_name "*.dwg")
     (while (setq lst_str (extract_folder lst_str))
       (foreach rep lst_str
         (rechercher rep "*.dwg")
       )
     )
   )
 )
 (setvar "sdi" sd)
 (setq *error* olderr)
 (princ)
)

guibout · le 16 mars 2006

Bonjour

Pour information, voici le code LISP que j'ai fait :

(defun c:dateagu ()

(setvar "cmdecho" 0)

(princ "\nTraitement en cours...")

(setq f (open (strcat (getvar "dwgprefix")(getvar "dwgname") ".ctl") "w"))

(princ "Fichier dessin: " f)

(princ "\n" f) (princ (getvar "dwgname") f)

(princ "\n" f) (princ "Taille :" f)

(princ "\n" f) (princ (vl-file-size (strcat (getvar "dwgprefix")(getvar

"dwgname"))) f)

(princ "\n" f) (princ "Date de création : " f)

(princ "\n" f) (princ (menucmd "M=$(edtime,$(getvar,TDCREATE), DD/MO/YY -

HH:MM:SS)")f)

(princ "\n" f) (princ "Date du dernier enregistrement : " f)

(princ "\n" f) (princ (menucmd "M=$(edtime,$(getvar,tdupdate), DD/MO/YY -

HH:MM:SS)")f)

(princ "\n" f) (princ "Temps passé :" f)

(princ "\n" f) (princ (menucmd "M=$(edtime,$(getvar,tdindwg), HH:MM)")f)

(princ "\n" f) (princ "Présentations :" f)

(princ "\n" f) (princ (layoutlist) f)

(close f)

(princ "\nFin du traitement.")

(princ (strcat "\nLe fichier d'information se nomme: " (getvar "dwgname")

".CTL"))

(princ)

(princ "\n==> DATEAGU")

(princ)

)

Et voici le contenu du fichier (.ctl) construit par le LISP :

Fichier dessin:

Relevé du 9-03-06.dwg

Taille :

1723126

Date de création :

24/10/05 - 14:57:35

Date du dernier enregistrement :

16/03/06 - 10:33:13

Temps passé :

07:57

Présentations :

(Layout1 Présentation1 Présentation2 Présentation3)

Maintenant, je cherche à faire le traitement automatique par Excel. Je vois que ce n'est pas aussi simple que je ne le pensais.

Merci à vous pour cette étape en tout cas.

Cordialement

Wallas

Patrick_35 · le 16 mars 2006

Salut

Tu as essayé le lisp que je te propose ?

@+

guibout · le 16 mars 2006

Bonjour à tous et à Patrick_35

Je viens de l'essayer. Je n'ai pas sur mon poste autocad 2005 mais uniquement 2004LT. Je dois donc attendre la disponibilité du poste de mon collègue.

Sinon, cela fonctionne de façon impeccable.

Par contre, je cherche à savoir si les données sont enregistrées dans un fichier mais apparement non.

Je vais essayer de programmer cela en mettant une ligne par fichier et un point virgule entre chaque donnée de façon à pouvoir le reprendre dans un fichier excel (via peut être du CSV).

Pour info, j'ai eu une petite erreur sur un fichier nommé NOMFICHIER_Recover. J'ai supprimé le fichier et je vais refaire un essai.

Merci beaucoup.

Si jamais cela est simple pour toi de ramener ton LISP aux dispositions ci-dessus, je suis preneur évidement.

Je vais de tout façon repartir sur ton excellent travail.

Bonne journée

Wallas

Patrick_35 · le 16 mars 2006

Non, je n'envoi pas les info dans un fichier mais uniquement dans le fenêtre de texte. Les valeurs sont là et c'est ensuite pour pouvoir ensuite les écrire directement dans Excel et c'est pour cela que je passe pas par un fichier.

Je te posais aussi quelques questions, à moins que tu ne souhaites le faire toi-même grace au deux liens que je t'ai donné lors d'un autre post

@+

guibout · le 16 mars 2006

Bonjour,

Pour te répondre, Patrick_35, à terme je souhaite récupérer dans un fichier excel vierge les propriétés de mes 900 fichiers Excel de la façon suivante :

Colonne A : Chemin

Colonne B : Nom du répertoire

Colonne C : Taille du fichier

Colonne D : Date de création

Colonne E : Date de dernier enregistrement

Colonne F : Noms des XREF dans la même cellule avec un séparateur entre chaque Xref

Colonne G : Noms de Présentations dans la même cellule avec un séparateur entre chaque Présentations

Par contre, lors d'essais, apparement, j'ai vu apparaitre des dates de créations bizarres du style 1982.

Apres recherche, j'ai un fichier avec les propriétés suivantes :

Propriétés/Général

Auteur : 24/02/2006 - 09h26m01s

Modification : 05/01/05 - 09h50m40s

et

Propriétés/Statistiques

Crée le 2 janvier 1982 01h00m00s

ça, c'est pour l'anecdote car je ne vasi me mettre à chercher pourquoi nous avons ce genre d'erreur dasn les stats de nos fichiers.

Merci Patrick_35 de ton aide

Cordialement

Wallas

Patrick_35 · le 20 mars 2006

Salut

voici le lisp complet avec une liaison avec Excel. Le séparateur pour les xrefs et les présentations est le ;

@+

(defun c:spy(/ classeur disk_unit dossier feuille folder_name folder_list ligne lien_xl lst_str olderr rep sd xl)

 (defun err (msg / i n)
   (if (/= msg "Fonction annulée")
     (princ (strcat "\nErreur : " msg))
     (princ msg)
   )
   (setq *error* olderr)
   (princ)
 ) 

 (defun Liaison_Excel(/ Chemin_Excel Environ Version_Excel)
   (if (setq Chemin_Excel (vl-registry-read "HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\Windows\\CurrentVersion\\App Paths\\Excel.EXE" "Path"))
     (progn
       (foreach Environ (list "SYSTEMROOT" "WINDIR" "WINBOOTDIR" "SYSTEMDRIVE" "USERNAME" "COMPUTERNAME" "HOMEDRIVE" "HOMEPATH" "PROGRAMFILES")
         (if (vl-string-search (strcat "%" Environ "%") Chemin_Excel)
           (setq Chemin_Excel (vl-string-subst (strcase (getenv Environ)) (strcat "%" Environ "%") Chemin_Excel))
         )
       )
       (if (= (vl-string-elt Chemin_Excel (1- (strlen Chemin_Excel))) 92)
         (setq Chemin_Excel (strcat Chemin_Excel "Excel.exe"))
         (setq Chemin_Excel (strcat Chemin_Excel "\\Excel.exe"))
       )
       (cond
         ((findfile (vl-string-subst "Excel8.olb" "Excel.exe" Chemin_Excel))
           (setq Chemin_Excel (vl-string-subst "Excel8.olb" "Excel.exe" Chemin_Excel))
         )
         ((findfile (vl-string-subst "Excel9.olb" "Excel.exe" Chemin_Excel))
           (setq Chemin_Excel (vl-string-subst "Excel9.olb" "Excel.exe" Chemin_Excel))
         )
         ((findfile (vl-string-subst "Excel10.olb" "Excel.exe" Chemin_Excel))
           (setq Chemin_Excel (vl-string-subst "Excel10.olb" "Excel.exe" Chemin_Excel))
         )
       )
       (cond
         ((= (strcase (vl-filename-base (vl-filename-directory Chemin_Excel))) "OFFICE11")
           (setq Version_Excel "2003")
         )
         ((= (strcase (vl-filename-base (vl-filename-directory Chemin_Excel))) "OFFICE10")
           (setq Version_Excel "XP")
         )
         ((= (strcase (vl-filename-base Chemin_Excel)) "EXCEL8")
           (setq Version_Excel "97")
         )
         ((= (strcase (vl-filename-base Chemin_Excel)) "EXCEL9")
           (setq Version_Excel "2000")
         )
       )
       (if (not Version_Excel)
         (setq Chemin_Excel nil)
       )
     )
   )
   (list Chemin_Excel Version_Excel)
 )

 (defun extract_folder (lst_fold / l_dir l)
   (setq l_dir '()) 
   (foreach n lst_fold
     (setq l (vl-directory-files n nil -1))
     (if (eq (car l) ".")
       (setq l (cddr l))
     )
     (cond
       (l
         (setq l_dir
           (append
             (mapcar
               '(lambda (x)
                  (strcat n x "/")
                )
                l
             )
             l_dir
           )
         )
       )
     )
   )
   l_dir
 )
 
 (defun rng (col)
  (xlp-get-range feuille (strcat col (itoa ligne)))
 )

 (defun rechercher(rep fichier / bl blc dess doc fic lsp lst rech)
   (if (setq lst (vl-directory-files rep fichier 1))
     (progn
(setq lsp (getvar "acadlspasdoc"))
(setvar "acadlspasdoc" 0)
(setq doc (vla-get-documents (vlax-get-acad-object)))
       (foreach fic lst
  (setq dess (vla-open doc (strcat rep fic)))
         (xlp-put-value (rng "A") (vl-string-translate "/" "\\" rep))
         (xlp-put-value (rng "B") fic)
         (xlp-put-value (rng "C") (vl-file-size (strcat rep fic)))
         (xlp-put-numberformatlocal (rng "C") "# ##0")
         (xlp-put-value (rng "D") (- (vlax-variant-value (vla-getvariable dess "tdcreate")) 2415019))
         (xlp-put-numberformatlocal (rng "D") "jj/mm/aaaa   hh:mm:ss")
         (xlp-put-value (rng "E") (- (vlax-variant-value (vla-getvariable dess "tdupdate")) 2415019))
         (xlp-put-numberformatlocal (rng "E") "jj/mm/aaaa   hh:mm:ss")
         (xlp-put-value (rng "F") (vlax-variant-value (vla-getvariable dess "tdindwg")))
         (xlp-put-numberformatlocal (rng "F") "hh:mm:ss")
         (setq blc (vla-get-blocks dess) nom "Aucun")
         (vlax-for bl blc
           (if (eq (vla-get-isxref bl) :vlax-true)
             (if (eq nom "Aucun")
               (setq nom (vla-get-name bl))
               (setq nom (strcat nom ";" (vla-get-name bl)))
             )
           )
         )
         (xlp-put-value (rng "G") nom)
         (setq blc (vla-get-layouts dess) nom "Aucune")
         (vlax-for bl blc
           (if (not (eq (vla-get-name bl) "Model"))
             (if (eq nom "Aucune")
               (setq nom (vla-get-name bl))
               (setq nom (strcat nom ";" (vla-get-name bl)))
             )
           )
         )
         (xlp-put-value (rng "H") nom)
         (setq ligne (1+ ligne))
  (vla-close dess)
)
(setvar "acadlspasdoc" lsp)
     )
   )
 )

 (vl-load-com)
 (if (car (setq lien_xl (Liaison_Excel)))
   (progn
     (setq olderr *error* *error* err)
     (setq sd (getvar "sdi"))
     (setvar "sdi" 0)
     (if (member "acetutil.arx" (arx))
       (setq folder_name (acet-ui-pickdir))
       (setq folder_name (getstring T "\nRépertoire de recherche : "))
     )
     (if folder_name
       (progn
         (if (not (eq (vl-string-elt folder_name (1- (strlen folder_name))) 92))
           (setq folder_name (strcat folder_name "\\"))
         )
         (setq folder_name (vl-string-translate "\\" "/" folder_name)
        folder_list (list folder_name)
               lst_str folder_list)
         (if (setq Xl (vlax-get-or-create-object "Excel.Application"))
           (progn
             (princ (strcat "\nConnexion avec Excel " (cadr lien_xl)))
             (if (null xl-open)
               (vlax-import-type-library
                 :tlb-filename (car lien_xl)
                 :methods-prefix "xl-"
                 :properties-prefix "xlp-"
                 :constants-prefix "xlc-")
             )
             (setq xl_wks (vlax-get xl "Workbooks"))
             (setq dossier (vla-add xl_wks))
             (setq classeur (vlax-get dossier "Sheets"))
             (setq feuille (xlp-get-item classeur 1))
             (vla-put-visible xl 1)
             (setq ligne 1)
             (xlp-put-value (rng "A") "Chemin")
             (xlp-put-value (rng "B") "Fichier")
             (xlp-put-value (rng "C") "Taille")
             (xlp-put-value (rng "D") "Date de création")
             (xlp-put-value (rng "E") "Date du dernier enregistrement")
             (xlp-put-value (rng "F") "Temps du dessin")
             (xlp-put-value (rng "G") "Xref(s)")
             (xlp-put-value (rng "H") "Présentation(s)")
             (setq ligne 2)
           )
         )
         (rechercher folder_name "*.dwg")
         (while (setq lst_str (extract_folder lst_str))
           (foreach rep lst_str
             (rechercher rep "*.dwg")
           )
         )
       )
     )
     (setvar "sdi" sd)
     (setq *error* olderr)
   )
   (alert "Excel est introuvable")
 )
 (princ)
)

guibout · le 21 mars 2006

Bonjour

Un grand merci à Patrick_35 pour son travail

Je vais essayer dès aujourd'hui ce lisp.

Encore Merci.

Dernière chose, si je peux me permettre, il serait intéressant que Patrick_35 metre à disposition, si ce n'est déjà fait ce lisp sur les téléchargements.

Si tu veux, je peux le faire en ton nom.

Cordialement

Wallas

guibout · le 21 mars 2006

Bonjour,

J'ai fait un essai et voici le résultat dans la ligne de commande de AUTOCAD

Connexion avec Excel 2003

Erreur : Erreur Automation. Aucune description n'a été entrée.

AUTOCAD 2005

Excel 2003

Excel s'est bien ouvert sur un tableau vierge.

Je n'ai pas sur le PC les fichiers excel8.olb, excel9.olb et excel10.olb. Cela est-il un problème ?

Merci de m'indiquer comment je peux corriger le lisp.

Cordialement

Wallas

Patrick_35 · le 21 mars 2006

Salut

C'est surement dû à un problème de version d'excel. D'après ce post, il faut remplacer tous les "xlp-put-value" par "xlp-put-value2". Comme je n'ai pas la version 2003, je ne peux pas tester, mais ça fonctionne très bien sur mon Excel97. Si d'autres pouvait tester le prog avec différentes versions d'excel, ce serait sympa.

Et si tu veux le mettre à disposition le lisp, c'est comme tu le souhaites

@+

(gile) · le 21 mars 2006

Salut,

J'ai testé en l'état avec excel 2003 : même message d'erreur que Guibout.

Après avoir remplacé tous les xlp-put-value par xlp-put-value2 çà marche impécablement :D

Patrick_35 · le 21 mars 2006

Merci (gile) :cool:

C'est donc bien un souci de version (c'est quand même vicieux de changer value par value2 :mad: )

Donc avec 2003 et XP, il faut value2

Sur 97 seulement value

Reste à savoir pour la version 2000 :casstet:

@+

Connexion

Récupérations des propriétés des fichiers DWG

Messages recommandés

guibout

guibout

Tramber

PCL

LUDWIG

Tramber

guibout

guibout

Tramber

Patrick_35

guibout

Patrick_35

guibout

Patrick_35

guibout

Patrick_35

guibout

guibout

Patrick_35

(gile)

Patrick_35

Créer un compte ou se connecter pour commenter

Créer un compte

Se connecter

Forums

Naviguer

Activité

Information importante