Accéder à la variable transparence de tracé

[La Lozère]

Bonjour,

Suite à ce post (Mon liehttp://cadxp.com/topic/44492-modifier-valeur-transparence-du-trace/page__p__256223__fromsearch__1?do=findComment&comment=256223n) qui n'a pas rencontré un grand succès, je me tourne vers le lisp.

Existe-t-il un moyen de changer la case à cocher de la transparence de tracé de la mise en page d'une présentation donnée.

En effet, j'ai 101 planches contenant chacune 1 seule présentation, mais avec une mauvaise configuration de cette case.

 

Pour cela, le top serait de modifier la mise en page, mais pour l'instant je fais choux blanc....

La commande -traceur n'y donne pas accès, et la variable PLOTTRANSPARENCYOVERRIDE gère la chose de manière global :(

 

Une idée?

Merci.

[cafougnette]

Bonjour,

ce lisp vous sera peut-être utile. Il active le paramètre "Transparence du tracé" dans toutes les présentations du dessin courant.

Pour désactiver le paramètre : (LayoutTransparency Layout 0)

La commande est TRANSPLAYOUT

Cordialement

 

(vl-load-com)
(defun LayoutTransparency (layout ON / xType xData )
 (setq xData (vlax-make-safearray vlax-vbVariant '(0 . 1)))
 (setq xType (vlax-make-safearray vlax-vbInteger '(0 . 1)))
 (vlax-safearray-fill xData (list(vlax-make-variant "PLOTTRANSPARENCY")(vlax-make-variant ON)))
 (vlax-safearray-fill xType (list 1001 1071))
 (vla-setXdata layout  xType xData)
 (entmod(entget (vlax-vla-object->ename layout) '("*")))
)
(defun C:TRANSPLAYOUT ()
 (setq AutoCAD (vlax-get-acad-object))
 (setq acdoc (vla-get-ActiveDocument AutoCAD))
 (setq aclay (vla-get-ActiveLayout acdoc))
 (vlax-for Layout (vla-get-Layouts acdoc)
   (if	(/= (vla-get-Name Layout) "Model")
     (LayoutTransparency Layout 1)
   )
 )
)

[La Lozère]

Super, merci cafougnette. Ca marche nickel.

 

Faute de mieux, dans mon script, je mettais la variable PLOTTRANSPARENCYOVERRIDE à 2 avant le tracé, et la rétablissait à 1 après le tracé.

 

Mais ta routine va me permettre de traiter une fois pour toute mes 101 planches.

 

Merci encore.