Sélection d'une fenetre spécifique (viewport) dans une présentation (layout)

[Iu63]

Bonjour,

J'ai un problème avec la sélection d'une fenêtre (parmi 3) dans un layout via lisp. En effet à chaque fois, il vient me sélectionner la même fenêtre ( peut importe que je mette viewport 1,2, ou 3 etc...) cependant il comprend bien qu'il y a plusieurs fenêtres.

voici le lisp :
 

(defun c:select-vp ()
  ;; Sélectionner tous les viewports dans le layout actif
  (setq ss (ssget "X" (list (cons 0 "VIEWPORT")
                            (cons 410 (getvar "CTAB")))))
 
  (if ss
    (progn
      (setq num (sslength ss))
      (princ (strcat "\nNombre de viewports trouvés : " (itoa num)))

      ;; Demander à l'utilisateur de choisir un viewport
      (setq vp-index (getint (strcat "\nSélectionnez un viewport (1-" (itoa num) ") : ")))

      ;; Vérifier si l'index est valide
      (if (and vp-index (> vp-index 0) (<= vp-index num))
        (progn
          ;; Définir le viewport actif
          (setvar "CVPORT" vp-index)
          (princ (strcat "\nViewport " (itoa vp-index) " activé."))

          ;; Passer en espace objet
          (command "_MSPACE")
        )
        (princ "\nIndex invalide.")
      )
    )
    (princ "\nAucun viewport trouvé.")
  )
  (princ)
)

 

[(gile)]

Salut

Pour qu'une valeur supérieure à 1 passée à CVPORT soit prise en compte, il faut appeler la commande _MSPACE avant d' modifier la valeur de CVPORT.

Si la valeur de CVPORT est égale à 1 c'est le viewport de la présentation qui est actif, autrement dit, on est en espace papier.

(defun c:select-vp (/ ss num vp-index)
  ;; Sélectionner tous les viewports dans le layout actif
  (setq ss (ssget "X" (list (cons 0 "VIEWPORT")
                            (cons 410 (getvar "CTAB")))))
 
  (if ss
    (progn
      (setq num (sslength ss))
      (princ (strcat "\nNombre de viewports trouvés : " (itoa num)))

      ;; Demander à l'utilisateur de choisir un viewport
      (setq vp-index (getint (strcat "\nSélectionnez un viewport (1-" (itoa num) ") : ")))

      ;; Vérifier si l'index est valide
      (if (and vp-index (> vp-index 0) (<= vp-index num))
	(progn
	  (if (= vp-index 1)
	    (command-s "_PSPACE")
	    (progn
	      ;; Passer en espace objet
	      (command-s "_MSPACE")

	      ;; Définir le viewport actif
	      (setvar "CVPORT" vp-index)
	      (princ (strcat "\nViewport " (itoa vp-index) " activé."))
	    )
	  )
	)
        (princ "\nIndex invalide.")
      )
    )
    (princ "\nAucun viewport trouvé.")
  )
  (princ)
)

 

[Iu63]

Merci pour ton retour, cependant, il y a encore des présentations ou cela ne fonctionne pas, voici ce que me renvoie autocad :

Commande: SELECT-VP
Nombre de viewports trouvés : 2
Sélectionnez un viewport (1-2) : 1 (ici que je mette 1 ou 2 j'ai toujours le même viewport de sélectionné qui correspond au dernier viewport sur lequel je suis allé)

Je precise que sur ma page de presentation(layout)j'ai deux viewport (2 fenêtres de presentation)

Exemple : admettons que je rentre dans l’espace objet du viewport 2 manuellement sur autocad, lorsque je vais lancer la commande, même si je spécifie 1, il va me sélectionner le 2 ème viewport.
Y'a t'il un moyen de forcer le truc avec ActiveX ou autre chose ?

[(gile)]

Utilises-tu le code que j'ai posté ?

Parce que si tu as créé deux fenêtres flottantes dans ta présentation, le nombre de viewports trouvés devrait être 3 (la fenêtre de la présentation (N° 1) et les fenêtres flottantes (N° 2 et N° 3).

Si tu veux que la routine ne prenne pas en compte la fenêtre de la présentation, tu peux faire comme ça :

(defun c:select-vp (/ ss num vp-index)
  ;; Sélectionner tous les viewports dans le layout actif
  (setq	ss (ssget "X"
		  (list	(cons 0 "VIEWPORT")
			(cons 410 (getvar "CTAB"))
		  )
	   )
  )

  (if ss
    (progn
      (setq num (- (sslength ss) 1))
      (princ (strcat "\nNombre de viewports trouvés : " (itoa num)))

      ;; Demander à l'utilisateur de choisir un viewport
      (setq vp-index (getint (strcat "\nSélectionnez un viewport (1-" (itoa num) ") : ")))

      ;; Vérifier si l'index est valide
      (if (and vp-index (<= 1 vp-index num))
	(progn

	  ;; Passer en espace objet
	  (if (= (getvar 'cvport) 1)
	    (command-s "_MSPACE")
	  )

	  ;; Définir le viewport actif
	  (setvar "CVPORT" (+ vp-index 1))
	  (princ (strcat "\nViewport " (itoa vp-index) " activé."))
	)
	(princ "\nIndex invalide.")
      )
    )
    (princ "\nAucun viewport trouvé.")
  )
  (princ)
)

 

[Iu63]

En effet il trouve bien 3 viewports cependant, lorsque je spécifie viewport 2 ou viewport 3, il me sélectionne toujours le même. Est ce que cela vient du fait que en amont, j'ai copier le viewport 1 que je suis venu coller juste à coté pour obtenir mes 2 fenêtres ?

Je crois savoir d’où vient le problème. En fait quand je vais faire "créer une nouvelle présentation" puis que je vais copier coller la fenêtre déjà présente, cela fonctionne, il m'identifie bien quel viewport est le 2 ou 3. (sachant que le 1 est bien le viewport de la presentation)
Cependant dans mon cas, je vais créer une nouvelle présentation puis SUPPRIMER le viewport présent, pour ensuite recréer deux fenêtres. Et je pense que le fait de supprimer le viewport de base présent (donc le vp 2) me pertube l’identification du bon viewport.
 

Modifié il y a 2 heures par Iu63

[(gile)]

Même avec une fenêtre copiée les deux routines que j'ai données fonctionnent chez moi. La seule raison que je vois pour que ce soit toujours la dernière fenêtre active qui soit sélectionnées serait que l'appel à (command "_MSPACE") intervienne après le (setvar "CVPORT" ...).

Comme dit plus haut, il faut d'abord passer en espace objet (si on est en espace papier, autrement dit, si CVPORT est égal à 1) et seulement ensuite spécifier la fenêtre active avec la variable système CVPORT.

[Iu63]

J'ai trouvé une solution qui marche mais je n'arrive pas à la faire fonctionner. Cela serait de redéfinir les coordonnées des 4 points du rectangle du viewport, pour ainsi placer le viewport au bon endroit, au fait merci de prendre le temps de me répondre gile.

J'ai testé cela mais en vain :

 

(defun c:etirer-vp2 ()
  (command "_PSPACE")  ; Passer en espace papier
  (princ "\nPassage en espace papier...")

  ;; Sélectionner tous les viewports du layout actif
  (setq ss (ssget "X" (list (cons 0 "VIEWPORT") (cons 410 (getvar "CTAB")))))
  (if ss
    (princ (strcat "\nNombre de viewports trouvés : " (itoa (sslength ss))))
    (princ "\nAucun viewport trouvé.")
  )

  (if (and ss (> (sslength ss) 1))  ; Vérifier qu'il y a au moins deux viewports
    (progn
      (princ "\nSélection du viewport 2...")
      (setq vp2 (ssname ss 1))  ; Récupérer le viewport 2

      (if vp2
        (progn
          (princ "\nViewport 2 trouvé ! Redéfinition des coordonnées...")

          ;; Obtenir les données du viewport 2
          (setq vp2data (entget vp2))
          
          ;; Extraire les points actuels du viewport (c'est le cadre du viewport)
          (setq vp2pts (cdr (assoc 10 vp2data)))  ; Extraction des points du viewport

          ;; Si les points sont disponibles, on peut redéfinir les coordonnées
          (if vp2pts
            (progn
              ;; Définir les nouvelles coordonnées pour chaque coin du rectangle
              ;; Par exemple, supposons que vous voulez les définir manuellement :
              (setq new-pt1 (list 0 0))  ; Nouveau coin inférieur gauche
              (setq new-pt2 (list 250 0))  ; Nouveau coin inférieur droit
              (setq new-pt3 (list 250 200))  ; Nouveau coin supérieur droit
              (setq new-pt4 (list 0 200))  ; Nouveau coin supérieur gauche

              ;; Appliquer les nouvelles coordonnées avec la commande _CVPORT
              (command "_CVPORT" (car new-pt1) (cadr new-pt1) (car new-pt3) (cadr new-pt3))

              (princ "\nLes coordonnées du viewport ont été redéfinies avec succès !")
            )
            (princ "\nLes points du viewport ne sont pas disponibles.")
          )
        )
        (princ "\nImpossible d'obtenir le viewport 2.")
      )
    )
    (princ "\nImpossible de trouver le viewport 2 (moins de deux viewports présents).")
  )

  (princ)
)


Il me renvoie cela : Commande: ETIRER-VP2
Passage en espace papier...
Nombre de viewports trouvés : 2
Sélection du viewport 2...
Viewport 2 trouvé ! Redéfinition des coordonnées...
Impossible de mettre CVPORT à cette valeur.
*Incorrect*