Création de côte avec soustraction constante

[Johann]

Bonjour,

Je cherche depuis quelque jour à créer des côtes ou la valeur de 0.20 est toujours appliqué en soustraction à cette côte mais je ne trouve aucune solution, sauriez-vous comment procéder?

 

Merci.

[bonuscad]

Bonjour,

 

Créer des côtes directement, je ne sais pas faire.

 

Par contre une autre solution est possible:

Tu crée ta/tes cotations de manière classique sans te préoccuper de la valeur de la côte, puis tu applique le lisp suivant.

 

Inconvénient: Tes côtes ne seront plus associatives, les lignes d'attaches sont déplacées (ce n'est peut être pas ce que tu souhaite?), donc la valeur de la côte correspond aux position des lignes d'attaches.

 

(defun c:dim-n ( / js n ent_dim dxf_ent p1 p2 p_nw1 p_nw2)
 (if (not value)
   (progn
     (initget 2)
     (setq value (getreal "\nValeur à retrancher à la côte sélectionnée <0.20>: "))
     (if (not value) (setq value 0.2))
   )
 )
 (or
   (setq js (ssget "_I" '((0 . "DIMENSION"))))
   (setq js (ssget "_P" '((0 . "DIMENSION"))))
 )
 (cond
   (js
     (sssetfirst nil js)
     (initget "Existant Nouveau _Existent New")
     (if (eq (getkword "\nTraiter jeu de sélection [Existant/Nouveau] <Existant>: ") "New")
       (progn (sssetfirst nil nil) (setq js (ssadd) js (ssget '((0 . "DIMENSION")))))
     )
   )
   (T (setq js (ssget '((0 . "DIMENSION")))))
 )
 (cond
   (js
     (repeat (setq n (sslength js))
       (setq ent_dim (ssname js (setq n (1- n))))
       (setq dxf_ent (entget ent_dim))
       (cond
         ((or (zerop (rem (cdr (assoc 70 dxf_ent)) 32)) (eq (rem (cdr (assoc 70 dxf_ent)) 32) 1))
           (setq p1 (cdr (assoc 13 dxf_ent)) p2 (cdr (assoc 14 dxf_ent)))
           (setq p_nw1 (polar p1 (angle p1 p2) (/ value 2.0)) p_nw2 (polar p2 (angle p2 p1) (/ value 2.0)))
           (setq dxf_ent (subst (cons 13 p_nw1) (assoc 13 dxf_ent) dxf_ent))
           (setq dxf_ent (subst (cons 14 p_nw2) (assoc 14 dxf_ent) dxf_ent))
           (entmod dxf_ent)
         )
         (T
           (princ "\nN'est pas une côte alignée, pivotée, horizontale ou verticale.")
         )
       )
     )
   )
 )
 (prin1)
)

[Johann]

Parfait! C'est exactement ce que je cherchais! Merci beaucoup. ;)

[lecrabe]

Hello

 

Mon idee est differente !

 

Un Lisp/VLisp qui recupere la valeur reelle de la cote puis force la valeur de la cote en enlevant 0.2 ...

 

Bye, lecrabe

[philsogood]

aïÏïÏ... le crabe il force des cotes!! c'est mal!!

en même temps incapable de savoir ce que fait exactement le lisp de bonuscad!! :)

Phi

[bonuscad]

en même temps incapable de savoir ce que fait exactement le lisp de bonuscad!!

 

Généralement quand on côte, on s'accroche en règle générale aux extrémités d'objets (ou on sélectionne directement l'objet) de façon à avoir la côte réelle. Nous sommes bien d'accord?

 

Dans son cas il voulait réduire sa côte de 0.20. Pour fixer les points en relatif par rapport aux extrémité en manuel, bonjour la gymmastique, avec le lisp ça se fait tout seul.