Quels sont les retours de "InputBox" ?

[DenisHen]

Bonjour à tous.

 

Voilà, je cherche à savoir ce qu'a fait l'utilisateur pendant InputBox de (gile) ?

 

J'ai ça :

  (setq Text (inputbox "DenisH" "Tapez votre texte :" ""))
 (if (or (= Text "") (= Text nil))
   (exit)
 ) ;_ Fin de if

Mais ça ne fait rien, comment savoir si la fenêtre InputBox a été fermée de force ou si Annule a été choisi ?

[(gile)]

Salut,

 

Comme spécifié dans les commentaires en en-tête, si l'utilisateur annule (ou ferme la boite de dialogue ce qui revient au même) une chaîne vide est retournée.

 

Il aurait été préférable que nil soit retourné en cas d'annulation, ce qui permettrait de différencier le fait de valider une chaîne vide avec OK ou d'annuler.

 

Pour ça, il suffit de supprimer l'initialisation de ret :

 

version originale :

;; InputBox (gile)
;; Ouvre une boite de dialogue pour récupérer une valeur
;; sous forme de chaine de caractère
;;
;; Arguments
;; tous les arguments sont de chaines de caractère (ou "")
;; box : titre de la boite de dialogue
;; msg : message d'invite
;; val : valeur par défaut
;;
;; Retour
;; une chaine ("" si annulation)

(defun InputBox	(box msg val / subr temp file dcl_id ret)

 ;; Retour chariot automatique à 50 caractères
 (defun subr (str / pos)
   (if	(and
  (< 36 (strlen str))
  (setq pos (vl-string-position 32 (substr str 1 36) nil T))
)
     (strcat ":text_part{label=\""
      (substr str 1 pos)
      "\";}"
      (subr (substr str (+ 2 pos)))
     )
     (strcat ":text_part{label=\"" str "\";}")
   )
 )

 ;; Créer un fichier DCL temporaire
 (setq	temp (vl-filename-mktemp "Tmp.dcl")
file (open temp "w")
ret  ""
 )

 ;; Ecrire le fichier
 (write-line
   (strcat
     "InputBox:dialog{key=\"box\";initial_focus=\"val\";spacer;:paragraph{"
     (subr msg)
     "}spacer;:edit_box{key=\"val\";edit_width=36;allow_accept=true;}spacer;ok_cancel;}"
   )
   file
 )
 (close file)

 ;; Ouvrir la boite de dialogue
 (setq dcl_id (load_dialog temp))
 (if (not (new_dialog "InputBox" dcl_id))
   (exit)
 )
 (set_tile "box" box)
 (set_tile "val" val)
 (action_tile
   "accept"
   "(setq ret (get_tile \"val\")) (done_dialog)"
 )
 (start_dialog)
 (unload_dialog dcl_id)

 ;;Supprimer le fichier
 (vl-file-delete temp)
 ret
)

 

Version modifiée

;; InputBox (gile)
;; Ouvre une boite de dialogue pour récupérer une valeur
;; sous forme de chaine de caractère
;;
;; Arguments
;; tous les arguments sont de chaines de caractère (ou "")
;; box : titre de la boite de dialogue
;; msg : message d'invite
;; val : valeur par défaut
;;
;; Retour
;; une chaine (nil si annulation)

(defun InputBox	(box msg val / subr temp file dcl_id ret)

 ;; Retour chariot automatique à 50 caractères
 (defun subr (str / pos)
   (if	(and
  (< 36 (strlen str))
  (setq pos (vl-string-position 32 (substr str 1 36) nil T))
)
     (strcat ":text_part{label=\""
      (substr str 1 pos)
      "\";}"
      (subr (substr str (+ 2 pos)))
     )
     (strcat ":text_part{label=\"" str "\";}")
   )
 )

 ;; Créer un fichier DCL temporaire
 (setq	temp (vl-filename-mktemp "Tmp.dcl")
file (open temp "w")
 )

 ;; Ecrire le fichier
 (write-line
   (strcat
     "InputBox:dialog{key=\"box\";initial_focus=\"val\";spacer;:paragraph{"
     (subr msg)
     "}spacer;:edit_box{key=\"val\";edit_width=36;allow_accept=true;}spacer;ok_cancel;}"
   )
   file
 )
 (close file)

 ;; Ouvrir la boite de dialogue
 (setq dcl_id (load_dialog temp))
 (if (not (new_dialog "InputBox" dcl_id))
   (exit)
 )
 (set_tile "box" box)
 (set_tile "val" val)
 (action_tile
   "accept"
   "(setq ret (get_tile \"val\")) (done_dialog)"
 )
 (start_dialog)
 (unload_dialog dcl_id)

 ;;Supprimer le fichier
 (vl-file-delete temp)
 ret
)

[DenisHen]

Salut (gile) et merci de me répondre...

 

Mais je ne comprend pas, si je ne tape rien dans la fenêtre et que je fais OK, ma routine continue, si je clique Annule, pareil et si je force sa fermeture (en cliquant sur la croix) pareil...

 

Je verrais ça plus-tard chez moi, je part une petite semaine en vacance...

 

Encore merci...

 

Je m’absente une semaine, mais je verrais ça au calme, chez moi...

[(gile)]

Essaye ça :

 

(alert
 (if (setq txt (InputBox "Test" "Entrez un texte:" ""))
   (strcat "Texte : \"" txt "\"")
   "Annulation"
 )
)

[DenisHen]

Salut (gile), et merci de ton aide...

 

J'ai testé chez moi le code de mon premier poste et ça fonctionne nickel... Je ne comprend pas...

 

Mais je verrais si ça au boulo... Dans le doute, reboot...

 

Il faut vraiment que je me concentre sur la gestion d'erreurs...

 

Merci encore...

[DenisHen]

Salut.

 

Ben je ne sais pas d'où ça venait... Mais après un reboot, c'est ok...

 

Encore merci...