CUMUL (sous-totaux) dans une liste

[rebcao]

Bonjour à Toutes et à Tous,

 

Soit la liste suivante, contenant des chaines avec des doublons, triplons, et plus :

 

("Nom BLOC" "123" "ABC" "BBB" "123" "AAA" "BBB" "123" "BBB" "123" "ABC" "789" "123")

 

Existe-t-il une fonction LISP ou VLISP toute prête, pour faire le CUMUL ou faut-il passer par une boucle qui va traiter la liste élément par élément ? qui donnerait par exemple ce résultat sous forme de paire pointée et le TOTAL ?

 

( ( "Nom BLOC" . 1 ) ("123" . 5) ("BBB" . 3) ("AAA" . 1) ("ABC" . 2) ("789" . 1) )

 

Je vous remercie

 

Christian

[Patrick_35]

Salut

 

(setq tbl '("Nom BLOC" "123" "ABC" "BBB" "123" "AAA" "BBB" "123" "BBB" "123" "ABC" "789" "123"))
(while tbl    
 (setq n   (length tbl)
js  (car tbl)
tbl (vl-remove js tbl)
lst (cons (cons js (- n (length tbl))) lst)
 )
)

 

(reverse lst) --> (("Nom BLOC" . 1) ("123" . 5) ("ABC" . 2) ("BBB" . 3) ("AAA" . 1) ("789" . 1))

 

@+

[(gile)]

Salut,

 

Un exemple de fonction LISP (defun)

 

(defun groupItems (lst / pair result)
 (foreach item	lst
   (setq result
   (if (setq pair (assoc item result))
     (subst (cons item (1+ (cdr pair))) pair result)
     (cons (cons item 1) result)
   )
   )
 )
 (reverse result)
)

[rebcao]

Bonjour,

 

Je vous remercie tous les 2... vous confirmez donc qu'il n'existe pas de fonction toute faite... c'est effectivement ce genre de boucle que j'imaginais !

 

Merci. :)

 

Christian