Coordonnées d'une polyligne

[Patrick_35]

La version spécial Noël pour Lecrabe

 

(defun c:BlexXYpoly(/ doc ename txt lst_pts rep ss)

 (defun lst_pts(ent / lst nb pts)
   (and (eq (type ent) 'ENAME)
     (setq ent (vlax-ename->vla-object ent))
   )
   (setq nb 0)
   (while (not (vl-catch-all-error-p (setq pts (vl-catch-all-apply 'vla-get-coordinate (list ent nb)))))
     (setq lst (cons (vlax-safearray->list (vlax-variant-value pts)) lst)
           nb (1+ nb)
     )
   )
   (reverse lst)
 )

 (vl-load-com)
 (setq doc (vla-get-activedocument (vlax-get-acad-object)))
 (vla-startundomark doc)
 (and (ssget (list (cons 0 "*POLYLINE")))
   (progn
     (initget "Oui Non")
     (setq rep (getkword "\nDésirez-vous indiquer les Z [Oui / Non] <Oui> : "))
     (or rep
(setq rep "Oui")
     )
     (vlax-for ename (setq ss (vla-get-activeselectionset doc))
(mapcar '(lambda(x)
	  (setq txt (strcat "X="   (rtos (car x)  2 2)
			    "\nY=" (rtos (cadr x) 2 2)
		    )
	  )
	  (and (eq rep "Oui")
	    (setq txt (strcat txt "\nZ=" 
				  (if (caddr x)
				    (rtos (caddr x) 2 2)
				    (rtos (vlax-get ename 'elevation) 2 2)
				  )
		      )
	    )
	  )
	  (entmake (list (cons   0 "MTEXT")
			 (cons   7 (getvar "textstyle"))
			 (cons 100 "AcDbEntity")
			 (cons 100 "AcDbMText")
			 (cons  10 x)
			 (cons   1 txt)
			 (cons  71 7)
			 (cons  72 5)
		   )
	  )
	)
	(lst_pts ename)
)
     )
     (vla-delete ss)
   )
 )
 (vla-endundomark doc)
 (princ)
)

 

@+

[x_all]

yahou hoo

c'est la fête !!

 

merci...

 

je compati avec toi Denis tu avais (à priori) un tout petit pb il "suffisait" d'ajouter une ligne à un texte....

 

c'est toujours comme ça... on crois que ça va être simple...