Changer style de texte

[fiesta13310]

Bonjour tous le monde,

 

Dans mon dessin, j'ai des textes, des textmultiples, des blocs avec des attributs qui ont comme style de texte "ARIAL". Je voudrais que toutes ces "écritures" passent du style arial au style standard. Actuellement, cela marche avec les sélections rapides pour les textes et les multitextes, pas pour les blocs et les textes dans les côtes.

 

Je ne sais pas si c'est possible, mais je cherche simplement un LISP qui ferait un truc du genre : toutes les écritures définit en styles ARIAL passent en style STANDARD.

 

Merci d'avance! ;)

[(gile)]

Salut,

 

Tu peux essayer ça, les attributs devraient être synchronisés.

Tu peux remplacer "Arial" et/ou "Standard" dans le code par les noms de style que tu veux.

 

(defun c:ReplaceTextStyle (/ oldStyle newStyle)
 (vl-load-com)
 (or *acad* (setq *acad* (vlax-get-acad-object)))
 (or *acdoc* (setq *acdoc* (vla-get-ActiveDocument *acad*)))
 
 (setq	oldStyle "Arial"
newStyle "Standard"
 )
 (vlax-for block (vla-get-Blocks *acdoc*)
   (if	(= (vla-get-IsXRef block) :vlax-false)
     (vlax-for	obj block
(if (and (vlax-property-available-p obj "StyleName" T)
	 (= (vla-get-StyleName obj) oldStyle)
    )
  (vla-put-StyleName obj newStyle)
  (if (= (vla-get-ObjectName obj) "AcDbBlockReference")
    (foreach att (vlax-invoke obj 'GetAttributes)
      (if (= (vla-get-StyleName att) oldStyle)
	(vla-put-StyleName att newStyle)
      )
    )
  )
)
     )
   )
 )
 (vla-Regen *acdoc* acAllViewports)
 (princ)
)

[fiesta13310]

Bonjour,

 

Mcrci Gile, mais rien ne se passe quand je le charge... il me demande rien et ne fait rien non plus, mais ne m'indique pas non plus de message d'erreur... :huh:

 

Merci

[DenisHen]

Salut.

 

Tu le charges, mais tu le lances ensuite ? Avec "ReplaceTextStyle" ?

[fiesta13310]

Oui c'est ce que j'avais fais... mais du coup je viens de recommencer et cette fois-ci ça a marché... mais j'ai l'impression qu'aujourd'hui autocad est un peu capricieux... il n'a pas très envi de bosser... :angry:

 

Merci! A bientôt! :P

[fiesta13310]

Par contre, une fois que j'ai lancé le programme, et que mes textes se sont lancés, quand je purge il ne me purge pas le style de texte...