recuperer le bit de l'accrochage

[Infinicad]

Bonjour,

 

Quelqu'un saurait il s'il est possible de récupérer la valeur du bit de l'accroche utilisé pour le clique.

 

En fait je souhaiterai pouvoir conditionner une action selon le type d'accroche utilisé.

 

Ex: si je clique sur un centre de cercle alors je fais XXXX

si je clique sur une extrémité alors YYYY

 

Cela est il possible?

J'ai essayer d'utiliser le GRSNAP de Lee Mac mais je crois que je n'ai pas compris son fonctionnement....

Merci à vous

[sbosarl]

bonjour,

voir variable system "OSMODE"

 (setq accro (getvar "osmode"));accro = valeur existante accrochage
 (setvar "osmode" 0);change la valeur en aucun
(setvar "osmode" accro); rend la valeur en fin de lsp

[(gile)]

Salut,

 

Tu peux essayer ça :

 

(defun getSnap (pt / modes)
 (setq modes '((1 . "_END")
               (2 . "_MID")
               (4 . "_CEN")
               (8 . "_NOD")
               (16 . "_QUA")
               (32 . "_INT")
               (64 . "_INS")
               (128 . "_PER")
               (256 . "_TAN")
               (512 . "_NEA")
               (1024 . "_GCE")
               (2048 . "_APP")
              )
 )
 (while (and modes (not (equal pt (osnap pt (cdar modes)))))
   (setq modes (cdr modes))
 )
 (car modes)
)

 

(getSnap (setq pt(getpoint "\nCliquez un point: ")))

retourne :

(4 . "_CEN") si tu cliques sur un centre

(1 . "_END") si tu cliques sur une extrémité

nil si tu cliques dans le vide.

[(gile)]

Ou, dans un style plus "fonctionnel" :

 

(defun getSnap (pt / match)
 (defun match (modes)
   (cond
     ((null modes) nil)
     ((equal pt (osnap pt (cdar modes))) (car modes))
     (T (match (cdr modes)))
   )
 )
 (match '((1 . "_END")
          (2 . "_MID")
          (4 . "_CEN")
          (8 . "_NOD")
          (16 . "_QUA")
          (32 . "_INT")
          (64 . "_INS")
          (128 . "_PER")
          (256 . "_TAN")
          (512 . "_NEA")
          (1024 . "_GCE")
          (2048 . "_APP")
         )
 )
)

[Infinicad]

OH! merci beaucoup

c'est exactement ce que je cherchais :)