[Résolu] Existe-t-il un moyen de sélectionner un répertoire ?

[DenisHen]

Bonjour à la communauté.
Il existe le (getfiled pour sélectionner un fichier dans une fenêtre de navigation.
Mais comment faire pour sélectionner un répertoire sans fichier ?
Denis...

[(gile)]

Salut,

getfolderdlg extrait de Dialog sur cette page.

;; getfolderdlg
;; Boite de dialogue pour choisir un dossier
;;
;; Arguments
;; msg : message à afficher dans la boite
;; newFolder : affiche le bouton "Créer un nouveau dossier" si non nil

(defun getfolderdlg (msg newFolder / shell folder self path)
  (or *acad* (setq *acad* (vlax-get-acad-object)))
  (vl-catch-all-apply
    '(lambda (flag)
       (and
         (setq shell (vla-getinterfaceobject *acad* "shell.application"))
         (setq folder (vlax-invoke-method shell 'browseforfolder (vla-get-HWND *acad*) msg flag))
         (setq self (vlax-get-property folder 'self))
         (setq path (vlax-get-property self 'path))
       )
     )
    (if newFolder
      '(0)
      '(512)
    )
  )
  (foreach obj (list self folder shell)
    (and obj (vlax-release-object obj))
  )
  path
)

 

[DenisHen]

Salut @(gile) et un grand merci à toi.
Je ne sais pas pourquoi j'étais passé à coté, je m'aide pourtant très souvent de tes routines...