[Résolu] Objet "Solide"

[DaWeeD_Gab]

Bonjour,

 

je travaille sur un fichier où je trouve des objets type "Solide".

Ce ne sont ni des solides 3D, ni des motifs de hachure solide.

Je ne connais pas ce type d'objet !

j'aimerai les convertir en hachure pour pouvoir en extraire l'aire.

tout ce que j'ai réussi à faire c'est les convertir en surface, puis décomposer celles-ci,

j'obtiens alors une région que je décompose à son tour!

là j'ai des polylignes, que je joins et j'ai enfin mon aire !...

Très fastidieux !!

 

Peut-on convertir directement ce type d'objet en hachure au motif solide afin de pouvoir sélectionner ces hachures et obtenir ainsi l'aire cumulée rapidement?

 

En vous remerciant,

bonne journée

[DenisHen]

Salut.

 

C'est une entité faite avec la commande "SOLID", c'est une sorte de trame à partir de quatre sommets (pour la plus simple).

 

Ce n'est pas décomposable...

[Tramber]

La commande est SOLIDE

à partir de 3 ou 4 sommets

Il doit exister des lisp de conversion.

Un lien un peu au hasard sur un site de confiance :

http://www.cadtutor.net/forum/archive/index.php/t-53044.html

[Tramber]

https://autocadtips1.com/2013/12/28/autolisp-convert-2d-solid-to-polyline-outline/

plus simple encore mais ne gère pas non plus les éventuels solides à trois points ;)

[lecrabe]

Hello

 

1) Pourquoi "acheter/utiliser" des routines US quand on a de l'excellent travail FRANCAIS !

 

2) Merci a notre grand maitre national: GILLES !!

 

3) VIEILLE Routine mais parfaitement operationnelle sur la version 2018

 

MERCI Gilles, Bye, lecrabe

 

PS: comme d'habitude, cela a ete puise dans "mes" 2000 routines ...

 

;;
;; SOLID2PLINE par GC 
;; 
;; transforme les Solides 2D selectionnés en polylignes fermees
;;

(vl-load-com) 

(defun c:Solid2Pline (/ ss n ent elst elv)
 (princ "\nSelectionnez les solides ou <tous>: ")
 (if
   (setq ss (cond ((ssget '((0 . "SOLID"))))
	   (T (ssget "_X" '((0 . "SOLID"))))
     )
   )
    (while (setq ent (ssname ss
		      (setq n (if n
				(1+ n)
				0
			      )
		      )
	      )
    )
      (setq elst (vl-remove-if
	    '(lambda (x) (member (car x) '(-1 0 5 100 39)))
	    (entget ent)
	  )
     elv  (cadddr (assoc 10 elst))
      )
      (entmake
 (append
   (list
     '(0 . "LWPOLYLINE")
     '(100 . "AcDbEntity")
     '(100 . "AcDbPolyline")
     (assoc 67 elst)
     (assoc 410 elst)
     (assoc 8 elst)
   )
   (if (equal (cdr (assoc 12 elst)) (cdr (assoc 13 elst)) 1e-9)
     (list
       '(90 . 3)
       '(70 . 1)
       (cons 38 elv)
       (assoc 10 elst)
       (cons 10 (cdr (assoc 11 elst)))
       (cons 10 (cdr (assoc 12 elst)))
       (assoc 210 elst)
     )
     (list
       '(90 . 4)
       '(70 . 1)
       (cons 38 elv)
       (assoc 10 elst)
       (cons 10 (cdr (assoc 11 elst)))
       (cons 10 (cdr (assoc 13 elst)))
       (cons 10 (cdr (assoc 12 elst)))
       (assoc 210 elst)
     )
   )
 )
      )
      (entdel ent)
    )
 )
 (princ)
)

[DaWeeD_Gab]

Super ! c'est ce qu'il me fallait.

Merci à vous 2, bien évidemment j'utiliserai dorénavant celle de notre grand maître national, Gilles !! :D