Modification point de base de bloc SANS déplacer le bloc déjà inséré une centaine de fois...

[angelique]

Hello !

Je suis chez un client dont les plans sont ... restons polis... 🙂

Les blocs sont fait n'importe comment, les points de base, aléatoires...

J'aimerais pouvoir changer le point de base d'un bloc sans qu'il se déplace dans le plan vu le nombre déjà inséré...

J'ai testé la commande BASE mais cela ne convient pas ...

Help Please !!!

[lecrabe]

Hello @angelique

Tu cherches la fameuse Routine Lisp "RINS" de notre regrette Patrick_35 !

Bye, lecrabe 

 

[vincentp010]

Salut,

 

J'ai fait une routine il y très longtemps pour le même problème

;###########################################################################
;# Copyright (C) 04-2011  Vincent PRELAT                                   #
;# This program is free software: you can redistribute it and/or modify	   #
;#  it under the terms of the GNU General Public License as published by   #
;#  the Free Software Foundation, either version 3 of the License, or      #
;#  any later version.                                                     #
;# This program is distributed in the hope that it will be useful,         #
;#  but WITHOUT ANY WARRANTY; without even the implied warranty of         #
;#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the          #
;#  GNU General Public License for more details.                           #
;# You should have received a copy of the GNU General Public License       #
;#  along with this program.  If not, see <http://www.gnu.org/licenses/>.  #
;###########################################################################

; Redefinit le point de base d'un bloc sans le deplacer

(vl-load-com)

;; getMatrixRot Retourne la matrice d'une rotation
(defun getMatrixRot (rot)
   (list
     (list (cos rot) (- (sin rot)) 0 0)
     (list (sin rot) (cos rot) 0 0)
     (list 0 0 1 0)
     (list 0 0 0 1)
    )
)

;; getMatrixEch Retourne la matrice d'une echelle
(defun getMatrixEch (ech)
   (list
     (list (nth 0 ech) 0 0 0)
     (list 0 (nth 1 ech) 0 0)
     (list 0 0 (nth 2 ech) 0)
     (list 0 0 0 1)
    )
)

;; getMatrixTranst Retourne la matrice d'une translation
(defun getMatrixTrans (trans)
   (list
     (list 1 0 0 (nth 0 trans))
     (list 0 1 0 (nth 1 trans))
     (list 0 0 1 (nth 2 trans))
     (list 0 0 0 1)
    )
)

;; mxv Apply a transformation matrix to a vector by Vladimir Nesterovsky
(defun mxv (m v)
  (mapcar '(lambda (row) (apply '+ (mapcar '* row v))) m)
)

;; Transpose une matrice Doug Wilson
(defun trp (m)
  (apply 'mapcar (cons 'list m))
)

;; mxm Multiply two matrices by Vladimir Nesterovsky
(defun mxm (m q)
  (mapcar (function (lambda (r) (mxv (trp q) r))) m)
)

;;; butlast Retourne la liste privée du dernier élément
(defun butlast (lst)
  (reverse (cdr (reverse lst)))
)

;; REMOVE-I
;; Retourne la liste privée de l'élément à l'indice spécifié (premier élément = 0)
;; Arguments : la liste et l'indice de l'élément à supprimer
(defun remove-i	(ind lst)
  (if (or (zerop ind) (null lst))
    (cdr lst)
    (cons (car lst) (remove-i (1- ind) (cdr lst)))
  )
)

;;; VXV Retourne le produit scalaire (réel) de deux vecteurs
(defun vxv (v1 v2)
  (apply '+ (mapcar '* v1 v2))
)

;; V^V (gile)
;; Retourne le produit vectoriel (vecteur) de deux vecteurs
;; Arguments : deux vecteurs
(defun v^v (v1 v2)
  (list (- (* (cadr v1) (caddr v2)) (* (caddr v1) (cadr v2)))
        (- (* (caddr v1) (car v2)) (* (car v1) (caddr v2)))
        (- (* (car v1) (cadr v2)) (* (cadr v1) (car v2)))
  )
)

;; M+M
;; Additionne 2 matrices
;; Arguments : deux matrices
(defun m+m (m1 m2)
  (mapcar '(lambda (v1 v2) (mapcar '+ v1 v2)) m1 m2)
)

;; MXS
;; Multiplie une martice par un nombre
;; Arguments : une matrice et un nombre
(defun mxs (m s) (mapcar '(lambda (v) (vxs v s)) m))

;; IMAT
;; Crée une matrice d'identité de dimension n
;; Argument
;; n : la dimension de la matrice
(defun Imat (d / i n r m)
  (setq i d)
  (while (<= 0 (setq i (1- i)))
    (setq n d r nil)
    (while (<= 0 (setq n (1- n)))
      (setq r (cons (if (= i n) 1.0 0.0) r))
    )
    (setq m (cons r m))
  )
)

;; INVERSEMATRIX
;; Inverse une matrice carrée (méthode Gauss-Jordan)
;; Argument: la matrice
;; Retour : la matrice inverse ou nil (si non inversible)
(defun InverseMatrix (mat / col piv row res)
  (setq	mat (mapcar '(lambda (x1 x2) (append x1 x2)) mat (Imat (length mat))))
  (while mat
    (setq col (mapcar '(lambda (x) (abs (car x))) mat))
    (repeat (vl-position (apply 'max col) col)
      (setq mat (append (cdr mat) (list (car mat))))
    )
    (if	(equal (setq piv (caar mat)) 0.0 1e-14)
      (setq mat	nil
	    res	nil
      )
      (setq piv	(/ 1.0 piv)
	    row	(mapcar '(lambda (x) (* x piv)) (car mat))
	    mat	(mapcar
		  '(lambda (r / e)
		     (setq e (car r))
		     (cdr (mapcar '(lambda (x n) (- x (* n e))) r row))
		   )
		  (cdr mat)
		)
	    res	(cons
		  (cdr row)
		  (mapcar
		    '(lambda (r / e)
		       (setq e (car r))
		       (cdr (mapcar '(lambda (x n) (- x (* n e))) r row))
		     )
		    res
		  )
		)
      )
    )
  )
  (reverse res)
)

(defun c:insredef (/ ent bl rot ech invech ptnouv ptins vect vect2 mat matrot matech debut nb nb1 allbl pt n i namebl)
   (setvar "cmdecho" 0)
   (command "_.undo" "_m")

   (setq ent (car (entsel "Selectionner le bloc a modifier :")))
   (if (/= ent nil) 
    (progn
     (setq bl (cdr (assoc 2 (entget ent))))
     ;; Calcul du vecteur de deplacement dans le scu du bloc
     (setq ptins (cdr (assoc 10 (entget ent))))
     (setq rot (cdr (assoc 50 (entget ent))))
     (setq ech (list
      (cdr (assoc 41 (entget ent)))
      (cdr (assoc 42 (entget ent)))
      (cdr (assoc 43 (entget ent)))
     ))
     (vla-highlight (vlax-ename->vla-object ent) :vlax-true)
     (setq ptnouv (getpoint "Pointez le nouveau point de base du bloc :"))
     (vla-highlight (vlax-ename->vla-object ent) :vlax-false)
     (setq ptnouv (trans ptnouv 1 0))
     
     (setq vect (mapcar '(lambda (x y) (- y x)) ptins ptnouv))
     (setq invech (mapcar '(lambda (x) (/ 1 x)) ech))
     (setq matech (getMatrixEch invech))
     (setq matrot (getMatrixRot (- rot)))
     (setq mat (mxm matech matrot))
     (setq vect (butlast (mxv mat vect)))
     ;;_fin calc vect dep
     
     ;; Modif definition du bloc
     (setq debut 1)
     (while (/= namebl bl)
       (setq i (tblnext "block" debut) debut nil)
       (setq namebl (cdr (assoc 2 i)))
     )
     (if (/= i nil) (progn
       (setq n (cdr (assoc -2 i)))
       (while n
         (if (and (/= (cdr (assoc 0 (entget n))) "VERTEX") (/= (cdr (assoc 0 (entget n))) "COVAPTSEL"))
           (vla-move (vlax-ename->vla-object n) (vlax-3d-point (list 0.0 0.0 0.0)) (vlax-3d-point (mapcar '(lambda (x) (- x)) vect)))
         )
         (setq n (entnext n))
         (if (/= n nil) 
          (if (= (cdr (assoc 0 (entget n))) "SEQEND") (setq n nil))
         )
       ) ;_while
     )) ;_if
     ;; Fin modif bloc
     
     ;; Deplace les blocs
     (setq allbl (ssget "x" (list (cons 2 bl))))
     (setq nb 0 nb1 (sslength allbl))
     (while (< nb nb1)
       (setq ent (ssname allbl nb))
       (setq ptins (cdr (assoc 10 (entget ent))))
       (setq rot (cdr (assoc 50 (entget ent))))
       (setq ech (list
        (cdr (assoc 41 (entget ent)))
        (cdr (assoc 42 (entget ent)))
        (cdr (assoc 43 (entget ent)))
       ))
       (setq matech (getMatrixEch ech))
       (setq matrot (getMatrixRot rot))
       (setq mat (mxm matech matrot))
       (setq vect2 (butlast (mxv mat vect)))
       (setq pt (mapcar '(lambda (x y) (+ x y)) ptins vect2))
       (entmod (subst (cons 10 pt) (assoc 10 (entget ent)) (entget ent)))
       (setq nb (+ nb 1))
     )
     ;; Fin deplace blocs
   )) ;;_if (/= ent nil)
)

 

[Steven]

Bonjour  @angelique,

 

Voici le lisp, RINS, de Patrick_35, et le lisp INSEDIT, de Gile.😉

Les 2, font le job 😀

INSEDIT.zip RINS_V320.7z

[angelique]

Il y a 2 heures, lecrabe a dit :

Hello @angelique

Tu cherches la fameuse Routine Lisp "RINS" de notre regrette Patrick_35 !

Bye, lecrabe 

 

Merci beaucoup Steven ! C'est parfait !!!!! J'ai une 50ene de plans à faire, ça va bien m'aider !!!!!