données d'un calque

[PHILPHIL]

bonjour

 

en lisp comment peut on récupérer les données d'un calque en connaissant sont nom ?

 

récupérer l'épaisseur, la couleur, et type de ligne ? et le reste aussi pourquoi pas

 

merci

 

a+

 

Phil

[(gile)]

Salut,

 

Globalement, il y a 3 façons (2 seulement sur MAC) pour obtenir les propriétés des objets AutoCAD (graphiques ou non).

 

La méthode "historique" utilise la "liste DXF" de l'objet telle que retournée par entget.

Les codes de groupe DXF peuvent paraître un peu obscurs mais l'aide DXF est en français (objet LAYER).

 

(setq layer  (tblobjname "layer" "0"))
(setq dxflst (entget layer))
(setq color (cdr (assoc 62 dxflst)))
(setq ltype (cdr (assoc 6 dxflst)))
(setq lweight (cdr (assoc 370 dxflst)))

 

La méthode Visual LISP (utilisation de l'interface COM non disponible sur MAC).

On obtient toutes les propriétés avec (vlax-dump-object layer).

 

(setq layer (vla-Item (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object))) "0"))
(setq color (vla-get-Color layer))
(setq ltype (vla-get-Linetype layer))
(setq lweight (vla-get-LineWeight layer))

 

La méthode MAC (alternative à COM qui fonctionne aussi sur Windows).

On obtient toutes les propriétés (dans la fenêtre de texte) avec (dumpallproperties layer).

 

(setq layer (tblobjname "layer" "0"))
(setq color (getpropertyvalue layer "Color"))
(setq ltype (getpropertyvalue (getpropertyvalue layer "LinetypeObjectId") "Name"))
(setq lweight (getpropertyvalue layer "LineWeight"))