Exporter une image géoréférencée

[bviard]

Bonjour,

J'ai inséré une image .png dans autocadmap 2015 et puis je l'ai géoréférencé.

Comment faire pour exporter cette image en .tif ou .ecw et surtout garder ce géoréférencement pour l'utiliser dans un logiciel sig?

 

merci

[lecrabe]

Hello

 

J'espere que ton Image est au format TIF ou JPG !?

 

Si OUI ...

 

1) Transferer ton/tes images dans un dossier "simple" a la racine de C:\ ou D:\

En fait un nom de dossier du genre C:\IMAGES ... AUCUN caractere special ou accent ou blanc/espace

 

2) Recharger ton DWG et avec la commande XR

Lui indiquer le "BON NOUVEAU" chemin de l'Image concernee (ou des Images) !

 

3) Charger la routine LSP ci-apres par APPLOAD

 

4) L'executer en lancant : GBTFW

Et ainsi tu auras le TFW qui sera genere dans ton dossier

Si il s'agissait d'une Image JPG, alors renommer le TFW en JGW ...

 

CLIC sur le cadre de l'image concernee ...

 

5) Recommencer pour chaque Image ...

 

Bonnes Annee et surtout LA SANTE, Bye, lecrabe

 

PS: je crois qu'il s'agit d'une Routine de gegematic !?

 

 

;; http://georezo.net/forum/viewtopic.php?id=45805&action=new 
;; GBTFW.LSP pour une IMAGE DEJA INSEREE au BON endroit en XY 
;; Creation d'un fichier ".TFW" par GB le 10/11/03 
;; Si Image inseree en JPG (et non pas en TIF), renommer le TFW genere en JGW ! 
;; 
;; Mirroir en Y des Parametres AutoCAD 
;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; ATTENTION : SVP Images dans un chemin SANS caractere special NI blanc/espace !! 
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; 
;; 
;; Micro-Modif par Patrice BRAUD pour AutoCAD/MAP/CIVIL 2006 et plus 
;; Micro-Modif par Patrice BRAUD pour AutoCAD/MAP/CIVIL 2010 et plus 

(defun c:GBTFW ()

;;; Pour AutoCAD/MAP       2000-2005 par GB vs Originale 
;;;  (command "_imageframe" "_on" ) 

;;; Pour AutoCAD/MAP/CIVIL 2006-2009 par PB vs 1.00 
;;;  (command "_imageframe" "1" ) 

;;; Pour AutoCAD/MAP/CIVIL 201X      par PB vs 1.01 
    (command "_imageframe"  2  ) 

(setq index "") 
(princ "\nGeneration du Fichier de Calage TFW depuis UNE Image quelconque inseree ... ")
(setq ent (entget (CAR(ENTSEL "\nMontrer l'IMAGE (En principe: TIF ou JPG) : ")))) 
(setq ent340 (cdr (assoc 1 (entget (cdr (assoc 340  ent)))))) 
(setq ef (strcat (substr ent340 1 (- (strlen ent340) 4)) index ".TFW")) 
(setq ftfw (open ef "w")) 
(setq X10 (car (cdr (assoc 10 ent))) ) 
(setq Y10 (cadr (cdr (assoc 10 ent))) ) 
(setq X11 (car (cdr (assoc 11 ent))) ) 
(setq Y11 (cadr (cdr (assoc 11 ent))) ) 
(setq X12 (car (cdr (assoc 12 ent))) ) 
(setq Y12 (cadr (cdr (assoc 12 ent))) ) 
(setq X13 (car (cdr (assoc 13 ent))) ) 
(setq Y13 (cadr (cdr (assoc 13 ent))) ) 
(setq line1 (rtos X11 2 9)) 
(write-line line1 ftfw) 
(setq line2 (rtos Y11 2 9)) 
(write-line line2 ftfw) 
(setq line3 (rtos (* -1 X12) 2 9)) 
(write-line line3 ftfw) 
(setq line4 (rtos (* -1 Y12) 2 9)) 
(write-line line4 ftfw) 
(setq line5 (rtos (+ X10 (* X12 Y13)) 2 9)) 
(write-line line5 ftfw) 
(setq line6 (rtos (+ Y10 (* Y12 Y13)) 2 9)) 
(write-line line6 ftfw) 
(close ftfw) 

) 

[bviard]

Bonjour,

Désolé de la réponse tardive je reviens de congé.

 

Le lips fonctionne très bien, merci beaucoup! :D :D