LISP supprimer points dans blocs

[fauxsuisse]

Bonjours tout le monde,

 

Existe t il un lisp qui peut supprimer tous les points qui se trouvent dans les blocs, j'utilise souvent les point pour diviser mes lignes mais malheureusement dans les xref il y a souvent beaucoup de bloc qui utilise aussi des point et dès qu'ils sont à l'échelle ils me remplissent tout le dessin, quand il y a deux ou trois bloc c'est vite fait de les éditer puis les supprimer mais quand ce xref contient des centaines de blocs ça devient plus possible.

 

Dans l'attente de vos idées je vous souhaite une bonne journée.

[x_all]

J'ai bricoler ça il y a peu grâce à une modif que (gile) m'a fait du lisp PurgeArchicad qui vire les hachures solide dans les bloc

Je ne saurai te dire si le "AcDbPoint" est l'entité qui te défrise, mais si tu connais le petit nom du point que tu veux supprimer ça va le faire...

 

la discution

http://cadxp.com/topic/40358-selection-dans-un-bloc/page__p__225443__fromsearch__1#entry225443

 

le lisp

 

;; purge les points dans les objets de plans archicad
;; faire un regen quand il a fini de travailler (c un peu long suivant la taille du plan

(vl-load-com)


(defun c:pap (/ cnt)
 (setq	cnt 0
 )
 (vlax-for bloc (vla-get-Blocks
	   (vla-get-ActiveDocument (vlax-get-acad-object))
	 )
(vlax-for ent bloc
 	(if (= (vla-get-ObjectName ent) "AcDbPoint")
(progn
  (vla-delete ent)
  (setq cnt (1+ cnt))
)
 	)
)
 )
 (princ (strcat "\n\t"
	 (itoa cnt)
	 " objets supprimés"
 )
 )
 (princ)
)

[fauxsuisse]

Super ça marche.

 

Merci beaucoup et bonne journée

[lili2006]

Bonsoir à toutes et tous,

 

Et pourquoi pas définir le point par "vide" dans les styles de points ?

[lecrabe]

Hello

 

Humour : ReInventer l'eau chaude, il est vrai qu'on le fait souvent !?

 

Car Gilles (debut 2011) et Fraid et VDH-Bruno avaient deja fourni la "Hot Water" !

 

Avec en plus la possibilite de garder / enlever un eventuel point dessine au Point d'Insertion du Bloc !!

 

Bye, lecrabe

 

;; 
;; Supprimer (Kill) les cotations     (DIMension) dans les blocs (BLOCK) 
;; 
;; Micro-Micro Modif par lecrabe pour G_P_TP pour traiter les POINTs 
;; Routine KDIM_BLOCK --> KPNT_BLOCK 
;; Supprimer (Kill) les points graphiques (POINT) dans les blocs (BLOCK) 
;; 
;; Par GC le 11/03/2011 - Passage en DEFUN par Fraid 
;; 
;; "KPNT_BLOCK" vs 1.00 traite TOUS les points dans TOUS les Blocs , SORRY ! 
;; 
;; Chargement par APPLOAD et Lancement par KPNT_BLOCK
;; Ne pas oublier un REGEN apres execution ! 
;; 
;; "KPNT_BLOCK" vs 1.01 par VDH-Bruno qui garde un eventuel POINT graphique 
;;                                    PRESENT juste au Point d'Insertion du Block 
;; 
;; Test Object in Lisp : (entget (car (entsel)) '("*"))
;; 

(defun c:KPNT_BLOCK (/ b o)
 (vl-load-com)
 (vlax-for b (vla-get-Blocks (vla-get-ActiveDocument (vlax-get-acad-object)))
   (or (= (vla-get-IsLayout B) :vlax-true)
       (= (vla-get-IsXref B) :vlax-true)
       (vlax-for o b          
         (and (eq (vla-get-ObjectName o) "AcDbPoint") 

;;; Ci-dessous : Test sur le Point eventuel au point d Insertion par VDH-Bruno 
;;               (not (equal '(0 0 0)             (vlax-get o 'Coordinates) 1e-8)) 
;;; Ci-dessous : Amelioration du Test par Patrick_35 
                (not (equal (vlax-get b 'origin) (vlax-get o 'Coordinates) 1e-8)) 

              (vla-delete o)
         )
       )
   )
 )
 (command "regen")
 (princ)
)

[fauxsuisse]

Bonsoir à toutes et tous,

 

Et pourquoi pas définir le point par "vide" dans les styles de points ?

 

Parce que si je le défini par vide c'est mes points que je ne verrai plus, effectivement si je n'ai pas l'utilisation des point alors le définir sur vide est le plus rapide mais comme j'utilise souvent la fonction diviser j'ai besoin de la croix et c'est là que dans certain cas un grand nombre de croix s'affiche partout.

[lili2006]

Bonjour toutes t tous,

Cest vrai que la gestion du style de p oints pourrait evoluer sur AutoCAD, .......

Et en mettant la hauteur en unite absolue ?

Bon, remarque tu as trouve ton bonheur, .