Sélectionner 1 bloc des textes et remplir les attributs

[zebzeb]

Bonjour à tous,

 

Voilà bien longtemps que je n’étais venu vous solliciter, mais la reprise du lisp … oups !

 

Je pense que quelqu’un déjà fais un lisp qui pourrait correspondre à mes besoins (enfin j’espère)

 

J’ai reçu plusieurs plans avec des blocs sans attribut et des textes ou mtext qui leurs sont associés

 

J’ai utilisé (merci encore) le lisp rbloc de Patrick35 pour modifié les bloc sans attribut.

 

Idéalement je souhaiterais maintenant sélectionner 1 bloc et de 2 à 8 textes ou mtext pour remplir les attributs (premier texte sélectionner attribut 1, deuxième texte attribut 2, etc …)

 

Avez quelque chose qui règlerais mon souci ?

 

Merci

[Patrick_35]

Salut

 

Par exemple

(defun c:rat(/ doc ent lst txt)
 (setq doc (vla-get-activedocument (vlax-get-acad-object)))
 (vla-startundomark doc)
 (while (setq ent (entsel "\nSélectionnez un bloc : "))
   (and (setq ent (vlax-ename->vla-object (car ent)))
 (eq (vla-get-objectname ent) "AcDbBlockReference")
 (eq (vla-get-hasattributes ent) :vlax-true)
     (progn
(setq lst nil)
(while (setq txt (entsel "\nSélectionnez un texte (entrée = FIN) : "))
  (and (setq txt (vlax-ename->vla-object (car txt)))
       (vlax-property-available-p txt 'textstring)
    (setq lst (cons (vla-get-textstring txt) lst))
  )
)
(and lst
  (mapcar '(lambda(a B) (vla-put-textstring a B)) (vlax-invoke ent 'getattributes) (reverse lst))
)
     )
   )
 )
 (vla-endundomark doc)
 (princ)
)

 

@+

[zebzeb]

Bonjour Patrick,

 

Quel rapidité !

Voilà ce que me retourne le code

 

Commande: RAT
; erreur: nombre d'arguments insuffisants

[Patrick_35]

Salut

 

J'avais 5mn et tu es tombé au bon moment.

 

J'avais oublié le / dans le nom de la fonction. C'est corrigé.

 

@+

[zebzeb]

Merci beaucoup ;)

 

c'est parfait