Arc->Ellipse ou Arc->Cercle

[(gile)]

Cette routine convertit un arc elliptique en ellipse, un arc de cercle en cercle.

 

L'arc peut être sélectionné avant ou après le lancement de la commande.

 

(defun c:a2e (/ val_dxf set1 ent lst)
 ;;------------------------------------------------
 (defun val_dxf (code ent)
   (cdr (assoc code (entget ent)))
 )
 ;;------------------------------------------------
 (if (and (= 1 (getvar "pickfirst"))
   (setq set1 (ssget "_i" '((0 . "ARC,ELLIPSE"))))
   (eq 1 (sslength set1))
     )
   (progn
     (setq ent (ssname set1 0))
     (sssetfirst nil nil)
   )
   (progn
     (sssetfirst nil nil)
     (while (not
       (and
	 (setq ent
		(car (entsel "\nSélectionnez un arc: ")
		)
	 )
	 (or
	   (= (val_dxf 0 ent) "ARC")
	   (= (val_dxf 0 ent) "ELLIPSE")
	 )
       )
     )
     )
   )
 )
 (setq lst (entget ent))
 (cond
   ((= (val_dxf 0 ent) "ARC")
    (foreach code '(-1 0 330 5 100 50 51)
      (setq lst (vl-remove-if '(lambda (x) (= (car x) code)) lst))
    )
    (setq lst (cons '(0 . "CIRCLE") lst))
    (command "_regen")
    (entmake lst)
    (entdel ent)
   )
   ((= (val_dxf 0 ent) "ELLIPSE")
    (cond
      ((and (= (val_dxf 41 ent) 0.0)
     (= (val_dxf 42 ent) (* 2 pi))
)
(princ "\n L'ellipse est fermée.")
)
      (T
(setq lst (subst '(41 . 0.0) (assoc 41 lst) lst)
      lst (subst (cons 42 (* 2 pi)) (assoc 42 lst) lst)
)
(command "_regen")
(entmod lst)
(entupd ent)
      )
    )
   )
 )
 (princ)
)

 

PS : La conversion inverse (ellipse->arc ou cercle->arc) n'est pas encore tout à fait au point.

 

[Edité le 6/11/2005 par (gile)]