[Résolue] Décharger Xref par simple clic

[La Lozère]

Salut,

Quelqu'un connait-il une astuce pour décharger une Xref par simple clic sur celle-ci sans passer par le gestionnaire?

 

Merci.

[bonuscad]

Salut,

 

Pas trop testé en profondeur, mais je pense que c'est bon...

 

(defun c:unload_xref ( / js n name_xref)
 (princ "\nSélectionner les XRefs à décharger. ")
 (while (null (setq js (ssget "_+.:E" '((0 . "INSERT")))))
   (princ "\nObjets non valable!")
 )
 (repeat (setq n (sslength js))
   (cond
     ((eq (boole 1 (cdr (assoc 70 (tblsearch "BLOCK" (setq name_xref (cdr (assoc 2 (entget (ssname js (setq n (1- n)))))))))) 4) 4)
       (command "_.-xref" "_Unload" name_xref)
     )
     (T (princ "\nN'est pas une référence externe. "))
   )
 )
 (prin1)
)

Modifié le 16 octobre 2014 par bonuscad

[La Lozère]

T'es un chef. Ca marche impec.

Et hop encore un dans ma boite à lisp...

 

Merci.

[La Lozère]

Juste une petite modif.

Est-il possible de ne pas sortir de la commande après avoir cliquer sur une Xref pour pouvoir en décharger plusieurs d'un seul coup sans avoir à relancer la commande.

 

A plus.

[Steven]

Salut,

 

Dur AA, lorsqu'on sélectionne des Xref et que l'on fait un clic droite, on peut Décharger, Détacher, Lier, etc les Xref. C'est curieux que les développeurs n'aient pas intégrer cette fonctionnalité dans AutoCAD.

[Patrick_35]

Juste une petite modif.

Est-il possible de ne pas sortir de la commande après avoir cliquer sur une Xref pour pouvoir en décharger plusieurs d'un seul coup sans avoir à relancer la commande.

 

A plus.

Salut

 

Tu as la commande multiple dans autocad

 

@+

[bonuscad]

Juste une petite modif.

Est-il possible de ne pas sortir de la commande après avoir cliquer sur une Xref pour pouvoir en décharger plusieurs d'un seul coup sans avoir à relancer la commande.

 

A plus.

J'ai modifié le code ci-dessus; le déchargement se fait après validation de l'ensemble de la sélection.

[La Lozère]

En fait ce que je demande fait un peu suite à ce post. Le truc c'est que je pourrais passer par le gestionnaire, mais si on a une très grosse Xref, rien que le fait de faire un clic droit met l'Xref en surbrillance. Et du fait de la taille de l'Xref, c'est particulièrement lourd.

 

Du coup, le lisp de bonuscad permet de s'affranchir de ce phénomène.

 

Tu as la commande multiple dans autocad

Effectivement, mais comme j'ai couplé cette routine avec un bouton, comment faire pour que cela fonctionne?

 

A plus.

[La Lozère]

Merci Bonuscad, mais du coup, cela sélectionne l'Xref et je me retrouve dans le problème premier. Si l'Xref est très grosse ça prend du temps. La commande "multiple" fonctionne bien dans ce cas.

 

Est-il possible de décharger à la volé?

Sinon, peux-tu reposter l'ancien code? Je ne l'ai plus.

Merci.

[Olivier Eckmann]

Bonjour,

 

Dans ton CUI, tu te crées une nouvelle commande et tu lui colles ça comme macro

(setq A (cdr (assoc 2 (entget (ssname (cadr (ssgetfirst)) 0)))));(command [/size]"_.-xref" "_Unload"[size=2] A)

 

Bien enlever les ^C^C en début de ligne

 

Puis tu colles cette commande soit dans le menu contextuel "Menu de l'objet XRef", soit directement dans l'action du double-clic associé à l'objet Xref.

 

Dans le lisp de Bonuscad, il suffit d'ajouter la ligne

(setvar "HIGHLIGHT" 0)

en 2ème ligne, puis

(setvar "HIGHLIGHT" 1)

en avant-dernière ligne

 

Olivier

[La Lozère]

Merci à vous de ces différentes solutions

Bonuscad, si tu pouvez remettre le premier code, juste pour voir la différence entre les deux.

 

A plus.

[bonuscad]

Le 1er était celui-ci:

(defun c:unload_xref ( / js name_xref)
 (princ "\nSélectionner l'XRef à décharger. ")
 (while (null (setq js (ssget "_+.:E:S" '((0 . "INSERT")))))
   (princ "\nObjets non valable!")
 )
 (cond
   ((eq (boole 1 (cdr (assoc 70 (tblsearch "BLOCK" (setq name_xref (cdr (assoc 2 (entget (ssname js 0)))))))) 4) 4)
     (command "_.-xref" "_Unload" name_xref)
   )
   (T (princ "\nN'est pas une référence externe. "))
 )
 (prin1)
)

Ça peut fonctionner avec MULTIPLE, mais alors cela boucle sur la sélection (while (null (setq js .......

Il faut simplement faire ESC pour sortir.

Est-il possible de décharger à la volé?

A la volée on pourrait essayer ceci (pas droit à l'erreur de sélection, sinon on sort de la boucle)

(defun c:unload_xref ( / js name_xref)
 (princ "\nSélectionner l'XRef à décharger. ")
 (while
   (and
     (setq js (ssget "_+.:E:S" '((0 . "INSERT"))))
     (eq (boole 1 (cdr (assoc 70 (tblsearch "BLOCK" (setq name_xref (cdr (assoc 2 (entget (ssname js 0)))))))) 4) 4)
   )
   (command "_.-xref" "_Unload" name_xref)
   (princ "\nSélectionner l'XRef à décharger. ")
 )
 (prin1)
)

[La Lozère]

Super, j'ai trouvé mon bonheur. Vous êtes des chef.

 

J'ai utilisé le premier code via un bouton qui lance la commande suivante:

^C^C_multiple;unload_xref

 

Il faut certes sortir de la commande via un Echap, mais ça me va très bien.

 

Le deuxième code est également très bien, mais comme tu l'as dis, pas le droit à l'erreur.

 

A plus et encore merci

[lili2006]

Bonjour à toutes et tous,

 

Salut La Lozère,

 

Commande:

Commande: _multiple

Entrez le nom de la commande à répéter: unload_xref Commande inconnue "UNLOAD_XREF". Appuyez sur F1 pour obtenir de l'aide.

 

Tiens, le code ne fonctionne pas sur mon Civil 3D 2015

[La Lozère]

Salut Lili,

Question bête, tu as bien chargé le lisp correspondant?

Dans mon fonctionnement, c'est un lisp qui est chargé au démarrage, du coup pas de problème.

 

A plus

[lili2006]

Re,

 

Oups, je n'étais pas sur la même session AutoCAD, c'était bien le pb du chargement du lisp;...

[La Lozère]

Hello,

Je déterre un vieux sujet car je cherche une fonction un peu similaire.

Je voudrais détacher à la volé des images.

J'ai essayé d'adapter le code suivant, mais je n'y arrive pas. Alors si une bonne âme passe dans le coin....

(defun c:unload_xref ( / js name_xref)
 (princ "\nSélectionner l'XRef à décharger. ")
 (while (null (setq js (ssget "_+.:E:S" '((0 . "INSERT")))))
   (princ "\nObjets non valable!")
 )
 (cond
   ((eq (boole 1 (cdr (assoc 70 (tblsearch "BLOCK" (setq name_xref (cdr (assoc 2 (entget (ssname js 0)))))))) 4) 4)
     (command "_.-xref" "_Unload" name_xref)
   )
   (T (princ "\nN'est pas une référence externe. "))
 )
 (prin1)
)

 

Merci d'avance

[La Lozère]

Hello,

Bon, finalement, j'ai repris depuis le début, et j'ai réussi à pondre un truc qui en tout cas marche et me convient.

(defun c:unload_image ( / *error str2lst sep pos str aa bb cc lst nom)
 (princ "\nSélectionner l'Image à décharger. ")
;;; Gestion d'erreur
 (defun *error* (msg)
   (if	(/= msg "Fonction annulée")
     (princ (strcat "\nErreur: " msg))
   )
   (princ)
 )
;;; Transformation d'une chaine avec séparateur en liste de chaînes
 (defun str2lst (str sep / pos)
   (if	(setq pos (vl-string-search sep str))
     (cons (substr str 1 pos)
    (str2lst (substr str (+ (strlen sep) pos 1)) sep)
     )
     (list str)
   )
 )
;;;
(while
(setq aa (entget (car (entsel))))
(setq bb (entget (cdr (assoc 340 aa))))
(setq cc (cdr (assoc 1 bb)))
(setq lst (last (str2lst cc "\\")))
(setq nom (car (str2lst lst ".")))
(command "_.-image" "D" nom)
)
 (prin1)
)

 

toujours en grand merci à (gile) pour son tuto.