Créer calque

[LUDWIG]

Bonjour,

 

Juste pour savoir s'il est possible de créer un calque sans passer par

 command "._layer" "n"...

en utilisant "entmake par exemple. J'ai essayé :

 (entmake (list (cons 0 "layer")(cons 2 "toto")(cons 70 0)(cons 62 7)(cons 6 "Continuous")))

mais ça ne marche pas

[bonuscad]

Une méthode plus sure.

(make_layer "toto") crer un calque toto avec la couleur 7 et type de ligne "Continuous" en s'assurant qu'il n'existe déjà!

 

(defun make_layer (name / )
    (if (not (tblsearch "LAYER" name))
      (entmake	(append
	  '((0 . "LAYER")
	  (100 . "AcDbSymbolTableRecord")
	  (100 . "AcDbLayerTableRecord"))
	  (list (cons 2 name))
	  '((70 . 0)
	  (62 . 7)
	  (370 . -3)
	  (6 . "Continuous")
	 ))
      )
    )
)

[BIM G CO]

essaye avec tblobjname à la place de tblsearch ca marche pas mal aussi

 

[Edité le 22/4/2005 par Maximilien]

[Patrick_35]

Salut

En vlisp et je te décompose la démarche

 

(setq a (vlax-get-acad-object)) ; je pointe sur l'application Autocad
(setq b (vla-get-activedocument a)) ; Je pointe sur le dessin actif de l’application
(setq c (vla-get-layers b)) ; je pointe dans la table des calques du dessin actif
(setq d (vla-add c "MON_CALQUE")) ; je crée mon calque dans la table des calques

 

Et si tu veux modifier des paramètres du calque "MON_CALQUE", c'est dans la variable d (geler avec (vla-put-freeze d :vlax-true) par exemple)

 

@+

[LUDWIG]

Merci à tous !

[DenisHen]

(setq d (vla-add c "MON_CALQUE")) ; je crée mon calque dans la table des calques

 

Mais je ne trouve aucune aide sur (vla-add... Comment faire pour l'utiliser pour créer un typede ligne ?

 

Denis...

[Patrick_35]

Salut

Je vais te donner la marche à suivre

(setq a (vlax-get-acad-object)) ; Je pointe sur Autocad

un (vlax-dump-object a t) me renseigne sur ce qu'il est possible de faire (un f2 dans l'interface vba donne plus de renseignements)

Les Méthodes prises en charge permettent un vla-eval sion, c'est un vla-get ou vla-put

Un (setq b (vla-get-activedocument a)) me donne le dessin courant

un (setq c (vla-get-linetypes b)) me donne kla table des type de ligne

Je sent que ton interêt commence à se faire pressant ;)

un (setq d (vla-item c 3)) me donne un type de ligne

Logiquement, après un (vlax-dump-object d) cela me dit comment créer mes types de lignes mais je pense qu'un (vla-load c "Maligne" "Mon_Fichier.lin") est plus approprié

 

@+

[DenisHen]

mais je pense qu'un (vla-load c "Maligne" "Mon_Fichier.lin") est plus approprié

 

Pourquoi ? Je ne veux justement pas de fichier lin, je ne voulais pas gérer un type d'erreur "si ce type de ligne existe déjà"...

 

Moins on donne la possibilité de faire d'erreurs, moins on a à les gérer...

 

Merci pour ta réponse... Mais c'est normale qu'il n'y a rien dans l'aide ?

 

Denis...