Calcul la somme des polylignes

[DenisHen]

Salut à tous,

 

Quelqu'un aurait-il sous le coude (car je suis sur que ça a déjà été fait) un LiSP qui donnerait la somme des longueurs des polylignes du calque courant ?

 

Je ne sais pas comment faire ce style de LiSP...

 

Denis...

[capde06]

j'ai ca

il n'y a pas de filtre sur les calques .. mais bon

 

(defun c:cumul	()
 (setq	cumul 0
sel nil
cpx 0)
 (prompt "\nSelection des poly lignes :")
 (setq sel (ssget '((0 . "LWPOLYLINE"))))

 (setq cpx 0)
 (repeat (sslength sel)
   (setq ent (ssname sel cpx))
   (setq obj (vlax-ename->vla-object ent))

   (setq cumul (+ cumul (vla-get-length obj)))

   (setq cpx (+ cpx 1))

   )
 (princ (strcat "\nLongueur :" (rtos cumul 2 2)))

 (princ)
 )

[DenisHen]

Salut,

 

Merci, je prend...

 

Denis...

[lesourd2]

Salut,

 

Merci, je prend...

 

Denis...

 

Ou ça

Longueur_cumul_poly.lsp

[(gile)]

Salut,

 

Pour avoir directement le cumul sur le calque courant (sans sélection par l'utilisateur) :

 

(defun c:cumul ()
 (princ
   (strcat "\nLongueur cummulée des polylignes sur le calque '"
    (getvar 'clayer)
    "' : "
    (rtos (polyLengthByLayer (getvar 'clayer)))
   )
 )
 (princ)
)

(defun polyLengthByLayer (layer / len ss)
 (vl-load-com)
 (or *acdoc* (setq *acdoc* (vla-get-ActiveDocument (vlax-get-acad-object))))
 (setq len 0)
 (if (ssget "_X" (list '(0 . "lwpolyline") (cons 8 layer)))
   (progn
     (vlax-for	pl (setq ss (vla-get-ActiveSelectionSet *acdoc*))
(setq len (+ len (vla-get-Length pl)))
     )
     (vla-Delete ss)
   )
 )
 len
)

[DenisHen]

Salut à tous

 

Et merci... J'ai exactement ce qu'il me faut...

 

Encore merci,

 

Denis...