Problème d\'attributs

[Steven]

Salut,

 

J'ai un sousis avec certains attributs d'un bloc. En effet, j'ai un bloc avec plusieurs attributs qui sont sur des calques différents (Nom, prénom, matériel, bureau de départ, bureau d'arrivée, etc, etc). Le calques où se trouve les attributs Nom et Prénom est actif, visible, dévérouiller. La définition de ces attributs est faites en sorte qu'ils soient visibles.

 

1°) J'ai vérifier avec la commande battman pour être sûr que la définition est bien visible. C'est ok.

 

2°) J'ai redéfini le bloc en passant par la commande attredef et les noms et prénoms redeviennent visibles.

 

Cependant, lors de l'insertion de ce bloc, certains attribut ont été forcés au niveau de la police et de la taille et de l'orientation :mad: . ce qui fait que lorsque je redéfini le bloc, que ce soit par la commande battman ---> Synchroniser ou la commande attredef, ces dits attributs retrouvent leur police, leur taille et leur oientation d'origine. Forcement.

N'ayant pas vraiment le choix, j'ai donc opté pour redéfinir le bloc et de remettre ces putains d'attributs comme il étaient lors de l"ouverture du fichier et je me marre comme un petit fous sachant que j'ai un minimum de 150 à 200 personnes environ dans l'étage...

 

Néanmoins, n'existe-t-il pas un moyen pour faire en sorte de "re-rendre" visible les noms et prénoms sans devoir redénir le bloc et de tout se recogner à la main sans péter un câble?

 

Bien évidement, je ne peux pas faire la révolution au niveau des fichiers étant donné qu'ils ont été fait comme ça depuis des années et que ça pourrait entraîner d'autre conséquences au niveau d'un autre logiciel.

[Patrick_35]

Salut

Tu as la variable ATTMODE, au cas où

 

Sinon, je t'ai fait ce lisp que tu peux adapter

 

@+

 

(defun c:attvis(/ att bl n)
 (princ "\nSélectionnez un bloc de référence pour rendre tous ses attributs \nVisible/Non constant/Sans vérification et non prédéfini.")
 (if (setq bl (ssget "_+.:E:s" '((0 . "INSERT"))))
   (progn
     (setq bl (entget (ssname bl 0)))
     (if (/= (logand (cdr (assoc 70 (tblsearch "block" (cdr (assoc 2 bl))))) 4) 4)
       (if (cdr (assoc 66 bl))
         (progn
           (setq bl (ssget "_x" (list (cons 0 "INSERT") (assoc 2 bl))) n 0)
           (while (ssname bl n)
             (setq att (entget (ssname bl n)))
             (while (/= (cdr (assoc 0 att)) "SEQEND")
               (if (= (cdr (assoc 0 att)) "ATTRIB")
                 (progn
                   (setq att (subst (cons 70 0) (assoc 70 att) att))
                   (entmod att)
                   (entupd (cdr (assoc -1 att)))
                 )
               )
               (setq att (entget (entnext (cdr (assoc -1 att)))))
             )
             (setq n (1+ n))
           )
           (princ (strcat "\nModification de " (itoa n) " bloc(s)."))
         )
         (princ "\nCe bloc ne contient pas d'attributs.")
       )
       (princ "\nCe bloc est un xref.")
     )
   )
 )
 (princ)
)