[Résolu] Fusionner 3 Lisp

[yusukens82]

Bonjour,

Sans passer par une fenêtre à choix multiple je souhaite fusionner 3 Lisp

en lançant qu'un seul lisp.

Si quelqu'un peut m'aider, merci.

 

 

Les 3 Lisp en question :

;;;===============================================================;;;

;; Sélection par calque
(defun c:ssl (/ ss ent)
 (and
   (or
     (and
(setq ss (cadr (ssgetfirst)))
(= 1 (sslength ss))
(setq ent (ssname ss 0))
     )
     (and
(sssetfirst nil nil)
(setq ent (car (entsel)))
     )
   )
   (sssetfirst nil (ssget "_X" (list (assoc 8 (entget ent)))))
 )
 (princ)
)

;;;===============================================================;;;

;; Sélection par type d'entité
(defun c:sse (/ ss)
 (and
   (or
     (and
(setq ss (cadr (ssgetfirst)))
(= 1 (sslength ss))
(setq ent (ssname ss 0))
     )
     (and
(sssetfirst nil nil)
(setq ent (car (entsel)))
     )
   )
   (sssetfirst nil (ssget "_X" (list (assoc 0 (entget ent)))))
 )
 (princ)
)

;;;===============================================================;;;

;; Sélection par couleur
(defun c:ssc (/ ent elst col)
 (and
   (or
     (and
(setq ss (cadr (ssgetfirst)))
(= 1 (sslength ss))
(setq ent (ssname ss 0))
     )
     (and
(sssetfirst nil nil)
(setq ent (car (entsel)))
     )
   )
   (setq elst (entget ent)
 	col  (cond
     ((assoc 430 elst))
     ((assoc 420 elst))
     ((assoc 62 elst))
     (T (cons 62 256))
          )
   )
   (sssetfirst nil (ssget "_X" (list col)))
 )
 (princ)
)

;;;===============================================================;;;

[x_all]

et pour quoi pas SSM de (gile) ?

[(gile)]

Salut,

 

(defun c:sselc (/ ent elst col)
 (and
   (or
     (and
(setq ss (cadr (ssgetfirst)))
(= 1 (sslength ss))
(setq ent (ssname ss 0))
     )
     (and
(sssetfirst nil nil)
(setq ent (car (entsel)))
     )
   )
   (setq elst (entget ent)
  col  (cond
	 ((assoc 430 elst))
	 ((assoc 420 elst))
	 ((assoc 62 elst))
	 (T (cons 62 256))
       )
   )
   (sssetfirst
     nil
     (ssget "_X" (list (assoc 0 elst) (assoc 8 elst) col))
   )
 )
 (princ)
)

[yusukens82]

x_all : pas de SSM car c'est une fenêtre à choix multiple, et je passe mon temps à cocher les 3 premières casses.

 

 

Grand merci Gile pour avoir bien voulu modifier ton LISP.

 

Bonne journée

[VDH-Bruno]

Bonjour,

 

Il est pour moi ce post là :) , si je peux pendant mes congés d'été, je me remettrais spécialement au Lisp pour vous faire une réponse sur ce sujet type -> Combiner les sélections personnalisés

 

A+

 

(Ps: (gile) de mémoire il me semble que je t'avais renvoyé ma version de ton fichier spécial sélection)