Géométrie

[Megeon]

je ne savais pas ou trop poster ça, donc je le poste ici. qu'un modo le place dans la bonne catégorie s'il vous plait

 

donc j'aimerais savoir si il y a une technique pour faire ce genre de chose rapidement test.zip

 

en claire faire une ligne et que les autres se fasse toute seul ( ou même deux et séparer l'espace en plusieurs espaces égales. Et le tout en vectoriel

 

Quel logiciel ?

Quel façon de procédé ?

[nosset]

Perso je dirais avec du LISP sans problème.

[Megeon]

Perso je dirais avec du LISP sans problème.

 

faut il encore connaitre le LISP, mais pour le commun des mortels ?

[Tramber]

1- Trace une ligne, clique-là pour avoir tes poignées bleues. Rougis une poignée et tape C, tu est en mode copier.

Je trouve que ça peut aider.

 

2- A l'inverse. Tu alignes tes lignes parallèles (facile) et tu les selctionnes toutes. Tu vas dans les proriétés et tu assignes un point de départ unique grâce aux coordonnées X et Y.

Toujours les propriétés qui ne sont pas que pour les débutants :P

 

Voir aussi du côté d'un bloc dynamique... et bon amusement B)

[Megeon]

1- Trace une ligne, clique-là pour avoir tes poignées bleues. Rougis une poignée et tape C, tu est en mode copier.

Je trouve que ça peut aider.

 

 

:D marche bien ça ^^

 

mais pour 50 lignes et 10 angles ça se complique.

 

pareil pour les autres solutions

[Tramber]

L'autre est bien plus puissant, le 2-

Alors ne t'arrête pas là <_>

[Tramber]

Tu as modifié ta réponse.

 

Sinon c'est tout ce que j'ai à la main. ;)

[rebcao]

Bonjour,

 

Avec un peu d'EXCEL pourquoi pas ! Du moment qu'on peut lui donner les éléments du style :

 

. Nombre de lignes (polylignes)

. Point de départ

. PT départ Vecteur 1 + dimension + angle

. PT départ Vecteur 2 + dimension + angle

. PT départ Vecteur 3 + dimension + angle

. Point d'arriver

 

Et ensuite balancer le tout via un SCRIPT généré dans EXCEL

 

Christian

[Megeon]

Via excel ???? :blink: :blink: :blink:

 

he ben j’apprends plein de chose dit donc !

[Tramber]

Ben oui, les scripts.

:angry:

[Megeon]

hue comprend pas pk t'es pas content Tramber

[Tramber]

Que tu sais toujours pas faire un script :angry:

Bonsoir, j'ai les gamins ce soir !!

[rebcao]

Fui, Fui,

 

Si tu regardes

la plupart des applications sont basées sur des Macros EXCEL...

 

C'est la cas des vidéos :

-

-

-

-

Et toutes ces applications sont 100% compatibles pour les versions LT...

 

Tiens ! Oui, pourquoi le Tramber t'en veux ?

 

Christian

[Megeon]

et ben non je ne sais pas faire de script, car ben je me suis jamais penché la dessus, car je ne sais pas vraiment a quoi ça pourrais me servir !

 

Si on commence a me jetter des pierre a cause de ça, je vais plus venir !

[rebcao]

Un SCRIPT permet de réaliser des taches à partir d'un fichier .SCR dans lequel on décrit ligne par ligne les commandes, les options à utiliser pour générer le dessin.

 

Christian

[nosset]

Allez Demain je te fais vite fait un Lisp si je trouve un peu de temps.

Tu n'as pas LT au moins

[Megeon]

Merci Christian

non j'ai pas LT

[(gile)]

Salut,

 

Vu le dessin donné en exemple, avec une seule polyligne comme donnée initiale ce n'est pas possible : les segments (fictifs) qui contiennent les sommets correspondants des polylignes ne sont ni parallèles, ni de longueurs égales.

 

Il faut donc (en plus du nombre de polylignes à dessiner bien sûr) :

- soit deux polylignes (première et dernière ou première et deuxième) pour déterminer ces segments fictifs ;

- soit la première polyligne et les segments qui contiendront les sommets correspondant des polylignes.

[(gile)]

Un exemple en LISP qui crée le nombre de polylignes spécifiées entre les deux polylignes sélectionnées.

 

(defun c:interPline (/ massoc getVertices entmakePline pl1 pl2 l1 l2 i vecs)

 (defun massoc	(key alst)
   (if	(setq alst (member (assoc key alst) alst))
     (cons (cdar alst) (massoc key (cdr alst)))
   )
 )

 (defun getVertices (pline / elst)
   (setq elst (entget pline))
   (if	(= (cdr (assoc 0 elst)) "LWPOLYLINE")
     (massoc 10 elst)
   )
 )

 (defun entmakePline (lst)
   (entmakex
     (append
(list
  '(0 . "LWPOLYLINE")
  '(100 . "AcDbEntity")
  '(100 . "AcDbPolyline")
  (cons 90 (length lst))
  '(70 . 0)
)
(mapcar '(lambda (p) (cons 10 p)) lst)
     )
   )
 )

 (if
   (and
     (setq pl1 (car (entsel "\nSélectionnez la première polyligne: ")))
     (setq l1 (getVertices pl1))
     (setq pl2 (car (entsel "\nSélectionnez la dernière polyligne: ")))
     (setq l2 (getVertices pl2))
   )
    (if (= (length l1) (length l2))
 (progn
   (initget 7)
   (setq i (1+ (getint "\nEntrez le nombre de polyligne intermédiaires: ")))
   (setq vecs (mapcar
		'(lambda (p1 p2)
		   (mapcar
		     '(lambda (x1 x2) (/ (- x2 x1) i))
		     p1
		     p2
		   )
		 )
		l1
		l2
	      )
   )
   (repeat (1- i)
     (setq l1 (mapcar '(lambda (p v) (mapcar '+ p v)) l1 vecs))
     (entmakePline l1)
   )
 )
      (prompt "\nLes deux polylignes n'ont pas le même nombre de sommets.")
    )
    (prompt "\nL'objet sélectionné n'est pas une polyligne.")
 )
 (princ)
)

[Megeon]

He ben même le grand maître du LISP se lance

je suis sur que ça vous amuse ce genre d'exercice

[Troll on] le prochain ça sera la meme chose mais avec des splines :roll: [/Troll off]

[Megeon]

hey (gile) je kiff ton LISP

http://image.noelshack.com/minis/2016/14/1459839437-sans-titre3.png

 

@ christian, je regarderais dans la journée tes videos !