chargement aligner

[argilles]

Bonjour à tous,

 

j'ai fais un petit programme ou j'utilise le commande aligner mais lors de la première utilisation la commande aligner n'est pas d'après AutoCAD " initialisé " me répond la machine.

Je pense que cela est dû car la commande aligner est une commande 3D.

 

Après avoir lancé la commande aligner toute seule, le programme marche.

 

Si quelqu'un a une piste pour charger la commande aligner dans un lisp son aide sera la bienvenue.

 

Merci d'avance par ce beau temps de soleil ou l'on a plus envie de sortir que de rester enfermé. Mais bon pensons à ce week-end pluvieux qui nous attends.

 

@+

[bonuscad]

Bonjour,

 

Un exemple où j'utilise la command _align

Tu verras façilement comment je m'assure dans le code pour que la fonction soit disponible

(defun c:Mult_Align ( / pt_o1 pt_o2 pt_d1 pt_d2)
(setvar "cmdecho" 0)
(if (not (member "geom3d.arx" (arx))) (arxload "geom3d.arx"))
(princ "\nChoisir les objets à aligner de façon multiple.")
(cond
	((ssget)
		(initget 9)
		(setq pt_o1 (getpoint "\n1er point origine: "))
		(initget 9)
		(setq pt_o2 (getpoint "\n2ème point origine: "))
		(initget 8)
		(while (setq pt_d1 (getpoint "\n1er point destination: "))
			(command "_.copy" "_previous" "" "*0.0,0.0,0.0" "*0.0,0.0,0.0")
			(initget 9)
			(setq pt_d2 (getpoint "\n2ème point destination: "))
			(command "_.align" "_previous" "" pt_o1 pt_d1 pt_o2 pt_d2 "" "_no")
			(setq
				pt_o2 (polar pt_d1 (angle pt_d1 pt_d2) (distance pt_o1 pt_o2))
				pt_o1 pt_d1
			)
			(initget 8)
		)
	)
	(T (princ "\nSélection vide!"))
)
(setvar "cmdecho" 1)
(princ)
)

[gile]

Salut,

 

La commande "align" est une commande définie extérieurement (traduction littérale) comme d'autres expliquées dans l'aide sous" AutoLISP references".

 

Il faut s'assurer de leur chargement :

 

(if (not (member "geom3d.arx" (arx)))
 (arxload "geom3d")
) 

On peut ensuite les utiliser avec la fonction "command" ou directement comme des fonctions AutoLISP :

 

(command "_align" obj "" pt1 pt2 pt3 pt4...) 

ou

 

(align obj "" pt1 pt2 pt3 pt4 ...) 

[argilles]

Je te remercie c'est exactement la chose qu'il me fallait, dire que j'avais ce petit soucis depuis un moment.

 

Je constate qu'il y a des bons que dis-je des très bons sur CAD-XP.

 

Merci beaucoup.