Creation presentations en automatique

[patrick.albinet]

Bonjour à tous,

 

J'aurais aimé faire des présentations en automatique car j'en ai plus de 300 à faire. Il me semble que Civil peut faire ça mais j'ai dans l'espace objet des blocs (modifiable si besoin en objet différent) et un bloc cartouche défini.

 

Ce que j'aurais souhaité, c'est m’éviter la rotation à chaque présentation.

 

Pas possible avec Covadis, long avec autocad....Je ne maitrise pas encore Civil mais s'il y a une solution, je suis preneur...ou avec un Lisp, autre logiciel..........

 

Ci joint le fichier en question : http://dl.free.fr/sSxXgBPUz

 

Merci d'avance

[thierry.garré]

Bonjour

 

C'est possible avec Autopiste depuis la version 15 .

 

C est le trace combine

 

Cordialement

[patrick.albinet]

OK, je le demande. La manip est possible avec mon système de bloc ? La mise en page auto avec dwg to pdf ou autre ? Sachant que j'ai besoin que du pdf final.

 

Le support d’auto piste est également visible de la même façon que covadis (en bas a gauche) ?

[x_all]

je suis de la vielle école, mais 300 présentations... Autocad va friser l'indigestion

il y a des solutions (lisp ou script) pour tout tracer depuis l'espace objet j'ai toujours eu le sentiment que c'était pas plus mal.

[patrick.albinet]

C'est que je fais en général mais avec le cartouche, ça va se superposer et le résultat ne conviendra pas a moins qu'il y ai une astuce que je ne connais pas....ca c'est largement possible

[x_all]

ha oui... j'avais pas chargé ton plan, effectivement les orientations multiples pose problème...

Le code que j'avais fait est bien pour les carnet de ferraillage qui sont tous suivant le SCG.

Il y a surement moyen d'adapter le truc, mais on est loin de mes cordes...

[patrick.albinet]

Merci pour vos réponses.

[bonuscad]

Bonjour,

 

Tu peux essayer avec ça; fait depuis ton dessin exemple (l'ideal est de supprimer la présentation (1) avant utilisation du lisp.

 

(defun c:test ( / js n ent dxf_ent pt_ins rot num adoc lay i j)
 (setq js (ssget "_X" '((0 . "INSERT") (67 . 0) (410 . "Model") (8 . "EE_07_ENCARTAGE A3 VUE EN PLAN") (66 . 1) (2 . "A$C28036E38"))))
 (cond
   (js
     (setvar "ATTDIA" 0)
     (setvar "ATTREQ" 0)
     (repeat (setq n (sslength js))
       (setq ent (ssname js (setq n (1- n))))
       (setq dxf_ent (entget ent))
       (setq pt_ins (cdr (assoc 10 dxf_ent)))
       (setq rot (- (cdr (assoc 50 dxf_ent)) 1.186823891356802))
       (setq num (cdr (assoc 1 (entget (entnext (cdar dxf_ent))))))
       (command "_.-LAYOUT" "_New" num)
       (command "_.-LAYOUT" "_Set" num)
       (command "_.ERASE" (ssget "_X" (list '(0 . "VIEWPORT") '(67 . 1) (cons 410 num) (cons 8 (getvar "CLAYER")))) "")
       (setvar "CLAYER" "EE_07_ENCARTAGE A3 VUE EN PLAN")
       (setq adoc (vla-get-activedocument (vlax-get-acad-object)))
       (setq lay (vla-get-ActiveLayout adoc))
       (vla-Put-Configname lay "DWG To PDF.pc3")
       (vla-put-CanonicalMediaName lay "ISO_full_bleed_A3_(420.00_x_297.00_MM)")
       (vla-SetCustomScale lay (vlax-make-variant 1.0) (vlax-make-variant 1.0))
       (setq i (vlax-make-safearray vlax-vbDouble '(0 . 1)))
       (vlax-safearray-put-element i 0 0.0) (vlax-safearray-put-element i 1 0.0)
       (setq j (vlax-make-safearray vlax-vbDouble '(0 . 1)))
       (vlax-safearray-put-element j 0 410.0) (vlax-safearray-put-element j 1 287.0)
       (vla-SetWindowToPlot lay i j)
       (vlax-put lay 'PlotOrigin '(4.20624 4.20624))
       (vla-put-PaperUnits lay 1)
       (vla-put-PlotHidden lay 0)
       (vla-put-PlotRotation lay 0)
       (vla-put-PlotType lay 4)
       (vla-put-PlotViewportBorders lay 0)
       (vla-put-PlotViewportsFirst lay 1)
       (vla-put-PlotWithLineweights lay 1)
       (vla-put-PlotWithPlotStyles lay 1)
       (vla-put-ScaleLineweights lay 0)
       (vla-put-ShowPlotStyles lay 0)
       (vla-put-StandardScale lay 16)
       (vla-put-StyleSheet lay "")
       (vla-put-UseStandardScale lay 1)
       (vla-put-CenterPlot lay 1)
       (command "_.MVIEW" "_none" "0.0,20.2759" "_none" "@410,266.724")
       (command "_.ZOOM" "_extent")
       (command "_MSPACE")
       (command "_UCS" "3" "_none" pt_ins "_none" (polar pt_ins (+ (* 0.5 pi) rot) 1.0) "_none" (polar pt_ins (+ rot pi) 1.0))
       (command "_.PLAN" "_current")
       (command "_zoom" "_left" "_none" "0,0" "250")
       (command "_.PSPACE")
       (setvar "CLAYER" "EE_03_CARTOUCHE")
       (command "_.MVIEW" "_none" "0.0,0,0" "_none" "@138.2782,20.2759")
       (command "_.-INSERT" "CARTOUCHE_BANDE_A4" "_none" "410.0,0" "1" "0")
     )
     (setvar "ATTDIA" 1)
     (setvar "ATTREQ" 1)
   )
 )
)

 

je suis de la vielle école, mais 300 présentations... Autocad va friser l'indigestion

Ce qui fait que le programme peut faire qu'Autocad affiche qu'il ne répond pas....

Mais laisse faire quand même, il fait le boulot, il fini par rendre la main.

[thierry.garré]

Oups,

 

pour ma part je n'avais pas encore téléchargé le fichier, mais du coup après l'avoir vu cela ne me semble pas du tout adapté Autopiste. car il faudrait que cela soit purement linéaire.

 

 

cordialement

[lili2006]

Bonjour à toutes et tous,

 

Avec les Atlas de MAP, c'est jouable,..

[Vincent Fredon]

Bonjour,

Je prends la conversation en retard. La demande originale portait sur Civil 3D et effectivement la mise en page automatique est possible en VP et PL.

C'est un axe du projet qui est le support des objets fenêtres.

En revanche, les groupes de fenêtres ajustées en matrice comme sur le DWG exemple nécessiteraient un placement manuel ou sur des axes supports fictifs.