Outils Texte

[Megeon]

Hello tous, je me posais la question si il existait un outils comme dans photoshop qui permettait d'adapter la zone de texte au texte !

 

Si oui quel est t'il ?

 

Question posé aussi sur les forums autodesk

https://forums.autodesk.com/t5/autocad-francais/zone-de-texte-s-adaptant-au-texte/td-p/7012356

[(gile)]

Salut,

 

Si tu parles de la largeur des textes multilignes, il suffit que celle-ci soit égale à 0.

Tu peux la forcer celle-ci à 0 quand tu crées le texte multiligne :

Commande: TEXTMULT

Style de texte courant: "Standard"  Hauteur de texte: 2.5  Annotatif:  Non
Spécifiez le premier coin:
Spécifiez le coin opposé ou [Hauteur/Justifier/Espacement lignes/Rotation/Style/Largeur/Colonnes]: l

Spécifiez la largeur: 0

 

Pour le faire après coup, on peut forcer la propriété "Largeur définie" du texte multiligne à 0 dans la palette des propriétés après avoir changé la propriété Colonnes sur "Aucun".

 

Ou en LISP :

 

(defun c:LARGEUR0 (/ text)
 (if
   (and (setq text (car (entsel "\nSélectionnez un texte multiligne: ")))
 (= (getpropertyvalue text "LocalizedName") "Textmult")
 (< 0.0 (getpropertyvalue text "Width"))
   )
    (progn
      (or (= (getpropertyvalue text "ColumnType") 0)
   (setpropertyvalue text "ColumnType" 0)
      )
      (setpropertyvalue text "Width" 0.0)
    )
 )
 (princ)
)

[Megeon]

je viens de tester et ça m'a fait ceci

 

Sélectionnez un texte multiligne: ; erreur: Demande ADS erronée

 

EDIT: Ta modif focntione, merci Gile !!!

[Steven]

Salut,

 

Pour compléter la réponse de Gile avec son lisp LARGEUR0 qui supprime la fenêtre dun texte multiligne après coup, voici un lisp que j''utilise depuis quelques années qui permet de créer directement un texte multiligne sans fenêtre, comme si on créait un texte sur une seule ligne.

Je ne sais plus qui me l'avait passé.

(defun c:mymtext (/ CURTXTST STHT CURHT PDEP TMP)
(if (not TEXTROT) (setq TEXTROT 0.000))
(setq CURTXTST (getvar "textstyle"))
(if (zerop (setq STHT (cdr (assoc 40 (tblsearch "style" CURTXTST)))))
(setq CURHT (getvar "textsize"))
(setq CURHT STHT)
)
(prompt (strcat "Style de texte courant : \"" CURTXTST "\" " "Hauteur de texte " (rtos CURHT)))
(terpri)
(setq PDEP (getpoint "\nSpécifier le point de départ : "))
(if (zerop STHT)
(progn
(setq TMP (getdist (strcat "\nSpécifier la hauteur <" (rtos CURHT) "> : ")))
(if TMP
(progn
(setq CURHT TMP)
(setvar "textsize" CURHT)
)
)
)
)
(setq TMP (getangle PDEP (strcat "\nSpécifier l'angle de rotation <" (angtos TEXTROT) "> : ")))
(if TMP (setq TEXTROT TMP))
(initdia)
(command "_mtext" "_non" PDEP "_h" (rtos CURHT) "_r" (angtos TEXTROT) "_w" "0.00")
(princ)
)

 

Cool, ton lisp LARGEUR0, Gile, ça me permet d'avoir des dessins uniformes au niveau des textes multilignes quand il en existe déjà avec la fenêtre

[Megeon]

Ha ben merci encore un lisp dans la biblio

[(gile)]

Si ça plait, je mets ici le LISP que j'ai posté sur AutoCAD Français (ah, les double posts...) qui fonctionne avec un jeu de sélection plutôt qu'avec une sélection unique.

 

(defun c:LARG0 (/ ss i text)
 (if (setq ss (ssget '((0 . "MTEXT"))))
   (repeat (setq i (sslength ss))
     (setq text (ssname ss (setq i (1- i))))
     (if (< 0.0 (getpropertyvalue text "Width"))
(progn
  (if (/= (getpropertyvalue text "ColumnType") 0)
    (setpropertyvalue text "ColumnType" 0)
  )
  (setpropertyvalue text "Width" 0.0)
)
     )
   )
 )
 (princ)
)

[Megeon]

Ouai \o/ genial merci gile

[Megeon]

je viens de tester la sélection multiple c'est pile poile ce que je voulais, cette outils manquait je trouve merci Gile ! ;)

 

EDIT: Gros avantage avec cette version, au moment du choix on peux faire le cadre de sélection sur tout le dessin ça ne prend que les textes !!!