Lister les images

[l56]

Bonjour,

 

Comment peut-on lister toutes les images que l'on attache avec la commande IMAGE ?

 

Merci a ceux qui savent ...

[bonuscad]

Bonjour,

 

Comme ceci?

 

((lambda ( / js n)
(setq js (ssget "_x" '((0 . "IMAGE"))))
(cond
	(js
		(repeat (setq n (sslength js))
			(print (cdr (assoc 1(entget (cdr (assoc 340 (entget (ssname js (setq n (1- n))))))))))
		)
	)
)
(prin1)
))

[l56]

Merci pour ta réponse, qui fonctionne très bien, mais si l'image à été supprimé par la commande EFFACER, il faut quand même pouvoir la "DETACHER" et pour cela, il me faut son nom.

[bonuscad]

En cas d'effacement (ou non), il faut passer par les dictionnaires.

 

((lambda ( / id ename_lst)
 (setq id (dictsearch (namedobjdict) "ACAD_IMAGE_DICT"))
 (cond
   (id
     (foreach n id
       (if (eq (car n) 350)
         (setq ename_lst (cons (cdr n) ename_lst))
       )
     )
     (cond
       (ename_lst
         (foreach el ename_lst
           (print (cdr (assoc 1 (entget el))))
         )
       )
     )
   )
 )
 (prin1)
))

[l56]

Merci bonuscad,

 

C'est exactement ce dont j'avais besoin.

 

Bonne journée