Récupération de la description d'un calque

[afipl]

Bonjour,

L'un d'entre vous aurait il une routine Lisp pour récupérer le texte de description d'un calque ?

Merci pour vos réponses, Cordialement

[lecrabe]

Hello @afipl

1) Tu trouveras ci-joint une routine Lisp "LAYER_LEGEND_DESCR" qui dessine

-- N Lignes horizontales avec la couleur par defaut du Calque concerne

-- N Textes avec le Nom du Calque ET la Description du Calque

2) La routine permet de traiter soit TOUT le DWG, soit une selection classique ...

3) En esperant que cela te convienne !?

Bon Dimanche, La sante, Bye, lecrabe

PS: extraction de mon stock de 3001 routines ...

 

;; 
;; Routine: Layer_Legend_Descr by Ranjit.Singh for Patrice B.
;;
;; ATTENTION: No Error Trap/Detection, so please be careful !
;; 

(vl-load-com) 

(defun c:Layer_Legend_Descr  (/ pt rsp dat ln lst desln)
 (initget "All Select")
 (setq pt (getpoint "\nSelect Insertion Point: "))
 (initget "Select All")
 (setq rsp (getkword "\nSpecify Option [Select / All] <All>:"))
 (cond ((= rsp "Select")
        (mapcar '(lambda (x) (setq pt (func_2 pt x)))
                (progn (acad_strlsort (mapcar '(lambda (x) (and (null (member x lst)) (setq lst (cons x lst))))
                                              (mapcar '(lambda (x) (cdr (assoc 8 (entget x))))
                                                      (vl-remove-if 'listp (mapcar 'cadr (ssnamex (ssget)))))))
                       lst)))
       (t (while (setq dat (tblnext "layer" (null dat))) (setq pt (func_2 pt (cdr (assoc 2 dat)))))))
 (princ)) 

(defun func_2  (pt ln / desln)
 (entmake (list '(0 . "line") (cons 10 pt) (cons 11 (mapcar '+ pt '(2.5 0))) (cons 8 ln)))
 (entmake (list '(0 . "text") (cons 10 (mapcar '+ pt '(3.0 0))) '(40 . 0.1) (cons 1 ln) (cons 8 ln)))
 (if (zerop (strlen (setq desln (getpropertyvalue (tblobjname "layer" ln) "Description"))))
  ()
  (entmake (list '(0 . "text") (cons 10 (mapcar '+ pt '(4.5 0))) '(40 . 0.1) (cons 1 desln) (cons 8 ln))))
 (mapcar '- pt '(0 0.15))
)

 

[afipl]

Merci beaucoup, @lecrabe

C'est exactement ce que je cherchais. Si tu en as d'autres, je suis preneur 😉