[Résolu] TblSearch avec caractères génériques

[DenisHen]

Bonjour à tous.

 

Voilà, aujourd'hui, je cherche à savoir si un calque contenant "ASS" existe.

 

J'ai donc un (tblsearch mais je ne peut pas y mettre des caractères génériques. comme ceci :

(tblsearch "layer" "*ASS*")

Qui me donne comme réponse nil, ce qui est normal puisqu’il n’existe pas de calque nommé "*ASS*"...

 

Si quelqu'un a une astuce, un conseil... Je suis preneur...

[Patrick_35]

Salut

 

Une boucle avec wcmatch

 

@+

[(gile)]

Salut,

 

Il faut utiliser wcmatch (avec strcase pour que la recherche ne soit pas sensible à la casse) dans une boucle avec tblnext.

 

(defun tblmatch (table pattern / rec lst)
 (setq pattern (strcase pattern))
 (while (setq rec (tblnext table (not rec)))
   (if (wcmatch (strcase (cdr (assoc 2 rec))) pattern)
     (setq lst (cons rec lst))
   )
 )
 (reverse lst)
)

 

(tblmatch "layer" "*ASS*")

retourne la liste de tous les calques dont le nom correspond au modèle ("*ASS*).

[DenisHen]

Salut Patrick_35, et merci pour ton aide.

 

J'avoue ne jamais avoir utilisé wcmatch... Et l'aide est très "light"... Je tente de faire quelques tests mais rien de probant...

(defun c:DHWcMatch ()
 ;;Teste pour chercher un calques avec caractères génériques
 (if (/= (wcmatch LAYER "*ASS*") nil)
   (princ "\nCalque trouvé")
   (princ "\nCalque non trouvé")
 ) ;_ Fin de if
)

[(gile)]

(if (/= (wcmatch LAYER "*ASS*") nil) ...)

Traduit en français, ça donne : "si la correspondance entre LAYER et "*ASS*" n'est pas fausse ...".

L'usage de la double négation peut être vu comme un effet de style en littérature, mais en programmation, on évite.

On préfère dire plus simplement "si la correspondance entre LAYER et "*ASS*" est vraie ...", ce qui se traduit simplement par :

(if (wcmatch LAYER "*ASS*") ...)

[Patrick_35]

Je trouve l'aide très complète et on voit la puissance de wcmatch.

 

Regarde bien la routine de (gile).

 

@+

[DenisHen]

Salut (gile) et merci de m'aider...

 

C'est exactement ce que je cherchais... Mais j'étais à mille lieux de la solution...

 

Oui, la double négation est un peu "capilotractée"... ;)

 

Effectivement, la routine de (gile) est encore "complexe" pour mon piètre niveau... Mais elle m'en apprend tout de même...

 

Encore merci à vous deux...

[(gile)]

Salut Patrick_35, et merci pour ton aide.

 

J'avoue ne jamais avoir utilisé wcmatch... Et l'aide est très "light"... Je tente de faire quelques tests mais rien de probant...

(defun c:DHWcMatch ()
 ;;Teste pour chercher un calques avec caractères génériques
 (if (/= (wcmatch LAYER "*ASS*") nil)
   (princ "\nCalque trouvé")
   (princ "\nCalque non trouvé")
 ) ;_ Fin de if
)

 

Juste un petit conseil.

Quand tu essayes de comprendre une fonction en faisant des tests (ce qui est une très bonne méthode), tu n'as pas besoin de définir une nouvelle fonction/commande.

Utilise simplement la console de l'éditeur avec de simples expressions qui appellent la fonction à tester :

(wcmatch "DenisH" "*ni*")

Ton code utilise une variable globale (LAYER) dont on ne sait rien, c'est ça qui rend les tests peu probants...

[Patrick_35]

Si je décompose la routine de (gile)

 

(tblnext "layer" T) --> Trouver le 1er calque

(tblnext "layer") --> Calque suivant

(tblnext "layer") --> Calque suivant

(tblnext "layer") --> Calque suivant

...

(tblnext "layer") --> Calque suivant

(tblnext "layer") --> nil --> Plus de calques

 

 

Ensuite, un (tblnext "layer" T) retourne par exemple ((0 . "LAYER") (2 . "0") (70 . 0) (62 . 7) (6 . "Continuous"))

Reste à exploiter le code dxf 2 avec wcmatch et à mettre le tout dans une boucle.

 

@+

[DenisHen]

Merci à vous deux pour toutes ces précisions...