ZOOM TOTAL DANS PRESENTATIONS

[PHILPHIL]

HELLO

 

 

gile avait ecrit ca, merci a lui

 

ca fait un zoom total dans toutes les fenetres des présentations sans devoir les ouvrir

 

comment modifier ce lisp, pour qu'il fasse un zoom total de ce qu'il y a dans la présentation a la volée, et non pas des fenetre de la dite présentation.

 

merci

 

Phil

 

 

;;;-------------------------------------------------------
;;; zoom tout dans les fenetres de presentation a la volée
;;;-------------------------------------------------------


(defun c:zep (/ acdoc ctab vp)
 (setq acdoc (vla-get-ActiveDocument (vlax-get-acad-object))
       ctab  (getvar 'ctab)
 )
 (vlax-for layout (vla-get-Layouts acdoc)
   (if (/= (vla-get-Name layout) "Model")
     (progn
       (vla-put-ActiveLayout acdoc layout)
       (setq vp nil)
       (vlax-for obj (vla-get-Block layout)
         (if (= (vla-get-ObjectName obj) "AcDbViewport")
           (progn
             (if vp
               (or (= (vla-get-DisplayLocked obj) :vlax-true)
                   (vla-put-Standardscale obj acVpScaleToFit)
               )
             )
             (setq vp T)
           )
         )
       )
     )
   )
 )
 (setvar 'ctab ctab)
 (princ)
)

[philsogood]

c'est vrai que ça peut être intéressant!! :)

Phil

[(gile)]

Salut,

 

On dirait que vous n'avez pas trop cherché...

 

(defun c:zel (/ ctab vp)
 (or *acad* (setq *acad* (vlax-get-acad-object)))
 (or *acdoc* (setq *acdoc* (vla-get-ActiveDocument *acad*)))
 (setq ctab  (getvar 'ctab))
 (vlax-for layout (vla-get-Layouts *acdoc*)
   (if (/= (vla-get-Name layout) "Model")
     (progn
       (vla-put-ActiveLayout *acdoc* layout)
       (vla-ZoomExtents *acad*)
     )
   )
 )
 (setvar 'ctab ctab)
 (princ)
)

[PHILPHIL]

hello

 

GILE merciii

 

 

la vérité, non je n'ai pas cherché c'est vrai

ni sur le site de cadxp ( en cherchant la je trouve rien )

 

ni dans les fonctions visual lisp ( c'est en anglais, je chercherai un HELP sur l ordi et j'arrive deja pas a décodé le premier lisp )

 

a+

 

Phil