NOM DE BLOC

[PHILPHIL]

bonjour

 

on peut recuperer le nom d'un bloc insérer dans un fichier en cliquant dessus.

 

mais comment fait on pour recuperer le nom d'un bloc qui est dans un bloc inséré?

 

il y a pas un lisp deja sur CADxp qui donnait les noms des blocs qui etaient dans des blocs et leurs nombre ?

 

a+

 

Phil

[(gile)]

Salut,

 

Il me semblait avoir fait un truc dans ce genre mais je ne le retrouve plus.

 

Le principe est de parcourir les entités composants la définition du bloc à la recherche de références de bloc et, quand on en trouve une, de faire la même chose (récursion) avaec la définition du bloc imbriqué.

 

Un petit truc vite fait :

(defun nested (blockName / printNested)
 (defun printNested (blk num / ent elst)
   (if	(setq ent (cdr (assoc -2 (tblsearch "BLOCK" blk))))
     (progn
(repeat num (princ "  "))
(princ blk)
(princ "\n")
(while ent
  (setq elst (entget ent))
  (if (= (cdr (assoc 0 elst)) "INSERT")
    (printNested (cdr (assoc 2 elst)) (1+ num))
  )
  (setq ent (entnext ent))
)
     )
   )
   (princ)
 )
 (printNested blockName 0)
)

[Steven]

Salut gile,

 

Le lisp ne fonctionne pas :(

J'ai cru, au début, que c'était le fait qu'il y est

 

(defun nested (blockName / printNested)

à la place de

(defun c:nested(blockName / printNested)

 

 

C'est en regardant d'autres lisp que j'ai pu remarquer ça, mais ça ne marche toujours pas.

 

Dans la ligne de commande, il y a ceci:

 

 

Commande:
Commande: APPLOAD
nested.lsp correctement chargé(s)


Commande:
Commande:
Commande: NESTED
; erreur: nombre d'arguments insuffisants

Commande:

[(gile)]

Salut,

 

Il ne s'agit pas d'une commande mais d'une fonction qui requiert un argument : le nom du bloc.

Exemple pour un bloc nommé "toto" :

(nested "toto")

[PHILPHIL]

hello Gile

 

s'il y a plusieurs blocs qui composent se bloc, il va donné tous les noms je suppose

je garde ca sous le coude, pour tester

 

 

mais il donnera pas le nom du bloc de l'entité que l on a sélectionné.

 

 

a+

merci

 

 

Phil

[(gile)]

Oupss !...

 

J'avais mal compris la demande.

Pour ce que tu veux faire, si j'ai bien compris, il faut utiliser la fonction nentsel ou nentselp.

Cette fonction appliquée à une 'sous-entité' retourne une liste qui contient les informations que tu cherches :

premier élément : le nom d'entité de la sous-entité sélectionnée

deuxième élément : le point cliqué

troisième élément : la matrice combinant toutes les transformations subies par l'entité sélectionnée

quatrième élément : la liste des entités 'parent'

Cas particulier quand l'entité sélectionnée est une référence d'attribut, le bloc parent n'apparaît pas dans la liste des parents mais on le retrouve facilement.

 

Une petite routine qui retourne la liste des noms de blocs parent. On peut lui passer en argument la liste retournée par nentsel :

(getOwnerNames (nentsel)) 

ou celle retournée par nentselp :

(getOwnerNames (nentselp))

 

;; Retourne la liste des noms des blocs parent de la sous-entité
;;
;; Arguument
;; nentLst : une liste telle que celle retournée par nentsel(p)
(defun getOwnerNames (nentLst / elst)
 (setq elst (entget (car nentLst)))
 (mapcar
   '(lambda (ent) (cdr (assoc 2 (entget ent))))
   (if	(= "ATTRIB" (cdr (assoc 0 elst)))
     (cons (cdr (assoc 330 elst)) (cadddr nentLst))
     (cadddr nentLst)
   )
 )
)

[iowa13]

bonjour.

Ci joint un code du mème principe, mais il y a le problème des noms des sous entités qui ne sont pas afficher.

Comment faire la compil de ce code et l'affichage des sous entités.

(defun c:BNameLabel (/ ent entl obj)
(cond ((not (setq ent (car (entsel "\nSelect block: ")))))
((not (eq (cdr (assoc 0 (entget ent))) "INSERT")) (princ "\nInvalid object!"))
((setq pt (getpoint "\nSpecify first point: "))
(setq entl (entlast))
(vl-cmdf "_.mleader" "_non" pt "\\")
(while (eq (logand 1 (getvar 'CMDACTIVE)) 1) (vl-cmdf ""))
(if (not (equal entl (setq entl (entlast))))
(vla-put-textstring
(vlax-ename->vla-object entl)
(vlax-get-property
(setq obj (vlax-ename->vla-object ent))
(if (vlax-property-available-p obj 'EffectiveName)
'EffectiveName
'Name
)
)
)
)
)
)
(princ)
)
(vl-load-com)
(princ)