Barre de commande

[l56]

Bonjour,

 

 

Toutes les commandes d'affichage du genre (princ, (prompt, (prin ... affiche le texte soit à la suite sur la dernière ligne soit sur une nouvelle ligne avec "\n".

 

Est-il possible d'afficher un texte sur la barre de commande, puis de le mettre à jour.

Pour afficher un pourcentage par exemple.

 

Merci.

[Patrick_35]

Salut

 

Un exemple avec ou sans les express pour indiquer un état d'avancement

(defun c:test(/ ava express pou tot)
 (if (eval 'acet-ui-progress-done)
   (setq express T)
 )
 (setq ava 0 tot 1000)
 (if express
   (acet-ui-progress-init "Avancement" tot)
   (princ "\nAvancement à : 00%")
 )
 (repeat tot
   (setq ava (1+ ava)
  pou (/ (* ava 100) tot)
   )
   (repeat 50000)
   (if express
     (acet-ui-progress-safe ava)
     (progn
(if (< pou 10)
  (repeat 2 (princ (chr 8)))
  (repeat 3 (princ (chr 8)))
)
(princ (strcat (itoa pou) "%"))
(princ)
     )
   )
 )
 (and express
   (acet-ui-progress-done)
 )
 (princ)
)

 

@+

[l56]

Salut Patrick_35,

 

Pil-poil ce que je voulais.

Encore une fois un grand merci.

 

Bon WE