Sélection de bloc par entité sur calque

[ASTERIXII]

Bonjour,

 

Voila mon problème, j'ai des blocs (qui ne sont pas créer sur le calque 0) dans lequel j'ai des entités (ligne, cercle, ellipse, spline) sur des calques différents.

 

Le bloc est sur le calque A

Il est composé d'entités (ligne, cercle, ellipse, spline) soit sur un calque B ou C (ligne du calque, couleur du calque)

 

Je voudrais avoir une sélection des blocs qui au moins une entité sur le calque C.

 

Le but n'est pas "initialiser" le bloc comme le fait la routine de Gilles (Edit_bloc), mais de pouvoir isoler les blocs avant de lancer un traitement (Edit_bloc) sans cette sélection.

Cela fait 2 jour que je parcours le net sans trouver une routine dans ce sens.

Merci pour votre aide.

[(gile)]

Salut,

 

Si j'ai bien compris la demande, le LISP ci-dessous devrait faire l'affaire.

L'utilisateur est invité à entrer les noms de calques séparés par des virgules, les caractères génériques sont acceptés.

 

(defun c:ASTERIXII (/ layers block ent filter)
 (if (setq layers (getstring T "\nEntrez les noms de calques séparé par des virgules: "))
   (progn
     (setq layers (strcase layers)
           filter ""
     )
     (while (setq block (tblnext "block" (not block)))
       (setq ent (cdr (assoc -2 block)))
       (if (< (cdr (assoc 70 block)) 4)
         (while ent
           (if (wcmatch (strcase (cdr (assoc 8 (entget ent)))) layers)
             (setq filter (strcat filter (cdr (assoc 2 block)) ",")
                   ent    nil
             )
             (setq ent (entnext ent))
           )
         )
       )
     )
     (sssetfirst nil (ssget "_X" (list (cons 0 "INSERT") (cons 2 filter))))
   )
 )
 (princ)
)

[ASTERIXII]

Salut,

 

Bien compris le sujet, c'est parfait.

Merci de répondre un dimanche.