Rectangle facilité

Dinosor · le 22 juin 2017

Hello,

Je me réfère à un sujet qui parlait de programmation pour faire un rectangle de façon simplifiée. Tout à fait à mon goût :)

Merci à Didier, sujet ici

J'essaie de pouvoir lancer cela sous forme de lisp, sauf que le première ligne que j'ai ajouté est bien évidemment fausse !!!

Je suis une pince, j'aimerai bien savoir faire cela... Une bonne âme à mon secours ?

Voici le code, avec ma première ligne fausse:

(defun c:rct ????????????? ) 

(setvar "osmode" 0)

(setq p1 (getpoint"\nPoint de Base\n"))

(setq longueur (getreal"\nLongueur\n")

      largeur(getreal"\nLargeur\n"))

(setq p2 (list

           (+ (car p1) longueur)

           (cadr p1)

           )

      p3 (list

           (+ (car p1) longueur)

           (+ (cadr p2) largeur)

           )

      p4 (list

           (car p1)

           (+ (cadr p1) largeur)

           )

      )

(command "_pline" p1 p2 p3 p4 "c")

(command "_rotate" "d" "" p1 pause "")

Merci beaucoup pour votre aide ;)

DenisHen · le 22 juin 2017

Salut Dinosor.

Tu n'avais jamais fais de LISP avant ?

Comme ça peut-être :

(defun c:rct ( / p1 longueur largeur p2 p3 p4)
 (setq old_osmode (getvar "osmode"))
 (setvar "osmode" 0)
 (setq p1 (getpoint "\nPoint de Base\n"))
 (setq longueur (getreal "\nLongueur :")
       largeur  (getreal "\nLargeur :")
 ) ;_ Fin de setq
 (setq p2 (list (+ (car p1) longueur) (cadr p1))
       p3 (list (+ (car p1) longueur) (+ (cadr p2) largeur))
       p4 (list (car p1) (+ (cadr p1) largeur))
 ) ;_ Fin de setq
 (command "_pline" p1 p2 p3 p4 "c")
 (command "_rotate" "d" "" p1 pause "")
 (setvar "osmode" old_osmode)
 (princ)
)

Dinosor · le 22 juin 2017

Super !

Merci pour ta réactivité :)

Et si je veux conserver l'accrochage, je fais ainsi ?

(defun c:rct ( / p1 longueur largeur p2 p3 p4)
  (setq p1 (getpoint "\nPoint de Base\n"))
  (setq longueur (getreal "\nLongueur :")
        largeur  (getreal "\nLargeur :")
  ) ;_ Fin de setq
  (setq p2 (list (+ (car p1) longueur) (cadr p1))
        p3 (list (+ (car p1) longueur) (+ (cadr p2) largeur))
        p4 (list (car p1) (+ (cadr p1) largeur))
  ) ;_ Fin de setq
  (command "_pline" p1 p2 p3 p4 "c")
  (command "_rotate" "d" "" p1 pause "")
  (setvar "osmode" old_osmode)
  (princ)
)

Super sympa ;)

Dinosor · le 22 juin 2017

Yep, c'est tout bon !

Meeeeeeerci :)

DenisHen · le 22 juin 2017

J'aurais du commenté... Désolé :

(defun c:rct ( / old_osmode  p1 longueur largeur p2 p3 p4) ;Déclaration locale des variables
 (setq old_osmode (getvar "osmode")) ;enregistrement de l'accrochage
 (setvar "osmode" 0) ;changement de l'accrochage, ici : aucun
 (setq p1 (getpoint "\nPoint de Base :"))
 (setq longueur (getreal "\nLongueur :")
       largeur  (getreal "\nLargeur :")
 ) ;_ Fin de setq
 (setq p2 (list (+ (car p1) longueur) (cadr p1))
       p3 (list (+ (car p1) longueur) (+ (cadr p2) largeur))
       p4 (list (car p1) (+ (cadr p1) largeur))
 ) ;_ Fin de setq
 (command "_pline" p1 p2 p3 p4 "c")
 (command "_rotate" "d" "" p1 pause "")
 (setvar "osmode" old_osmode) ;réaffectation de l'accrochage enregistré avant les opération.
 (princ) ;évite le retour Lisp
)

Pour toutes commandes lisp, l'interpréteur renvoi toujours la dernière opération sous forme de texte dans la fenêtre AutoCAD, le (princ) à la fin du code évite se genre de retour.

Content d'avoir pu aider... ;)

Dinosor · le 22 juin 2017

Yep, c'est tout bon !

Meeeeeeerci :)

Ben non en fait, j'ai encore une ligne de trop :mellow:

(defun c:rct ( / p1 longueur largeur p2 p3 p4)
  (setq p1 (getpoint "\nPoint de Base\n"))
  (setq longueur (getreal "\nLongueur :")
        largeur  (getreal "\nLargeur :")
  ) ;_ Fin de setq
  (setq p2 (list (+ (car p1) longueur) (cadr p1))
        p3 (list (+ (car p1) longueur) (+ (cadr p2) largeur))
        p4 (list (car p1) (+ (cadr p1) largeur))
  ) ;_ Fin de setq
  (command "_pline" p1 p2 p3 p4 "c")
  (command "_rotate" "d" "" p1 pause "")
  (princ)
)

Je vais essayer ça... Sinon je vais encore avoir besoin d'aide... :D

DenisHen · le 22 juin 2017

Je ne vois pas où ça coince...

Mon code en réponse 5 marche bien chez moi...

Quel est ton problème ?

Dinosor · le 22 juin 2017

Ca fonctionne, mais ça me modifie la variable SELECTIONPREVIEW...

Normal ?

DenisHen · le 22 juin 2017

Je ne comprend pas, chez moi, cette variable reste à 3, avant et après le code...

Elle n'y a aucune raison de changer, on n'y touche pas...

Dinosor · le 22 juin 2017

Je ne comprend pas, chez moi, cette variable reste à 3, avant et après le code...

Ouais, c'est bizarre... Ca m'a d'abord modifié la variable SELECTIONPREVIEW.

Plus maintenant !

Mais ça modifie le DYNMODE actuellement, il passe de 2 à -2 :D

Initialement, le code fonctionne bien sans accrochages.

Ce que je souhaite, c'est conserver ceux-ci et gérer uniquement avec la touche F3.

Merci.

DenisHen · le 22 juin 2017

Comme tu peux le lire dans mes commentaires, je sauvegarde l'accrochage

(setq old_osmode (getvar "osmode"))

je le modifie

(setvar "osmode" 0)

et je le réaffecte à la fin

(setvar "osmode" old_osmode)

.

Dinosor · le 22 juin 2017

Un plus serait de pouvoir cliquer les longueurs et largeurs du rectangle à l'écran ou de donner les entrées clavier. Mais je suppose que c'est bien compliqué...

Comme j'ai dit, j'y connaît rien.

Merci encore.

Dinosor · le 22 juin 2017

Comme tu peux le lire dans mes commentaires, je sauvegarde l'accrochage
(setq old_osmode (getvar "osmode"))
je le modifie
(setvar "osmode" 0)
et je la réaffecte à la fin
(setvar "osmode" old_osmode)
.

Je croise les messages, désolé.

J'ai bien vu, sauf que je souhaite maintenir les accrochages pour pouvoir ancrer mon rectangle où je veux. Je tripote F3 si je veux ou non l'accrochage, c'est tout.

Mais je sais que si l'accrochage est actif, le rectangle peut s'accrocher à des entités proches. Mais ce n'est pas grave.

Bien à toi :)

DenisHen · le 22 juin 2017

Eh non, ce n'est pas bien compliqué, tu remplace tes (getreal par des (getdist :

(defun c:rct ( / p1 longueur largeur p2 p3 p4)
 (setq old_osmode (getvar "osmode"))
 (setvar "osmode" 0)
 (setq p1 (getpoint "\nPoint de Base :"))
 (setq longueur (getdist p1 "\nLongueur :")
       largeur  (getdist p1 "\nLargeur :")
 ) ;_ Fin de setq
 (setq p2 (list (+ (car p1) longueur) (cadr p1))
       p3 (list (+ (car p1) longueur) (+ (cadr p2) largeur))
       p4 (list (car p1) (+ (cadr p1) largeur))
 ) ;_ Fin de setq
 (command "_pline" p1 p2 p3 p4 "c")
 (command "_rotate" "d" "" p1 pause "")
 (setvar "osmode" old_osmode)
 (princ)
)

DenisHen · le 22 juin 2017

Mais les trois points doivent définir deux droites parfaitement perpendiculaires...

DenisHen · le 22 juin 2017

Personnellement, je placerais (maintenant que je sais à peu près le faire) une gestion d'erreur.

Ce qui te permettra un [Echap] pendant ton code et de retrouver l'accrochage enregistré :

(defun c:rct (/ p1 longueur largeur p2 p3 p4)
;;; Gestion des erreurs  ********
 (setq olderror *error*)
 (defun *error* (msg)
   (princ msg)
   (setvar "osmode" old_osmode)
   (setq *error* olderror)
   (princ)
 ) ;_ Fin de defun
 (setq old_osmode (getvar "osmode"))
 (setvar "osmode" 0)
 (setq p1 (getpoint "\nPoint de Base :"))
 (setq longueur (getdist p1 "\nLongueur :")
       largeur  (getdist p1 "\nLargeur :")
 ) ;_ Fin de setq
 (setq p2 (list (+ (car p1) longueur) (cadr p1))
       p3 (list (+ (car p1) longueur) (+ (cadr p2) largeur))
       p4 (list (car p1) (+ (cadr p1) largeur))
 ) ;_ Fin de setq
 (command "_pline" p1 p2 p3 p4 "c")
 (command "_rotate" "d" "" p1 pause "")
 (setvar "osmode" old_osmode)
 (princ)
)

Dinosor · le 22 juin 2017

Mais les trois points doivent définir deux droites parfaitement perpendiculaires...

Oui et non, en fait ça me prend la longueur réelle :)

Au final, cette dernière mouture fonctionne très bien malgré le désactivage des accrochages.

J'entre la commande, si j'appuie sur F3 il me propose du coup le menu d'accrochage, je choisis celui qui m'intéresse pour ancrer mon rectangle, j'entre mes dimensions largeur puis hauteur et je définis finalement l'orientation.

La plupart du temps j'ai l'ortho actif (F8), du coup c'est extra !

Merci beaucoup pour ton aide et tes explications plus haut (commentaires dans le lisp). C'est génial, il faut que je m'y intéresse sérieusement.

Amitiés ;)

DenisHen · le 22 juin 2017

Content d'avoir pu t'aider... ;)

Relis le fil, je t'ai ajouter une gestion d'erreur.

Plutôt que d'utiliser [F3], pourquoi pas un [Ctrl] + clic droit ? Sauf si tu connais l'accroche que tu veux pendant la saisie des distances. Dans ce cas, on peut le paramétrer.

Dinosor · le 22 juin 2017

Content d'avoir pu t'aider... ;)

Relis le fil, je t'ai ajouter une gestion d'erreur.

Plutôt que d'utiliser [F3], pourquoi pas un [Ctrl] + clic droit ? Sauf si tu connais l'accroche que tu veux pendant la saisie des distances. Dans ce cas, on peut le paramétrer.

Oui, bien sûr ! Suis-je bête :rolleyes: A force de vouloir simplifier.... :D

J'ai mis donc le dernier de la discussion et ça fonctionne à merveille !

Bel outil ;)

A+

Connexion

Rectangle facilité

Messages recommandés

Dinosor

DenisHen

Dinosor

Dinosor

DenisHen

Dinosor

DenisHen

Dinosor

DenisHen

Dinosor

DenisHen

Dinosor

Dinosor

DenisHen

DenisHen

DenisHen

Dinosor

DenisHen

Dinosor

Créer un compte ou se connecter pour commenter

Créer un compte

Se connecter

Forums

Naviguer

Activité

Information importante