renommer des blocs avec suffixe

[philsogood]

Hello,

Je travaille sur un fichier qui comprend une multitude de blocs avec des arbres que j'ai récupéré un peu partout.

bref c'est un joyeux **** au niveau des désignation des blocs arbres et je souhaiterai faire le tri et pouvoir renommer mes blocs pour pouvoir les utiliser facilement par la suite. Existe-t-il un moyen pour renommer des blocs avec "palm" comme particule dans le nom du bloc et ensuite de renommer le bloc avec palmier_01 (en sachant que le chiffre s'incrémenterait si il y avait plusieurs blocs ayant la particules "palm" en eux)

on doit pouvoir sélectionner des blocs avec renommer mais je ne vois aps comment faire l'incrémentation sur le nouveau nom de bloc!

Une idée?

Phil

[lovecraft]

Bonjour,

 

dans un premier temps tu peux renommer des blocs avec la commande renommer.

 

Pour ajouter un préfixe en utilisant la syntaxe suivante: Palm-*

 

Cordialement,

 

Laurent

[philsogood]

Re

voici quelques exemples des noms de bloc que j'ai

I_SITE2D_TREE_ELEV_Palm 1_P

I_SITE2D_TREE_ELEV_Palm 2_P

Palm Tree EV 1

PALM_TREE__17308164

Comment faire pour qu'ils s'appelent

palmier_01

palmier_02

...

Phil

[lili2006]

Bonjour à toutes et tous,

 

Il existe des petits frewaire qui permettent de faire ce que tu souhaites (si les blocs sont des fichiers biblio, sinon, il faudra commencer par ça,...(Extraire les blocs internes en .wbloc, là aussi, il existe des routines sur Cadxp qui le permettent (de mémoire, Bonuscad avait proposé un lisp de traitement par lots,...)

[VDH-Bruno]

Salut,

 

Ecrit très rapidement donc un peu brut de décoffrage, à tester..

;; Renomme et incrémente les blocs pour la chaine spécifié
(defun c:renominc (/ lst name chaine cmdecho nouvnom i *error*)
 (defun *error* (msg)
   (setvar 'cmdecho cmdecho)
   (if msg
     (princ msg)
   )
   (princ)
 )
 (and (setq cmdecho (getvar 'cmdecho)
            chaine  (getstring "\nChaine de caractère à rechercher dans les définitions de blocs: ")
      )
      (setvar 'cmdecho 0)
      (not (while (not (snvalid (setq nouvnom (getstring "\nBlocs à renommer en: "))))
             (alert "Nom de définition de bloc non valide!!!")
           )
      )
      (while (setq bl (tblnext "BLOCK" (not bl)))
        (if (vl-string-search (strcase chaine) (strcase (setq name (cdr (assoc 2 bl)))))
          (setq lst (cons name lst))
        )
        lst
      )
      (repeat (setq i (length lst))
        (command "_-RENAME" "_b" (car lst) (strcat nouvnom (itoa i)))
        (setq i   (1- i)
              lst (cdr lst)
        )
      )
 )
 (*error* nil)
)

 

A+