CadXP: Bricscad et les .BAK - CadXP

Aller au contenu

Page 1 sur 1
  • Vous ne pouvez pas commencer un sujet
  • Vous ne pouvez pas répondre à ce sujet

Bricscad et les .BAK

#1 L'utilisateur est hors-ligne   sef 

  • ceinture jaune
  • Groupe : Membres
  • Messages : 8
  • Inscrit(e) : 08-novembre 06

Posté 26 mars 2018 - 16:03

Bonjour les amis Déssineux,

Je suis en mission chez un nouveau client depuis quelques semaines,
et celui-ci a eu la bonne idée de remplacer tous les Autocad par BricsCad.

Au premier abord, j'étais un peu réfractaire, mais après quelques semaines
d'utilisation, je m'y suis fait (de toute façon je n'avais pas trop le choix).

Je souhaitais poser quelques questions, et pouvoir vous faire bénéficier
de mes découvertes sur ce clone qui m'a été imposé, alors pourquoi pas
créer une rubrique BricsCad dans "Autres logiciels de CAO"?

J'ai d’ailleurs déjà une demande pour nos chers spécialistes en LISP:

Sauf erreur de ma part, il n'y a pas de "Gestionnaire de récupération de dessin"
ni de sauvegarde automatique, du coup après plantage c'est la galère,
à part le ".BAK", il n'y a pas grand chose.

Vu qu'il est relativement compatible avec les LISP d'Autocad,
je me demandais si il existait un lisp pour faire des sauvegardes auto
au bout d'un certain nombre de commandes ou de clics?

Merci d'avance et bonne soirée ;)
0

#2 L'utilisateur est hors-ligne   Tramber 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 8 500
  • Inscrit(e) : 29-mars 03
  • LocationStrasbourg

Posté 26 mars 2018 - 20:39

Bonjour sef,
Je me suis permis de modérer en créant un nouveau sujet.
La sauvegarde auto en bak sur Bricscad ?
Si quelqu'un sait....

Pour ta demande en lisp. Elle ferait appel à des réacteurs. Plutôt difficile à mettre en oeuvre à mon sens.
Image IPB

Bureau d'études dessin.
Spécialiste Escaliers
Développement - Formation

./__\.
(.°=°.)
0

#3 L'utilisateur est hors-ligne   sef 

  • ceinture jaune
  • Groupe : Membres
  • Messages : 8
  • Inscrit(e) : 08-novembre 06

Posté 26 mars 2018 - 20:58

Voir le messageTramber, le 26 mars 2018 - 20:39 , dit :

Bonjour sef,
Je me suis permis de modérer en créant un nouveau sujet.
La sauvegarde auto en bak sur Bricscad ?
Si quelqu'un sait....

Pour ta demande en lisp. Elle ferait appel à des réacteurs. Plutôt difficile à mettre en oeuvre à mon sens.


Merci j'avais hésité à créer un sujet...

Pour le lisp, j'avais il y a longtemps réussi à en trouver un
qui sauvegardait au bout d'un certain nombre de clic
mais impossible de remettre la main dessus.

Ensuite il suffirait d'ajouter une commande pour copier le .bak ailleurs,
voir même incrémenter son nom avec l'heure et la date par exemple ;)

Plus facile à dire qu'à faire ;)
0

#4 L'utilisateur est hors-ligne   vincentp010 

  • ceinture noire 1er dan
  • Groupe : Membres
  • Messages : 644
  • Inscrit(e) : 19-décembre 07

Posté 27 mars 2018 - 07:32

Bonjour,

j'ai trouvé ce sujet, pour sauvegarder en bout de 20 commandes
Aide au téléchargement du cadastre dgfip-download-helper
Insertion de photos géolocalisées exif https://www.dropbox....xifscr.zip?dl=0
0

#5 L'utilisateur est hors-ligne   Tramber 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 8 500
  • Inscrit(e) : 29-mars 03
  • LocationStrasbourg

Posté 27 mars 2018 - 08:03

Voir le messagevincentp010, le 27 mars 2018 - 07:32 , dit :

Bonjour,
j'ai trouvé ce sujet, pour sauvegarder en bout de 20 commandes

Ah bah oui, pas si dur le lisp du réacteur de son auteur.
et il a mis :
(:vlr-commandended . autosave)
(:vlr-commandcancelled . autosave)
(:vlr-commandfailed . autosave)
Quand je pensais au lancement des commandes. Plutôt malin et sans doute pour éviter tout plantage.
Image IPB

Bureau d'études dessin.
Spécialiste Escaliers
Développement - Formation

./__\.
(.°=°.)
0

#6 L'utilisateur est hors-ligne   vincentp010 

  • ceinture noire 1er dan
  • Groupe : Membres
  • Messages : 644
  • Inscrit(e) : 19-décembre 07

Posté 27 mars 2018 - 08:07

Bonjour,

j'ai trouvé ce sujet, pour sauvegarder en bout de 20 commandes

En remplacant
(vla-save *autosave-acdoc*)
par
(progn
  (vla-export *autosave-acdoc* (strcat "c:/" (vla-get-name *autosave-acdoc*) (rtos (getvar 'date) 2 8)) "dxf" (setq sel (vla-add (vla-get-selectionsets *autosave-acdoc*) (rtos (getvar 'date) 2 8))))
  (vla-delete sel)
)

on a un export du dessin en dxf. (là j'ai mis dans c:, mais on peut personaliser)
J'ai pas trouvé mieux pour le moment
Aide au téléchargement du cadastre dgfip-download-helper
Insertion de photos géolocalisées exif https://www.dropbox....xifscr.zip?dl=0
0

#7 L'utilisateur est hors-ligne   (gile) 

  • ceinture rouge et blanche 8em dan
  • Groupe : Moderateurs
  • Messages : 11 451
  • Inscrit(e) : 02-septembre 05

Posté 27 mars 2018 - 09:29

Salut,

J'ai un peu modifié le LISP de Lee Mac.
Deux commandes :
- AUTOSAVEON : pour activer le réacteur
- AUTOSAVEOFF : pour désactiver le réacteur

Le réacteur ne prends en compte que l'évènement :vlr-commandEnded, c'est à dire les commandes qui ont abouti (inutile, à mon avis de comptabiliser les commandes qui ont échoué ou ont été annulées).
L'utilisateur est averti si le dessin n'est pas enregistré.
EDIT: Le fichier .bak est copié dans le même répertoire renommé avec la date et l'heure avec l'extension .dwg.
J'ai évité toutes les variables globales.

(vl-load-com)

(defun c:AutoSaveOn ()
  (if (not (vl-some
	      '(lambda (rea)
		 (equal	'((:vlr-commandended . AUTOSAVE))
			(vlr-reactions rea)
		 )
	       )
	      (cdar (vlr-reactors :VLR-Command-Reactor))
	    )
      )
    (vlr-command-reactor 0 '((:vlr-commandended . AUTOSAVE)))
  )
  (princ)
)

(defun c:AutoSaveOff ()
  (foreach rea (cdar (vlr-reactors :VLR-Command-Reactor))
    (if	(equal '((:vlr-commandEnded . AUTOSAVE))
	       (vlr-reactions rea)
	)
      (vlr-remove rea)
    )
  )
  (princ)
)

(defun autosave	(rea lst / filename)
  (if (zerop (rem (vlr-data-set rea (1+ (vlr-data rea))) 20))
    (if	(= 1 (getvar 'dwgtitled))
      (progn
	(vla-save (vla-get-ActiveDocument (vlax-get-acad-object)))
	(setq filename (strcat (getvar 'dwgprefix) (vl-filename-base (getvar 'dwgname))))
	(vl-file-rename
	  (strcat filename ".bak")
	  (strcat filename "_" (rtos (getvar 'cdate) 2 6) ".dwg")
	)
      )
      (alert "\nLe dessin n'est pas enregistré")
    )
  )
  (princ)
)

Gilles Chanteau - gileCAD -
Développements sur mesure pour AutoCAD
Image IPB
0

#8 L'utilisateur est hors-ligne   sef 

  • ceinture jaune
  • Groupe : Membres
  • Messages : 8
  • Inscrit(e) : 08-novembre 06

Posté 27 mars 2018 - 12:18

Nickel, ça marche super bien ;)
Ca va m'éviter de perdre quelques heures de boulot à chaque plantage,
Merci beaucoup :P :rolleyes:
0

Partager ce sujet :


Page 1 sur 1
  • Vous ne pouvez pas commencer un sujet
  • Vous ne pouvez pas répondre à ce sujet

1 utilisateur(s) en train de lire ce sujet
0 membre(s), 1 invité(s), 0 utilisateur(s) anonyme(s)