aligner les textes de cotation en modifiant les propriétés des coordonnées du texte

[francinez]

Bonsoir

Lors du la mise en page, mes cotations sont souvent insivibles dans mes fenêtres, est-il possible de d'aligner les textes de cotation par rapport a une cote existante?

J'y arrive manuellement en modifiant les propriétés des coordonnées du texte. Je cherche a automatiser cette etape, est-ce possible avec un lisp?

Merci de votre aide

Dimension.dwg

[Invité francinez]

J'ai trouvé un exemple de lisp sur le forum Autodesk  ca fonctionne bien mais seulement si les cotes sont horizontales. Y a-t'il  une solution pour que ca fonctionne verticalement?

https://forums.autodesk.com/t5/autocad-forum/lisp-routine-to-slide-dimension-text/td-p/5189789

 

[La Lozère]

Bonjour,

En fait, tes lignes de côtes ne sont pas invisible das tes fenêtres, c'est juste que tes fenêtres ne couvrent pas la position de ta côte car celles-ci n'apparaissent pas entièrement dans la fenêtre. Tes côtes sont bien comme il faut centrées sur la ligne de côtes tel que défini dans le style.

A part manuellement, tu peux modifier ton style de côte pour avoir par défaut ton texte du côté ligne d'attache 1 ou ligne d'attache 2.

[Invité francinez]

Bjr, 

Merci pour votre réponse,

Je sais que mes côtes sont bien là en arrière plan et en temps normal j'utilise la commande permettant d'attacher les côtes a une ligne de côte.

C'est simplement une situation qui arrive couramment et je me suis posée la question comment simplifier cette tache. Surtout que je le fais en 3 étapes, je côte avec mon style standard, je bouge la côte a une extremité puis je redéplace la côte car elle se trouve trop près de la ligne de côte.

J'ai testé le lisp, c'est exactement ce que je recherche, mais c'est dommage car ca ne fonctionne que pour des côtes horizontales.

[PHILPHIL]

HELLO

trois petit lisp

coc : remet le texte de cote au centre

cog : met le texte de cote a gauche intérieur de la cote ( depend de la création de cote de gauche a droite ou de droite a gauche )

cod : met le texte de cote a droite intérieur de la cote ( depend de la création de cote de gauche a droite ou de droite a gauche )

a+

Phil
 

(defun c:coc ()
  (setvar "cmdecho" 0)
  (setvar "PICKSTYLE" 0)
  (setq osm (getvar "osmode"))
  (prompt "\nCLIQUER SUR LES OBJETS COTES A MODIFIER, TEXTE AU CENTRE:")
  (setq entites nil)
  (while (null entites) (setq entites (ssget '((0 . "DIMENSION")))))
  (setvar "osmode" 0)
  (setq compt 0)
  (setq com (sslength entites))
  (while (< compt com)
    (progn (setq obj (ssname entites compt)) (command-s "_dimtedit" obj "c") (setq compt (1+ compt)))
    (setvar "osmode" osm)
    (princ)
    )
  )

(defun c:cod ()
  (setvar "cmdecho" 0)
  (setvar "PICKSTYLE" 0)
  (setq osm (getvar "osmode"))
  (prompt "\nCLIQUER SUR LES OBJETS COTES A MODIFIER, TEXTE INTERIEUR DROIT :")
  (setq entites nil)
  (while (null entites) (setq entites (ssget '((0 . "DIMENSION")))))
  (setvar "osmode" 0)
  (setq compt 0)
  (setq com (sslength entites))
  (while (< compt com)
    (progn (setq obj (ssname entites compt)) (command-s "_dimtedit" obj "d") (setq compt (1+ compt)))
    (setvar "osmode" osm)
    (princ)
    )
  )

(defun c:cog ()
  (setvar "cmdecho" 0)
  (setvar "PICKSTYLE" 0)
  (setq osm (getvar "osmode"))
  (prompt "\nCLIQUER SUR LES OBJETS COTES A MODIFIER, TEXTE INTERIEUR GAUCHE  :")
  (setq entites nil)
  (while (null entites) (setq entites (ssget '((0 . "DIMENSION")))))
  (setvar "osmode" 0)
  (setq compt 0)
  (setq com (sslength entites))
  (while (< compt com)
    (progn (setq obj (ssname entites compt)) (command-s "_dimtedit" obj "g") (setq compt (1+ compt)))
    (setvar "osmode" osm)
    (princ)
    )
  )

 

 

 

[francinez]

J'aimerai pouvoir choisir moi-même l'emplacement des cotations, et comme déjà indiqué le lisp trouvé me conviendrait parfaitement si cela fonctionnerait aussi avec les cotations verticales.

tt.lsp

[francinez]

j'ai trouvé cette video qui decrit exactement ce que je recherche, mais le lisp qui y est rattaché est un lisp protégé (vlx) dont la commande DTA ne fonctionne pas

 

 

[(gile)]

Salut Francine,

Ceci devrait répondre à ta demande :

(defun c:FRANCINE (/ ss i lst rot pt p)
  (if (setq ss (ssget '((0 . "DIMENSION") (-4 . "<NOT") (-4 . "&") (70 . 7) (-4 . "NOT>"))))
    (progn
      (repeat (setq i (sslength ss))
	(setq lst (cons (ssname ss (setq i (1- i))) lst))
      )
      (setq rot (getpropertyvalue (car lst) "Rotation"))
      (if (vl-every '(lambda (d) (= (getpropertyvalue d "Rotation") rot)) lst)
	(if (setq pt (getpoint "\nSpécifiez le point d'alignement: "))
	  (foreach d lst
	    (if	(= rot 0.)
	      (setpropertyvalue d "TextPosition/X" (car pt))
	      (setpropertyvalue d "TextPosition/Y" (cadr pt))
	    )
	  )
	)
	(prompt "\nCôtes horizontales et verticales mélangées.")
      )
    )
  )
  (princ)
)

 

[francinez]

Merci Gile pour ton aide, je vais partager sur le forum anglais

[francinez]

Bjr Gile,

A l'utilisation on c'est rendu compte que le lisp bouge aussi les lignes de cotations (voir image ci jointe). 

Comment peut on remédier a ca?