Trouver les champs "perdus" ?

[lecrabe]

Hello

 

Soit un dessin qui aurait des champs dynamiques dans : MTexte, Attribut, MLeader, etc

MAIS qui font reference (ObjectId) a une entite graphique qui a "disparu" (effacee, decomposee, etc)

 

A ce moment le champ dynamique est orphelin et il affiche des # ...

 

Donc a partir d'une selection AutoCAD classique, SVP je desire une routine Lisp/VLisp qui ne garde dans la selection QUE les champs orphelins !!

 

Ainsi je pourrais les deplacer ou les effacer ou les changer de calque, etc ...

 

Je n'ai pas reussi a trouver mais j'ai peut etre mal cherche !?

 

Merci d'avance, Bye, lecrabe

[(gile)]

Salut,

 

Pas testé en profondeur, je te laisse faire...

 

(defun c:champsorphelins (/ acdoc ss)
 (vl-load-com)
 (setq acdoc (vla-get-ActiveDocument (vlax-get-acad-object)))
 (vla-regen acdoc acActiveViewport)
 (setq ss (ssadd))
 (vlax-for obj	(vla-get-Block (vla-get-ActiveLayout acdoc))
   (if
     (or
(and
  (member (vla-get-ObjectName obj)
	  '("AcDbMLeader" "AcDbMText" "AcDbText")
  )
  (= (vla-get-TextString obj) "#########")
)
(and
  (= (vla-get-ObjectName obj) "AcDbBlockReference")
  (vl-some '(lambda (x) (= (vla-get-TextString x) "#########"))
	   (vlax-invoke obj 'GetAttributes)
  )
)
     )
      (ssadd (vlax-vla-object->ename obj) ss)
   )
 )
 (sssetfirst nil ss)
 (princ)
)

[lecrabe]

Hello Gilles

 

1) MERCI pour ta reactivite !

 

2) J'ai fais un test rapide sur des MTexts representant les aires & longueurs de polylignes ...

 

3) Cela ne fonctionne que sur les champs ou il y a 9 cars # car ta routine teste la presence de 9 cars #

Je pense qu'il faudrait une version qui teste la presence "n'importe ou" (A cause des prefixes ou suffixes eventuels sur les champs) de 3 cars # (OU PLUS) : cela devrait suffire a "ramasser" la majorite des champs orphelins !

 

Qu'en penses tu ?

 

4) Micro-amelioration : SVP serait il possible d'avoir une selection AutoCAD classique et non pas un traitement automatique de TOUT le DWG ?

 

Encore Merci, Bye, lecrabe

[Patrick_35]

Salut

 

(defun c:champsorphelins (/ acdoc ss sel)
 (vl-load-com)
 (setq acdoc (vla-get-ActiveDocument (vlax-get-acad-object)))
 (setq ss (ssadd))
 (and (ssget)
   (progn
     (vlax-for obj (setq sel (vla-get-activeselectionset acdoc))
(if
  (or
    (and
      (member (vla-get-ObjectName obj)
	      '("AcDbMLeader" "AcDbMText" "AcDbText")
      )
      (vl-string-search "###" (vla-get-TextString obj))
    )
    (and
      (= (vla-get-ObjectName obj) "AcDbBlockReference")
      (vl-some '(lambda (x)  (vl-string-search "###" (vla-get-TextString x)))
	       (vlax-invoke obj 'GetAttributes)
      )
    )
  )
  (ssadd (vlax-vla-object->ename obj) ss)
)
     )
     (vla-delete sel)
   )
 )
 (sssetfirst nil ss)
 (princ)
)

 

@+

[lecrabe]

Hello Gilles & Patrick_35

 

1) Encore MERCI pour la reactivite de GC & P35 et les 2 Modifs !

 

2) Cela me parait OK pour les MTexts (Aires & Longueurs des Polylignes)

NON teste sur les MLeaders et Attributs, mais j'ai confiance ...

 

3) J'ai mis en fait 2 # ... Tant pis pour les champs sur UN SEUL caractere !

 

4) Et j'ai rajoute UNE ligne comme dans la 1ere version :

;;;;;; Ainsi les champs orphelins sont bien avec des # ;;;;;; REGEN

(vla-regen acdoc acActiveViewport)

 

MERCI Les Pros, Bonne Journee, Bye, lecrabe

[Patrick_35]

MERCI Les Pros, Bonne Journee, Bye, lecrabe

C'était le cadeau pour ta 12em année de cadxp ;)

 

@+

[lecrabe]

Hello

 

MERCI & Bonnes Fetes de Fin d'Annee au Marseillais (Gilles) et au Rennais (Patrick) et A TOUS !

 

Bye, lecrabe (d'eau douce de la Loire)