Polyligne 2D dans un SCU particulier

[La Lozère]

Hello,

J'ai récupéré un fichier dont les éléments sont issues d'un projet Autopiste. Mais le projet Autopiste n'existe plus.

Le truc c'est que les éléments des profils en travers sont des polylignes 2D dans un SCU particulier, et que je voudrais les transformer en polylignes 3D. Mais quand je passe par la commande Covadis, la conversion se passe mal, les polylignes ne respectent plus leur profil initial.

 

Si le projet autopiste marchait encore, il suffirait de cocher la bonne case, mais là, après coup, je ne vois pas comment faire.

 

Une idée?

Merci.

[(gile)]

Salut,

 

Ne sachant pas s'il s'agit de polylignes 2d 'old style' ou de polylignes 'optimisées', j'ai fait un truc qui devrait fonctionner avec les deux.

 

(defun c:Convert3d (/ *error* getVertices ss space norm)
 (vl-load-com)
 (or *acad* (setq *acad* (vlax-get-acad-object)))
 (or *acdoc* (setq *acdoc* (vla-get-ActiveDocument *acad*)))

 (defun *error* (msg)
   (and
     msg
     (/= msr "Fonction annulée")
     (princ (strcat "\nErreur: " msg))
   )
   (vla-EndUndoMark *acdoc*)
   (princ)
 )

 (defun getVertices (pl / n pts)
   (repeat (setq n (1+ (fix (vlax-curve-getEndParam pl))))
     (setq pts	(cons (vlax-curve-getPointAtParam pl (setq n (1- n))) pts)
     )
   )
 )

 (vla-StartUndoMark *acdoc*)
 (if (ssget '((-4 . "<or")
       (0 . "lwpolyline")
       (-4 . "<and")
       (0 . "polyline")
       (-4 . "<not")
       (-4 . "&")
       (70 . 124)
       (-4 . "not>")
       (-4 . "and>")
       (-4 . "or>")
      )
     )
   (progn
     (setq space (vla-get-Block (vla-get-ActiveLayout *acdoc*)))
     (vlax-for	pl (setq ss (vla-get-ActiveSelectionSet *acdoc*))
(setq norm (vlax-get pl 'Normal))
(vla-put-Closed
  (vlax-invoke
    space
    'Add3dpoly
    (apply 'append (getVertices pl))
  )
  (vla-get-Closed pl)
)
(vla-Delete pl)
     )
     (vla-Delete ss)
   )
 )
 (*error* nil)
)

[La Lozère]

Impecable, ça marche au poil.

 

Au top (Gile), comme d'hab.....

 

Merci.