[RESOLU] Dissocier des groupes

[William44850]

Bonjour,

J'ai hérité d'un DWG avec plusieurs centaines de groupes au lieu d'avoir des blocs. Il va me falloir les recréer

Y a t'il une fonction, un lisp ou un script qui permette de dissocier en masse ? La fonction "DISSOCIERGROUPE" ne me permet que de le faire 1 par 1

Je vous remercie.

[Flower0f]

ne peux tu pas utiliser "décomposer" sur les groupes ?

 

[William44850]

il y a 2 minutes, Flower0f a dit :

ne peux tu pas utiliser "décomposer" sur les groupes ?

 

Ah bah non...ça ne marche pas.

c'eût été trop simple.

[lecrabe]

Hello @William44850

SVP tu testes cette routine Lisp "DG" et tu nous dis ...

Bye, lecrabe

 

;;
;; http://cadxp.com/index.php?/topic/35771-del-all-groups-ene-fonctionne-pas-avec-autocad-2013/page__pid__194692#entry194692
;;
;; Routine pour remplacer Dell_All_Groups.lsp qui semble ne pas fonctionner avec AutoCAD 2013
;;
;; Decompose les groupes auxquels appartiennent les objets selectionnes.
;;
;; Brice Studer, ocobre 2011
;;

(defun c:DG (/ *error* acdoc groups ss i gl)


(vl-load-com)
(setq   acdoc (vla-get-activedocument (vlax-get-acad-object))
        groups (vla-get-groups acdoc)
)

(defun *error* (msg)
  (and msg
    (or
      (member (strcase msg) '("FUNCTION CANCELLED" "QUIT / EXIT ABORT" "FONCTION ANNULEE" "QUITTER / SORTIR ABANDON"))
      (princ (strcat "\nErreur : " msg))
    )
  )
  (if ss (setq ss nil))
  (vla-endundomark acdoc)
  (princ)
)

(vla-startundomark acdoc)

(princ "\nSelectionnez les groupes a decomposer <entree pour tous> : ")
(if (setq ss (ssget))
  (progn
    (setq i 0)
    (repeat (sslength ss)
      (mapcar
        '(lambda (x)
          (and
            (= 330 (car x))
            (= (cdr (assoc 0 (entget (cdr x)))) "GROUP")
            (or
              (member (cdr x) gl)
              (setq gl (cons (cdr x) gl))
            )
          )
        )
        (entget (ssname ss i))
      )
      (setq i (1+ i))
    )
    (foreach g gl
      (entdel g)
    )
  )
  (vlax-for g groups
    (setq gl (cons g gl))
    (vla-delete g)
  )
)

(princ (strcat "\n" (itoa (length gl)) " groupes decomposes !"))
(*error* nil)
(princ)
)

(princ "\nCommande a utiliser : DG")
(princ)

 

[Olivier Eckmann]

Bonjour,

 

Les groupes n'existent que dans le dessin courant. Copier/coller tous objets dans un dessin vierge supprime tous les groupes.

 

Olivier

[William44850]

@lecrabe, le LISP fonctionne parfaitement. Merci beaucoup.

@Olivier Eckmann, je le saurais pour une prochaine fois...même si je ne la souhaite pas

Merci à tous les 2. Bonne fin de journée.